Ejecutar exe y pasarle archivo txt

[sqa212]

Tengo un archivo exe al que soltandole encima un archivo txt me devuelve un archivo en otro formato. (esto lo hago manualmente)

Estoy intentando abrir el archivo exe y pasarle un fichero de texto desde asp, trabajando desde el propio pc el localhost este es el codigo:

<%
Dim wshell, intReturn
set wshell = server.createobject("wscript.shell")
intReturn = wshell.run("c:\carpeta\miejecutable.exe > c:\carpeta\miarchivo.txt", 0, True)
Response.Write( intReturn )
set wshell = nothing
%>

intReturn me devuelve 0, y no se me crea el archivo resultante,
¿alguien sabe que hago mal?

[monkyta]

El Disco C que se hace mención siempre será el del Server; nunca el del PC en donde estás cargando la página; por lo que para que funcione eso, debes de tener la carpeta llamada "carpeta" en el disco C del server, con el ejecutable en dicha carpeta y ser este directorio uno más del Sitio en donde quieres crear el archivo.... por otro lado debes de dar control total a esa carpeta para que se genere ese archivo al usuario anonimo

Mira acá tengo un ejemplo en donde doy Control Total a una carpeta XXXXX usando el wshell; ejecutando el comando CALC ; para dar los permisos correctos NTFS.... fijate que uso el Server.MapPath ... etc

' Da Control Total a Directorio Asignado

On Error Resume Next

nm_directorio = server.MapPath("/") & "\" & frm_categ
arch = server.MapPath("/") & "\temp.txt"
map = """" & nm_directorio & """"
comando = "cmd /c echo y| CACLS"
comando = comando & " " & map
comando = comando & " /t /e /p " & frm_login & ":f"
comando = comando & " > " & arch

set objwsh = Server.CreateObject("WScript.Shell")
objcom = objwsh.Run (comando, 0 , True)
set objwsh = Nothing
if (err.number <> 0) then
msg = "ERROR AL DAR CONTROL TOTAL" & hex(err.number) & " - " & err.description & " ***"
response.redirect.....
end if


Espero te ayude

[sqa212]

Gracias por tu ayuda monkyta

Obtego este mensaje de error:

msg = ERROR AL DAR CONTROL TOTAL 46 - Permiso denegado ***
Conn el codigo que has puesto se intenta dar permisos a la carpeta:

c:\inetpub\wwwroot\

Aunque no haya funcionado correctamente el script, me ha sido muy clarificadora tu respuesta, gracias.

[monkyta]

Me faltó decirte lo siguiente.... para usar el comando CALC debes de hacerlo autentificado con un usuario con perfil de Administrador..... en realidad yo uso esa página que te envié parte del código usando Autentificacion Basica; con un login con perfil de administrador.... de otra manera es imposible

saludos

[sqa212]

Hola monkyta,
Perdona por no contestarte antes, ayer me fue imposible. No se a que puede deberse el usuario con el que etoy en el pc es el administrador del equipo pero obtengo el error de Permiso denegado.
Seguire investigando Gracias de nuevo por tu ayuda.

[sqa212]

He conseguido por fin ejecutar el archivo exe en el localhost y pasarle el archivo txt.

<%
programa="programa1"
archivo="probando.txt"
rutaprograma=server.MapPath(".") & "\" & programa
rutayarchivo=server.MapPath(".") & "\" & archivo
sExecStr = rutaprograma & " " & rutayarchivo
Response.Write sExecStr &"<br>"
Set oShell = Server.CreateObject("WScript.Shell")
Set oExec = oShell.Exec(sExecStr)

Do While oExec.Status = 0
Response.Write "Esperando oExec.Status " & oExec.Status &"<br>"
Loop
Response.Write "<b>oExec.Status " & oExec.Status &"</b><br>"

Do While Not oExec.Stdout.atEndOfStream
tmpStr = oExec.StdOut.Read(1)
if tmpStr = Chr(13) then tmpStr = "<BR>" & tmpStr
Response.Write tmpStr
Response.Flush()
Loop

RetCode = oExec.stderr.readall
Response.Write RetCode
Response.Write "<br>oExec.Status " & oExec.Status
%>


Esto es lo que me arroja:

