Colorear días con actividades en un calendario.

luismi78 · #1 (**permalink**) 22/03/2010, 11:04

Hola a todos. Tengo un calendario hecho en ASP donde me colorea el día en el que estamos, y donde podemos pinchar los días para abrir una ventana nueva donde muestro actividades que hay ese día. Estas actividades las tengo en una base de datos access.

Lo que estoy intentando hacer pero no soy capaz es de marcar los días (el color de fondo), en rojo por ejemplo, donde hay actividades, y donde no hay, que no salga coloreado.

Os pongo el código:

Cita:

<%
Dim giorno,mese,anno,tmese,day1,primog, mese2, anno2, dayoff,ultimog,x,giorno1

giorno = request("giorno")
If giorno = "" then
giorno = day(now())
End If

mese = request("mese")
If mese = "" then
mese = month(now())
End If
anno = request("anno")
If anno = "" then
anno = year(now())
End If
If mese = 12 then
mese2 = 1
anno2 = anno+1
else
mese2 = mese+1
anno2 = anno
End If

day1 = Cdate("1"+"/"+Cstr(mese)+"/"+Cstr(anno))
dayoff = Cdate("1"+"/"+Cstr(mese2)+"/"+Cstr(anno2))-1
primog = Weekday(Cdate("1"+"/"+Cstr(mese)+"/"+Cstr(anno)))-1
ultimog = Weekday(dayoff)-1

If ultimog = 0 then
ultimog = 7
End If

If primog = 0 then
primog = 7
End If
Select Case mese
case 1
tmese = "Enero"
case 2
tmese = "Febrero"
case 3
tmese = "Marzo"
case 4
tmese = "Abril"
case 5
tmese = "Mayo"
case 6
tmese = "Junio"
case 7
tmese = "Julio"
case 8
tmese = "Agosto"
case 9
tmese = "Septiembre"
case 10
tmese = "Octubre"
case 11
tmese = "Noviembre"
case 12
tmese = "Diciembre"
End Select
x=1
%>

<HTML>
<HEAD>

</HEAD>

<BODY>
<table width="190" border="0" cellpadding="0" cellspacing="0" bordercolor="#50A9D3">
<tr bgcolor="#3399CC">
<td bgcolor="#3399CC">
<div align="center"><font color="#FFFFFF" face="Arial, Helvetica, sans-serif"><strong><%=anno%></strong></font> </div>
</td>
</tr>
</table>
<table width="190" border="0" cellpadding="0" cellspacing="0" bordercolor="#50A9D3">
<tr bgcolor="#3399CC">
<td width="20" bgcolor="#297BA3"><div align="center"><a href="eventos_calendario.asp?mese=<%if mese > 1 then response.write mese-1 else response.write 12 End If%>&anno=<%if mese > 1 then response.write anno else response.write anno-1 End If%>"><img src="imagenes/eventos_ant.png" width="12" height="11" border="0"></a></div></td>
<td bgcolor="#2F8CB9"><div align="center"><font color="#FFFFFF"><strong><%=tmese%></strong></font></div></td>
<td width="20" bgcolor="#297BA3"><div align="center"><a href="eventos_calendario.asp?mese=<%if mese < 12 then response.write mese+1 else response.write 1 End If%>&anno=<%if mese < 12 then response.write anno else response.write anno+1 End If%>"><img src="imagenes/eventos_sig.png" width="12" height="11" border="0"></a></div></td>
</tr>
</table>
</font>
<table width="190" border="0" cellpadding="0" cellspacing="0" bordercolor="#50A9D3">
<tr bgcolor="#3399CC">
<td bgcolor="#FFFFFF">
<table width="190" border="1" cellpadding="0" cellspacing="0">
<tr align="center">
<td bgcolor="#333333"><font color="#FFFFFF" size="2"><strong>L</strong></font></td>
<td bgcolor="#333333"><font color="#FFFFFF" size="2"><strong>M</strong></font></td>
<td bgcolor="#333333"><font color="#FFFFFF" size="2"><strong>M</strong></font></td>
<td bgcolor="#333333"><font color="#FFFFFF" size="2"><strong>J</strong></font></td>
<td bgcolor="#333333"><font color="#FFFFFF" size="2"><strong>V</strong></font></td>
<td bgcolor="#333333"><font color="#FFFFFF" size="2"><strong> S</strong></font></td>
<td bgcolor="#333333"><font color="#FFFFFF" size="2"><strong> D </strong></font></td>
</tr>
<tr>
<%
giorno1 = (day1-primog+x)
Do While giorno1 <= (dayoff+7-ultimog)
%>
<td <%If day(day1-primog+x)=day(now()) and month(day1-primog+x)=month(now()) then response.write "bgcolor=""#D6EAF5""" End If%><%If day(day1-primog+x)="25" and month(day1-primog+x)="3" then response.write "bgcolor=""#3399CC""" End If%>>

