Problemas con cargador en as3

[Lynxcraft]

sera porque tu pelicula no pesa mucho lo cual al cargar no da tiempo del efecto pra que veas si funciona o no coloca el codigo de esta forma

Código PHP:

  package { 
    import flash.display.Stage; 
    import flash.display.MovieClip; 
    import flash.display.Shape; 
    import flash.text.TextField; 
    import flash.events.* 
     
    public class Cargador extends MovieClip { 
        private var texto:TextField; 
        private var marco:Shape;       
        private var barra:Shape; 
 
        public function Cargador() {  
            dibujaPreload(); 
            posicionaPreload(); 
             
            this.loaderInfo.addEventListener(ProgressEvent.PROGRESS, onLoadProgress); 
            this.loaderInfo.addEventListener(Event.COMPLETE, onLoadComplete); 
        } 
 
        public function dibujaPreload() { 
            texto = new TextField(); 
            marco = new Shape(); 
            barra = new Shape(); 
            marco.graphics.lineStyle(1, 0x000000); 
            marco.graphics.drawRoundRect(0, 20, 70, 5, 0); 
            barra.graphics.beginFill(0x000000); 
            barra.graphics.drawRect(0, 20, 70, 5); 
            barra.graphics.endFill();    
            addChild(texto); 
            addChild(marco); 
            addChild(barra); 
        } 
 
        public function posicionaPreload() { 
            texto.x = marco.x = barra.x = stage.stageWidth /2 - marco.width /2 
            texto.y = stage.stageHeight /2 - texto.height /2 
            marco.y = barra.y = texto.y + 5 
        } 
         
        function onLoadProgress (event:ProgressEvent):void { 
            var cargado:int = event.bytesLoaded; 
            var total:int = event.bytesTotal; 
            var porcentaje:int = cargado/total*100; 
            texto.text = "Cargado: "+String(porcentaje)+"%"; 
            barra.width = porcentaje*marco.width/100; 
         } 
 
         function onLoadComplete (event:Event):void { 
            /*removeChild(texto); 
            removeChild(marco); 
            removeChild(barra);*/ 
            nextFrame(); 
         } 
    } 
}