INPUT:
1) "c:\inetpub\wwwroot\webexe\probando.txt" (ASC file)
OUTPUT:
1) "c:\inetpub\wwwroot\webexe\probando.inc"
2) "c:\inetpub\wwwroot\webexe\probando.bmp"
Error, could not open output file

En realidad deberia aparecer: (es lo que ocure cuando uso la linea de comandos)
Creating file "c:\inetpub\wwwroot\webexe\probando.bmp"
1 archivos copiados.

A ver si alguien me aclara un poco que ocurre y si ahi solucion pra esto, estoy empezando a pensar que quizas no es posible lo que intento hacer.
Mezcla de emociones!
Contento por conseguir ejecutar el programa y triste por que no funcione.

[monkyta]

Haces algo mal.....

Para probar desde la consola MSDOS en forma exacta lo que quieres hacer desde tu página haz el response.write de todo el comando completo y response.end.... con lo que salga intentalo por DOS a ver si hace algo.... ese error que da es porque está tratando de generarse un archivo vacío.... revisa bien.... te falta poco.... animo que se puede.... todo se puede

[sqa212]

He pensado que lo mejor es explicaros a todos lo que estoy intentando hacer,
me parece super interesante y creo que puede ser muy util y con infinidad de posibles utilidades.

Quizas le interese a alguien más y podamos entre todos los interesados lograrlo.

El objetivo es a traves de archivos de texto (.txt) obtener archivos en formato .ov2 y .bmp.

Os explico los archivos en formato .ov2 son POI de TomTom Navigator POI (Points of Interest).

Hay un archivo .exe que es el que se encarga de convertir los archivos .txt en archivos .ov2 y .bmp
Este archivo es: makeov2.exe

Se puede descargar desde:http://www.tomtom.com/support/ce/sup...v_poi.php#poi4
donde pone Download ov2tools.zip version 1.22 (58 kb)

La descarga directa seria: http://www.tomtom.com/support/ce/sup...2/ov2tools.zip

Lo descomprimis y encotrareis el archivo makeov2


Los archivos archivos .ov2 y .bmp se pueden introducir en el gps y consigues que te avise con un sonido y mostrando la imagen del archivo .bmp
cuando te encuentras a un radio que tu determinas de los puntos de interes que hallas introducidos.

El archivo micasa.txt contiene la longitud, la latitud y el nombre del punto de interes, el contenido por ejemplo puede ser:

-3.67845 , 38.40622 , "Piso"


Todos los archivos han de estar en la misma carpeta:

Supongamos: c:\inetpub\wwwroot\webpuntosdeinteres\webroot\

para conseguir los archivos hay distintas formas:

1. - Arrastrando el archivo .txt sobre el archivo exe makeov2

2.- Escribiendo en la consola de msdos:
c:\inetpub\wwwroot\webpuntosdeinteres\webroot\make ov2 c:\inetpub\wwwroot\webpuntosdeinteres\webroot\mica sa.txt

3.- Desde ASP?

Este es el codigo que uso:


<%@LANGUAGE="VBSCRIPT" CODEPAGE="1252"%>
<%
Response.Expires = 0
Response.Buffer = True
%>
<html>
<head>
<meta http-equiv="Content-Type" content="text/html; charset=iso-8859-1">
<title></title>
</head>
<body>
<%
archivo="micasa.txt"
rutaprograma=server.MapPath(".") & "\makeov2"
rutayarchivo=server.MapPath(".") & "\" & archivo
sExecStr = rutaprograma & " " & rutayarchivo
Response.Write sExecStr &"<br>"
Set oShell = Server.CreateObject("WScript.Shell")
Set oExec = oShell.Exec(sExecStr)
Do While oExec.Status = 0
Response.Write "Esperando oExec.Status " & oExec.Status &" Hora:" & now &"<br>"
Response.Flush()
Loop
Do While Not oExec.Stdout.atEndOfStream
tmpStr = oExec.StdOut.ReadAll()
Response.Write tmpStr
Response.Flush()
Loop

RetCode = oExec.stderr.readall
Set oShell=Nothing
Response.Write RetCode
Response.Write "<br>oExec.Status " & oExec.Status
%>
</body>
</html>

Y el resultado es:

c:\inetpub\wwwroot\webpuntosdeinteres\webroot\make ov2 version 1.1

INPUT:
1) "c:\inetpub\wwwroot\webpuntosdeinteres\webroot\mic asa.txt" (ASC file)