<div align="center"> <font color ="<%if giorno1 >= day1 and giorno1 <= dayoff then
response.write "#000000" ' Dias del mes
Else
response.write "#666666"' Dias del otro mes
End If%>">
<%if giorno1 >= day1 and giorno1 <= dayoff then%>
<a href="eventos_info.asp?dia=<%=day(day1-primog+x)%>&mes=<%=month(day1-primog+x)%>&ano=<%=year(day1-primog+x)%>" target="eventos_info"><font face="Arial, Helvetica, sans-serif" size="2"><b><%=day(day1-primog+x)%></b></font></a>
<%else%>
<%=day(day1-primog+x)%>
<%End If%>
</font></div>
</td>
<%If weekday(day1 - primog + x - 1) = 7 Then
response.write "</tr>"
End If%>
<%
giorno1 = giorno1 + 1
x=x+1
loop
%>

</table>
</td>
</tr>
</table>
</BODY>
</HTML>

A ver si me podeis ayudar.

Un saludo.

yakare84 · #2 (**permalink**) 22/03/2010, 11:56

luismi78,

Yo utilizo estilos, hago el IF pero segun lo que sea muestro un estilo u otro para mostrar el color. Tengo 2 tipos de actividades: una en color azul con un estilo y otra con color amarillo con otro estilo.

A vos no te está coloreando nada? o solo de un color?

Consejo: quizás fue cuando lo copiaste y pegaste en el post, pero sino, te recomiendo formatear el código, lo vas a entender mas facil y va a ser mas ordenado para buscar cosas.

Cita:

<td <%
If day(day1-primog+x)=day(now()) and month(day1-primog+x)=month(now()) then
response.write "bgcolor=""#D6EAF5"""
End If %>
<% If day(day1-primog+x)="25" and month(day1-primog+x)="3" then
response.write "bgcolor=""#3399CC"""
End If %>>

<div align="center">
<font color ="<%
if giorno1 >= day1 and giorno1 <= dayoff then
response.write "#000000" ' Dias del mes
Else
response.write "#666666"' Dias del otro mes
End If %>">
<% if giorno1 >= day1 and giorno1 <= dayoff then %>
<a href="eventos_info.asp?dia=<%=day(day1-primog+x)%>&mes=<%=month(day1-primog+x)%>&ano=<%=year(day1-primog+x)%>" target="eventos_info">
<font face="Arial, Helvetica, sans-serif" size="2">
<b><%=day(day1-primog+x)%></b></font></a>
<% else %>
<%=day(day1-primog+x)%>
<%End If%>
</font></div>
</td>

Viendo el código de esta manera nos encontramos que cuando pones el response.write para mostrar el bgcolor usas doble comillas, proba con comillas simples, ej: response.write "bgcolor='#3399CC'"

Fijate como te funciona eso y nos contas!!

Saludos!

