Error al crear archivo en modo ASCII y escribir contenido

[angel_dope]

Hola a tod@s, tengo un problema al que no encuentro solución. Os explico el proceso: hago una llamada a un webservice para descargar el contenido de un archivo pdf. A continuación creo un archivo nuevo y le meto ese contenido. Si lo hago en modo unicode, no hay problema, se crea y se rellena perfectamente peeeero, al ser un archivo firmado digitalmente se invalida la firma.
Por lo que he averiguado, el archivo se debe crear en formato ASCII para que esto no pase pero se me presenta un nuevo problema. Si creo un archivo en este formato y escribo cualquier cosa, va bien; sin embargo, si intento escribir el contenido que he descargado me da un error. Os adjunto el código y el error, a ver si a alguien se le ocurre como solucionarlo.

Código:

Código PHP:

  <% 
        Set objWinHttp4 = Server.CreateObject("WinHttp.WinHttpRequest.5.1")         
        objWinHttp4.Open "GET", "http://www.dominio.com/aplicacion/v1/docs/260.pdf"  
        objWinHttp4.setRequestHeader "Content-type", "application/pdf" 
        objWinHttp4.SetCredentials "usuario","password",HTTPREQUEST_SETCREDENTIALS_FOR_PROXY 
        objWinHttp4.Send  
        texto = objWinHttp4.responsebody 
 
        nombre = "260.pdf" 
 
        dim fs,f 
        set fs=Server.CreateObject("Scripting.FileSystemObject") 
        set f=fs.openastextstream(Server.MapPath("./pruebas/"&nombre),2,true,-2) 
        f.write(texto) ---> LINEA DEL ERROR 
        f.Close 
        set f=Nothing 
        set fs=Nothing 
 
%>  
   

Error

Microsoft VBScript runtime error '800a0005'

Invalid procedure call or argument

/serviciosonline/informeslab/prueba2.asp, línea 18

[angel_dope]

He encontrado una solución, lo malo es que es muuuy lenta, ya que por lo que veo va escribiendo caracter a caracter y tarda bastante, sobre todo si el archivo es muy gordo. Hay alguna forma de escribirlo de golpe??

Os dejo el código que tengo ahora:

Código PHP:

  set ofs=Server.CreateObject("Scripting.FileSystemObject")
Set ofile = oFS.createTextfile(server.mappath("./pruebas/algo.pdf"), True) 
For nIndex = 1 to LenB(texto) 
ofile.write Chr(AscB(MidB(texto,nIndex,1))) 
Next  
   

[angel_dope]

Nadie sabe como hacerlo de golpe?? Es que con este metodo lleva casi dos horas y apenas ha escrito 900 Kb. Lo extraño es que para archivos pequeños (sobre unos 400 Kb) lo hace en unos 30 segundos. Sin embargo con los archivos un poco más grande (de 1'5 a 2 Mb) tarda un montón.

[bebo]

Utiliza este código:

Código ASP:

<&#37;
        Set objWinHttp4 = Server.CreateObject("WinHttp.WinHttpRequest.5.1")         
        objWinHttp4.Open "GET", "http://www.dominio.com/aplicacion/v1/docs/260.pdf"  
        objWinHttp4.setRequestHeader "Content-type", "application/pdf" 
        objWinHttp4.SetCredentials "usuario","password",HTTPREQUEST_SETCREDENTIALS_FOR_PROXY 
        objWinHttp4.Send  
        texto = objWinHttp4.responsebody 
Set ado=Server.CreateObject("ADODB.Stream")
ado.type=1
ado.open
ado.write texto
ado.savetofile server.mappath("nombre.pdf")
ado.close
%>
 

El objeto ADODB.Stream convierte el texto mucho mas rápido que fso.

[angel_dope]

Vaya, de esta forma es instantáneo!!! Muchas gracias por la ayuda y perdón por tardar en responder, es que estaba de viaje y no lo he podido probar hasta ahora.

Salu2

[sjam7]

hola, oye, podrias poner un ejemplo de como llamar a un webservice con asp?

[angel_dope]

Pues depende del tipo de webservice, en este caso, la llamada es como se ve en el código:

Código ASP:

Set objWinHttp4 = Server.CreateObject("WinHttp.WinHttpRequest.5.1")         
        objWinHttp4.Open "GET", "http://www.dominio.com/aplicacion/v1/docs/260.pdf"  
        objWinHttp4.setRequestHeader "Content-type", "application/pdf" 
        objWinHttp4.SetCredentials "usuario","password",HTTPREQUEST_SETCREDENTIALS_FOR_PROXY 
        objWinHttp4.Send
 

En este caso llamas al webservice para descargar el contenido de un archivo pdf