OUTPUT:
1) "c:\inetpub\wwwroot\webpuntosdeinteres\webroot\mic asa.ov2"
2) "c:\inetpub\wwwroot\webpuntosdeinteres\webroot\mic asa.bmp"

Error, could not open output file intermediate\poi.9999



Por lo que se consuigue ejecutar el archivo makeov2.exe, pasarle el archivo .txt, que lo ejecute, pero no se obtienen los archivos .ov2 y .bmp resultantes.


Nota:
Para evitar el error de Permiso denegado debes de hacerlo autentificado con un usuario con perfil de Administrador.

Le he dado todos los permisos posibles en la carpeta webpuntosdeinteres y todo su contenido
a la cuenta de invitado de internet nombrePc\IUSR_nombrePc

Bueno hasta aqui he llegado,

Ojala alguien tenga alguna idea de que mas hacer

[monkyta]

El permiso a la carpeta en donde generarás los archivos debes de darlo al usuario con el cual estás trabajando; ese con perfil de administrador; no al usuario anonimo... ese es el problema..... dale permiso NTFS de Control Total al usuario autentificado que usas para llamar a esa página... eso es todo... ya hiciste lo más dificil; falta solo la parte de los permisos..... ese error que da es porque no puede grabar el archivo de salida por falta de permiso....

[sqa212]

monkyta Gracias por responder, no creo que sea por falta de permisos, le he dado permisos a en la pestaña de seguridad a todos los usuarios todos los permisos posibles, pero sigue el mismo error:

Error, could not open output file intermediate\poi.9999

¿Lo has probado tu y te ha funcionado?
Me llevaria una inmensa alegria si asi fuera, ya que veria que hay algo que no hago bien pero que es posible. Ya creia que nadie responderia a este post. Gracias de Nuevo

[gmoreno]

Hola, estoy intentando llamar a un bat desde asp pero con el codigo que os pongo y con el de este tema me pasa siempre lo mismo, la pagina que se queda pensando hasta que me deja tieso el IIS.
Os paso el codigo por si os sirve.
<%
dim objShell
Set objShell = CreateObject("WScript.Shell")
objShell.run "d:\ejecuta_dts.bat",3,false
set objShell = nothing
%>
He probado con true tambien he probado con muchos codigos del estilo pero ninguno funciona en todos ocurre lo mismo se queda pensando.
Gracias

[monkyta]

Se queda colgado porque te faltan permisos...

Primero debes de llevar ese bat que quieres ejecutar a una carpeta del Sitio; para que puedas darles los permisos necesarios por IIS

Por el explorador de Windows llegas a esa carpeta y vas a la carpeta seguridad y agregas al usuario anonimo ; que es IUSR_nombremaquina; luego lo marcas y en la parte de abajo le das los permisos

Luego vas a la consola MMC del IIS y vas al directorio en donde estará el bat que vas a ejecutar y das click derecho propiedades.... acá vas adonde dice Permisos de Ejecucion... alli debes de dar permisos para leer y ejecutar script... el defecto no es ejecutar...

Eso es todo

[movidita]

sqa212, estoy en la misma situación que tu, y no hay manera de avanzar...el dixoso error: "Error, could not open output file intermediate\poi.9999"

Y no hay manera...Habeis conseguido algo vosotros?

[sqa212]

actualmente sigo en la misma situacion

[movidita]

He probado con dynuexec con el siguiente codigo:

<%
Set myexec = Server.Createobject("Dynu.Exec")
Response.Write("<PRE>")
aejecutar=Server.MapPath("makeov2.exe intermedio.asc")
response.write(myexec.execute(aejecutar))
Response.Write("</PRE>")
Set myexec = nothing
%>

y me devuelve esto:

E:\pois\makeov2.exe version 1.1
INPUT:
1) "intermedio.asc" (ASC file)
OUTPUT:
1) "intermedio.ov2"
2) "intermedio.bmp"
Error, could not open input file intermedio.asc

creo que voy para atras en vez de para adelante...
habeis probado con el aspexec?
Un saludo

[Myakire]

Esto esta fàcil

Solo pon estas dos lineas de código y veras como funciona lo que necesitas (ya lo probé)