luismi78 · #3 (**permalink**) 22/03/2010, 12:13

Muchas gracias yakare. Voy a probar lo que me comentas y os cuento como me ha ido

.

Un saludo.

luismi78 · #4 (**permalink**) 23/03/2010, 02:41

Hola de nuevo. Leyendo más detenidamente tu respuesta me he dado cuenta que no es exactamente lo que necesito. El problema no es que no sepa colorear las celdas, si no que no consigo resaltar solo los días en el calendario en los que hay alguna actividad.. Por ejemplo, si en la base de datos tengo que el dia 26 de marzo hay una actividad, que ese día me salga resaltado en el calendario.

Espero haberlo explicado bien

yakare84 · #5 (**permalink**) 23/03/2010, 07:12

Cuando comienza el Do While hay un pequeño problema. Tenes 2 if dentro de la celda que le indican 2 bgcolor distintos...

Hacé 2 cosas, saca el if de dentro de la celda y usa variables para guardar el color del background.

creaste una variable giorno1 y sin embargo estas poniendo en todos lados [day1-primog+x]

yo te separe el codigo de la celda, lo que deberias ver es reacomodar los 2 if que tenes para poner en una variable el color que deberia salir en pantalla.

Código:

 giorno1 = day1-primog+x
Do While giorno1 <= (dayoff+7-ultimog)
If day(giorno1)=day(now()) and month(giorno1)=month(now()) then 
  response.write "bgcolor=""#D6EAF5""" 
 End If
 If day(giorno1)="25" and month(giorno1)="3" then 
  response.write """#3399CC""" 
 End If %>
<td bgcolor="<% =color %>">

Espero haber ayudado! Saludos!

luismi78 · #6 (**permalink**) 23/03/2010, 09:04

Muchas gracias de nuevo yakare. Voy a probar lo que me comentas.

Un saludo.

Adler · #7 (**permalink**) 24/03/2010, 07:24

Hola

Y ya van dos veces hoy

Código ASP:

Ver original<%@LANGUAGE="VBSCRIPT" CODEPAGE="1252"%>
<% Option Explicit %>
<%
Dim oConn, SQL, rs, registros, j
Dim Fecha
Fecha = 0
'conexion
' ==== campos ===
'Fecha = 23/04/2010, 24/05/2010, .....
'AnyoMes = 20104, 20105, ....
' ============
 
SQL ="SELECT Fecha, AnyoMes FROM Calendario WHERE AnyoMes >= "&CInt(Year(Date)) & CInt(Month(Date))&"" 
set rs = oConn.Execute(SQL)
registros = rs.getrows()
rs.Close
Set rs = Nothing
oConn.Close
Set oConn = Nothing
 