set objShell = CreateObject("Shell.Application")
objShell.ShellExecute "makeov2.exe", "micasa.txt", "C:\Inetpub\wwwroot\MisPruebas\Ejecutar", "open", 1

Se que es innecesario decirte que hay que cambiar el tercer parámetro que indica el directorio de trabajo, pero igual lo hago

Saludos

[sqa212]

Myakire me repondistes a mi pregunta, no te entendi

[Myakire]

Solo pon estas dos lineas de código y veras como funciona lo que necesitas (ya lo probé)

mmmm, ¿qué parte de esto no fue clara?

Con esas dos lineas de código ejecutas el makeov2.exe, enviándole tu archivo micasa.txt como parámetro que se encuentran en el directorio (en mi caso) C:\Inetpub\wwwroot\MisPruebas\Ejecutar.

Te genera un bmp con una figurilla parecida a un asterisco y un archivo .ov2

Pruébalas, solo ponlas en un archivo .asp, correlo en el directorio donde ya no te marca error de permisos tu código anterior (que no ejecuta el .exe como deseas) y listo, problema resuelto

Saludos

[movidita]

mmm Perfecto ahora tengo otro problemilla, el fichero que lee el makeov2 lo genero mediante codigo:

corx=request.form("corx")
cory=request.form("cory")
nombre=request.form("nombre")
archivo= request.serverVariables("APPL_PHYSICAL_PATH") & "intermedio.asc"
set confile = createObject("scripting.filesystemobject")
set fich = confile.CreateTextFile(archivo)
aescribir=corx & ", " & cory & ", " & nombre & "" & chr(13)
fich.write(aescribir)
fich.close()

el problema es que parece que me deja el archivo abierto porque el makeov2 no trabaja con el, me devulve el .bmp pero no el .ov2, sin embargo si abro el archivo intermedio.asc (que es el que lee el makeov2) le doy a guardar cambios (aunque no haya hecho ningun cambio) lo cierro y ejecuto el script, funciona a la perfeccion.
con la sentencia fich.close() deberia de cerrar el archivo, ¿verdad?
no se lo que esta pasando...ayuda please!!!
Un saludo

[sqa212]

Gracias Myakire

como dijo einstein "Make everything as simple as possible, but not simpler".

Te expreso mis mas enormes agradecimientos y admiración.

Esta seria otra forma pero usando el server.MapPath tambien funciona

<%
set objShell = CreateObject("Shell.Application")
ruta=server.MapPath(".")
objShell.ShellExecute "makeov2.exe", "micasa.txt", ruta, "open", 1
%>

[Myakire]

Que bueno que te sirvió, por lo del MapPath, en efecto, funciona; aunque otra alternativa puede ser Request.ServerVariables("PATH_TRANSLATED")

Por lo de generar el archivo con FSO, no le veo problema, en una chance que tengo lo probarè también pero no debe haber problema

Saludos

[vrm184]

Despues de mucho buscar por Foros e Internet no encontré nada hasta que me puse a probar por mi cuenta y con lo siguiente me funcionó!!!

Para tener permiso de ejecución lo que se debe hacer es en Internet Explorer en Herramientas-> Opciones de Internet -> Seguridad-> Sitios de confianza. Una vez añadido el sitio en Nivel personalizado hablitar la opcion "Inicializar y generar escripts de los controles ActiveX no marcados como seguros para scripts"

[Adler]

Hola, bienvenido al foro

Iniciado por vrm184

Despues de mucho buscar por Foros e Internet no encontré nada hasta que me puse a probar por mi cuenta y con lo siguiente me funcionó!!!

Para tener permiso de ejecución lo que se debe hacer es en Internet Explorer en Herramientas-> Opciones de Internet -> Seguridad-> Sitios de confianza. Una vez añadido el sitio en Nivel personalizado hablitar la opcion "Inicializar y generar escripts de los controles ActiveX no marcados como seguros para scripts"

De eso hace ya 3 años

[daniellopez]

buen día encontré este blog al buscar ayuda para mi error:

Tengo un ws que manda a llamar a un .bat y ese a su vez ejecuta un .exe

Pruebo el .bat y funciona genial, al igual si pruebo el ws en visual studio, pero cuando lo pongo en el iis no ejecuta el exe y el administrador de tareas se queda abierto el proceso de ese exe.

Que puedo hacer?


Saludos.