Dim arreglo()
Redim arreglo(UBound(registros,2))
For j = 0 to UBound(registros,2)
arreglo(j) = registros(Fecha,j)
Next 'j
%>
<html>
<head>
<title>Horarios</title>
<meta http-equiv="Content-Type" content="text/html; charset=iso-8859-1">
<style type="text/css">
.calFondoCalendario {background-color:#EEEEEE;border: 1px solid #C9C9C9;border-width: 1px 1px 1px 1px;}
#calFondoMes {background-color:#C9C9C9;font-family:Arial, Helvetica, sans-serif; font-size:11px;font-weight:bold;text-align:center;}
.calFondoDias, .calFondoSemanas, .calFondoNumeroSemanas {background-color:#C9C9C9;font-family:Arial, Helvetica, sans-serif; font-size:9px; font-weight:900; }
#calDias, #calFinSemana {font-family:Arial, Helvetica, sans-serif; font-size:11px; font-weight:700;}
#calDias a:link, #calDias a:visited {color:#333333;text-decoration:none;}
#calDias a:hover, #calDias a:active {color:#333333;text-decoration:none;}
#calDiasMarcado, #calFinSemanaMarcado {background-color:#C9C9C9;font-family:Arial, Helvetica, sans-serif; font-size:11px; font-weight:700;}
#calDiasMarcado a:link, #calDiasMarcado a:visited {color:#FFFFFF;text-decoration:none;}
#calDiasMarcado a:hover, #calDiasMarcado a:active {color:#FFFFFF;text-decoration:none;}
#calFinSemanaMarcado a:link, #calFinSemanaMarcado a:visited {color:#FF0000;text-decoration:none;}
#calFinSemanaMarcado a:hover, #calFinSemanaMarcado a:active {color:#FF0000;text-decoration:none;}
#calFinSemana a:link, #calFinSemana a:visited {color:#FF0000;text-decoration:none;}
#calFinSemana a:hover, #calFinSemana a:active {color:#FF0000;text-decoration:none;}
.calDiaVacio {background-color:#FFFFFF;color:#C9C9C9;font-family:Arial, Helvetica, sans-serif; font-size:11px; font-weight:700;text-align:center;}
#paginador {background-color:#EEEEEE;height:30px;padding-top:7px;}
#paginador a:link, #paginador a:visited{background-color:#A4A4A4;color:#FFFFFF;font-family:Arial, Helvetica, sans-serif; font-size:9px; font-weight:900;text-decoration:none;padding:3px;border: 1px solid #C9C9C9;border-width: 1px 1px 1px 1px;}
#paginador a:hover, #paginador a:active{background-color:#EEEEEE;color:#333333;font-family:Arial, Helvetica, sans-serif; font-size:9px; font-weight:900;text-decoration:none;padding:3pxborder: 1px solid #C9C9C9;border-width: 1px 1px 1px 1px;}
</style>
</head>
<body bgcolor="#FFFFFF">
<%
Const URL = "OtraPagina.asp"
Dim Mes, ElMes 
Dim Anyo, ElAnyo 
Dim FechaInicio, FechaActual, FechaFinal 
Dim DiaActual
Dim i, SumarMesQuery, MesAnyo
Dim PrimerDiaMes
Dim Semana, nSemanas01, nSemanas31
Dim DiasMesSiguiente, DiasMesAnterior
Dim Columna, Fila
Dim UltimoDiaMesAnterior
Dim EstamosEnEl, cad
Dim unmesmenos, unmesmas, menos, mas, mesmenos, mesmas, anyomas, anyomenos
 
' Si viene vacía o no es numerica
If Request.Querystring("mes") = "" or Not IsNumeric(Request.Querystring("mes")) then 
Mes = CInt(Month(Date))
Else 
Mes = CInt(Request.Querystring("mes"))
End If
If Request.Querystring("anyo") = "" or Not IsNumeric(Request.Querystring("anyo")) then 
Anyo = CInt(Year(Date))
Else
Anyo = CInt(Request.Querystring("anyo"))
End If
FechaInicio = CDate("1/" & Month(Date) & "/" & Year(Date))
FechaActual = CDate("1/" & Mes & "/" & Anyo)
FechaFinal = DateAdd("m", 6, FechaInicio)
%>
<div style="background-color:#EEEEEE;padding-top:20px;border: 1px solid #C9C9C9;border-width: 1px 1px 1px 1px;">
<!-- Empezamos a montar el Calendario -->
<div id="ContenedorCalendario">
<table border="0" cellspacing="0px" cellpadding="0px" width="85%" align="center">
<tr>
<%
IF FechaActual > FechaFinal then ' Aún no ha progresado un año (empezó 01/03/2010 termina 01/09/2010)
%>
<td id="calFondoMes">No puede hacer una reserva con mas de 6 meses de antelación</td></tr></table>
<div id="paginador" align="center">
<a href="<%=Request.Servervariables("SCRIPT_NAME")%>?mes=<%=Month(FechaFinal)%>&anyo=<%=Year(FechaFinal)%>">Atr&aacute;s</a>
</div>
<%
ELSEIF FechaActual < FechaInicio then ' Se ha manipulado las var con una fecha menor a la de inicio (empezó 01/03/2010 quiere imprimir 01/02/2010)
%>
<td id="calFondoMes">No puede hacer una reserva con una fecha ya pasada</td></tr></table>
<div id="paginador" align="center">
<a href="<%=Request.Servervariables("SCRIPT_NAME")%>?mes=<%=Month(Date)%>&anyo=<%=Year(Date)%>">Atr&aacute;s</a>
</div>
<%
ELSE
For i = 0 to 2
SumarMesQuery = DateAdd("m", i, DateSerial(Anyo, Mes, 1))
MesAnyo = Split(SumarMesQuery,"/")
ElMes = MesAnyo(1)
ElAnyo = MesAnyo(2)
%>
<td> 
<table border="0" cellspacing="1px" cellpadding="3px" width="200px" align="center" class="calFondoCalendario">
<tr align="center">
<td colspan="8">
<div id="calFondoMes">
<%=Nombre_Mes(ElMes)%>,&nbsp;<%=ElAnyo%>
</div>
<%
Call Dias()
DiaActual = 1
PrimerDiaMes = DatePart("w", DateAdd("d", -1, DateSerial(ElAnyo, ElMes, 1)), vbMonday)
Semana = DatePart("ww", CDate("01/" & ElMes & "/" & ElAnyo), vbMonday, vbFirstFourDays) ' Número de la semana del mes actual
nSemanas31 = DatePart("ww", CDate("12/31/" & ElAnyo), vbMonday, vbFirstFourDays) 'Número de semanas del año
nSemanas01 = DatePart("ww", CDate("01/01/" & ElAnyo), vbMonday, vbFirstFourDays) 'Número de semana de la primera semana del año siguiente
DiasMesSiguiente = 0
For Fila = 0 to 5
%>
<tr height="20px">
<%
' ============== Número de la Semana ==============
IF Fila = 0 then 
If Semana = nSemanas01 then  'La última semana del año anterior comprende algún día del siguiente año
%>
<td class="calFondoNumeroSemanas"><%=Semana%></td>
<%
Else
%>
<td class="calFondoNumeroSemanas"><%if Len(Semana) = 1 then Response.Write "0"&Semana else Response.Write Semana end if%></td>
<%
End If
ELSE
If Semana >= nSemanas31 then 'Primera semana del año
Semana = 1
Else
Semana = Semana +1
End If
%>
<td class="calFondoNumeroSemanas"><%if Len(Semana) = 1 then Response.Write "0"&Semana else Response.Write Semana end if%></td>
<%
END IF
' ============== Fin  Número de la Semana ==============
For Columna = 0 to 6
IF Fila = 0 and Columna < PrimerDiaMes then ' No hay día
UltimoDiaMesAnterior = UltimoDia((ElMes-1),ElAnyo)
DiasMesAnterior = ((UltimoDiaMesAnterior - (PrimerDiaMes-1)) + Columna)
%>
<td class="calDiaVacio"><%=DiasMesAnterior%></td>
<%
ELSEIF DiaActual > UltimoDia(ElMes, ElAnyo) then ' No hay día
DiasMesSiguiente = DiasMesSiguiente +1
%>
<td class="calDiaVacio"><%=DiasMesSiguiente%></td>
<%
ELSE
EstamosEnEl = CDate(DiaActual & "/" & ElMes & "/" & ElAnyo)
cad = EstamosEnEl & " = " & Join(arreglo, " or " & EstamosEnEl & " = ")
%>
<td bgcolor="#FFFFFF" align="center">
<%
If Columna = 5 or Columna = 6 then ' es fin de semana
if eval(cad) Then ' lo marcamos con reservado
%>
<div id="calFinSemanaMarcado">
<a href="<%=URL%>?day=<%=DiaActual%>&month=<%=ElMes%>&year=<%=ElAnyo%>"><%=DiaActual%></a>
</div>
<%
else
%>
<div id="calFinSemana">
<a href="<%=URL%>?day=<%=DiaActual%>&month=<%=ElMes%>&year=<%=ElAnyo%>"><%=DiaActual%></a>
</div>
<%
end if
Else
if eval(cad) Then ' lo marcamos como reservado
%>
<div id="calDiasMarcado">
<a href="<%=URL%>?day=<%=DiaActual%>&month=<%=ElMes%>&year=<%=ElAnyo%>"><%=DiaActual%></a>
</div>
<%
else
%>
<div id="calDias">
<a href="<%=URL%>?day=<%=DiaActual%>&month=<%=ElMes%>&year=<%=ElAnyo%>"><%=DiaActual%></a>
</div>
<%
end if
End If
%>
</td>
<%
DiaActual = DiaActual +1
END IF
Next ' Columna
%>
</tr>
<%
Next ' Fila
%>
</table></td>
<%
Next 'i
%>
</tr>
</table>
</div>
<!-- Fin Calendario -->
<!-- Paginador  -->
<div id="paginador" align="center">
<%
unmesmenos = DateAdd("m", -3, DateSerial(ElAnyo, ElMes, 1))
unmesmas = DateAdd("m", -1, DateSerial(ElAnyo, ElMes, 1))
menos = split(unmesmenos, "/")
mas = split(unmesmas, "/")
mesmenos = menos(1)
anyomenos = menos(2)
mesmas = mas(1)
anyomas = mas(2)
%>
<a href="<%=Request.Servervariables("SCRIPT_NAME")%>?mes=<%=mesmenos%>&anyo=<%=anyomenos%>">Anterior</a>
<a href="<%=Request.Servervariables("SCRIPT_NAME")%>?mes=<%=mesmas%>&anyo=<%=anyomas%>">Siguiente</a>
</div>
<%
END IF
%>
</div>
<!-- Fin Paginador  -->
</body>
</html>
<%
Sub Dias()
%>
</td>
</tr>
<tr align="center">
<td rows="6"><div class="calFondoSemanas">Sem</div></td>
<td><div class="calFondoDias">Lun</div></td>
<td><div class="calFondoDias">Mar</div></td>
<td><div class="calFondoDias">Mi&eacute;</div></td>
<td><div class="calFondoDias">Jue</div></td>
<td><div class="calFondoDias">Vie</div></td>
<td><div class="calFondoDias">S&aacute;b</div></td>
<td><div class="calFondoDias">Dom</div></td>
</tr>
<%
' Sub y Funciones
End Sub
 
Function Nombre_Mes(ElMes)
Select Case ElMes
Case 1
Nombre_Mes = "Enero"
Case 2
Nombre_Mes = "Febrero"
Case 3
Nombre_Mes = "Marzo"
Case 4
Nombre_Mes = "Abril"
Case 5
Nombre_Mes = "Mayo"
Case 6
Nombre_Mes = "Junio"
Case 7
Nombre_Mes = "Julio"
Case 8
Nombre_Mes = "Agosto"
Case 9
Nombre_Mes = "Septiembre"
Case 10
Nombre_Mes = "Octubre"
Case 11
Nombre_Mes = "Noviembre"
Case 12
Nombre_Mes = "Diciembre"
Case Else
Nombre_Mes = "ERROR!"
End Select
End Function
 
Function UltimoDia(ElMes, ElAnyo)
Select Case ElMes
Case 1, 3, 5, 7, 8, 10, 12
UltimoDia = 31
 
Case 4, 6, 9, 11
UltimoDia = 30
 
Case 2
If IsDate(ElAnyo & "-" & ElMes & "-" & "29") Then UltimoDia = 29 Else UltimoDia = 28
 
Case Else
UltimoDia = 31
End Select
End Function
%>

Suerte