Error al enviar mail

[tomchat]

Tengo un error al momento que quiero enviar un correo.

Origen = Request.Form("origen")
Destino = Request.Form("destino")
Asunto = Request.Form("asunto")
Mensaje = Request.Form("mensaje")

Set myMail=CreateObject("CDO.Message")
myMail.Subject = asunto
myMail.From = origen
myMail.To="[e-mail]"
myMail.TextBody = mensaje
myMail.Send
set myMail=nothing

Tipo de error:
CDO.Message.1 (0x80040220)
No es válido el valor de configuración "SendUsing".

Creo que no esta comportandose bien el componente o la configuración no esta bien dada.

Gracias por su tiempo.

[u_goldman]

Con CDO necesitas especificar el puerto por el que se envia.

http://www.aspfaq.com/show.asp?id=2026

[tomchat]

has bien creo que tiene que ver con la configuracion del maldito dominio y del componente. Y como especifico el puerto.

[tomchat]

System.Web.Mail, esta clase es parte de ASP.NET ?

[u_goldman]

Código:

sch = "http://schemas.microsoft.com/cdo/configuration/"
Set cdoConfig = CreateObject("CDO.Configuration") 
 
    With myMail.Fields 
        .Item(sch & "sendusing") = 2 ' cdoSendUsingPort 
        .Item(sch & "smtpserver") = "[email protected]" 
        .update 
    End With

[monkyta]

Aca te mando una pagina de prueba que funciona con el componente sin ningun problema..... debes de cambiar los TO, FROM y el servidor SMTP.... en este caso estoy usando mi server remoto SMTP; para usar tu server local seria
.Item(cdoSendUsingMethod) = 1
.Item(cdoSMTPServer) = "localhost"

<!--
METADATA
TYPE="typelib"
UUID="CD000000-8B95-11D1-82DB-00C04FB1625D"
NAME="CDO for Windows 2000 Library"
-->
<%
dim cdoMessage, cdoConfig
Set cdoConfig = CreateObject("CDO.Configuration")

With cdoConfig.Fields
.Item(cdoSendUsingMethod) = 2
.Item(cdoSMTPServer) = "xxxxx.xxx.cl"
.Update
End With

Set cdoMessage = CreateObject("CDO.Message")

With cdoMessage
Set .Configuration = cdoConfig
.From = "[email protected]"
.To = "[email protected]"
.Subject = "Prueba"
.TextBody = "Este es un mensaje de prueba"
.Send
End With

Set cdoMessage = Nothing
Set cdoConfig = Nothing
%>

[tomchat]

Yo Utilizo esta configuració, pero no me funciona:

Set Mail = Server.createObject("CDO.Message")
Set Config = Server.createObject ("CDO.Configuration")
With Config
.Fields("http://schemas.microsoft.com/cdo/con...ion/smtpserver") = "vir.midominio.com"
.Fields("http://schemas.microsoft.com/cdo/con...smtpserverport") = 25
.Fields("http://schemas.microsoft.com/cdo/con...tion/sendusing") = 2
.Fields("http://schemas.microsoft.com/cdo/con...nectiontimeout") = 60
.Fields.update
End With
Set Mail.Configuration = Config

Y me Genera este error con esta configuración:

Tipo de error:
CDO.Message.1 (0x80040220)
No es válido el valor de configuración "SendUsing".


Voy a Probar lo que me dierón Gracias...

[tomchat]

Ya prove tu codigo monkita pero genera error.

[tomchat]

El hice algunas modificaciones y ahora me genera el siguiente error:

Tipo de error:
(0x8004020F)
La clase de suceso para esta suscripción está en una partición no válida


Y el código es este:

Set myMail = Server.createObject("CDO.Message")
Set Config = Server.createObject ("CDO.Configuration")
With Config
.Fields("http://schemas.microsoft.com/cdo/con...ion/smtpserver") = "localhost"
.Fields("http://schemas.microsoft.com/cdo/con...smtpserverport") = 25
.Fields("http://schemas.microsoft.com/cdo/con...tion/sendusing") = 2
.Fields("http://schemas.microsoft.com/cdo/con...nectiontimeout") = 60
.Fields.update
End With

Set myMail.Configuration = Config

myMail.Subject = asunto
myMail.From = origen
myMail.To="[email protected]"
myMail.TextBody = mensaje
myMail.Send
set myMail=nothing

[u_goldman]

Este error indica que hay un problema tu servidor:

# Make sure the SMTP server allows anonymous (non-authenticated) relaying. If your SMTP requires outgoing authentication, see Article #2026.

# Check if the problem is specific to the domain name(s) used in the e-mail addresses of the recipients. For example, some users have complained that they can send to users on their own domain only; others have said that they can send to any domain except their own (see Article #2511 for some potential causes and solutions).

# It may be simply that the e-mail address is being rejected, but other configuration settings on the SMTP server are preventing the true error message from being relayed propely back to the ASP script ... so verify that the address is valid.

# If you have a proxy or firewall, make sure the web server is set up to correctly pass through it, that the SMTP server knows about it, and that the proxy allows access to port 25.

# Try using a SendUsing value of 1 (pickup) instead of 2 (port). E.g. the following line:

.Item(cdoSendUsingMethod) = cdoSendUsingPort

Becomes

.Item(cdoSendUsingMethod) = cdoSendUsingPickup

fuente:
http://www.aspfaq.com/show.asp?id=2305

Salu2,

[monkyta]

Para localhost debes de usar sendusing = 1 .... eso indica local
Que problema te dio con el envio de correo ?... a mi me funciona super bien... solo que la pagina que te mande sirve para usar servidor SMPT remoto (sendusing = 2)......

[tomchat]

Colocandole el valor al (sendusing = 1)...... me genera este error:

Tipo de error:
CDO.Message.1 (0x80040222)
Es necesaria la ruta de acceso del directorio de recogida, pero no se especificó.

[tomchat]

OK Monkyta me genera este error tu pagina:

Tipo de error:
CDO.Message.1 (0x80040213)
Error de transporte en la conexión al servidor.

Yo creo que no se puede conectar con el servidor para externos para enviar el correo.

Sigo intentando.

[u_goldman]

# Check if the problem is specific to the domain name(s) used in the e-mail addresses of the recipients. For example, some users have complained that they can send to users on their own domain only; others have said that they can send to any domain except their own (see Article #2511 for some potential causes and solutions).

[tomchat]

Monkyta colocandole estas modificaciones

.Item(cdoSendUsingMethod) = 1
.Item(cdoSMTPServer) = "localhost"

Genera este error el mismo que mi codigo:

Tipo de error:
CDO.Message.1 (0x80040222)
Es necesaria la ruta de acceso del directorio de recogida, pero no se especificó.

Diganme como configuro mi SMTP y mi dominio para no tener problema con esto, y es que la verdad que no tengo mucha experiencia con esta parte de dominios y SMTP.

[tomchat]

U Goldman gracias por esa documentación. Pero la verdad es que tiene el mismo codigo que el mio y hablan de tener que colocar el puerto y otras cosas.

[u_goldman]

No, lo que dice es que verifiques si es problema de tu dominio y hay mucha documentacion al respecto, es claro que tu codigo no tiene el problema, el problema esta en el servidor o en el lado de la resolucion del dominio.

[tomchat]

PS Si, el problema esta en el servidor:

Para que tengan una idea estoy trabajando en una Red LAn la cual se conecta con un proxy para el internet y estoy desarrollando este proyecto el cual necesita enviar E-mail, bien pero lo estoy provando desde una maquina cliente en XPPRO... y con el IIS. Y l verdad no se como configurar mi dominio para poder enviar E-Mails.

Espero solucionar pronto esto. Gracias por su tiempo.

[u_goldman]

je je je:

# If you have a proxy or firewall, make sure the web server is set up to correctly pass through it, that the SMTP server knows about it, and that the proxy allows access to port 25.

En fin, aqui seguramente esta todo lo que necesitas, solo es cuestion de leer.

Salu2,

[tomchat]

No le veo la gracia, pero por hay no va la cosa con el mensaje puesto por u_goldman .

Bueno tendre que hacer las pruebas al momento de subir la pagina al servidor.

Gracias a todos por su tiempo.

Y si le indico el puerto, gracias mil veces otra ves por decirlo.

[monkyta]

Tomchat ahora que entendi mas como tienes tu red, te aclaro que el problema que te estaba dando es porque estabas tratando de usar un servidor SMTP local que no existe en tu PC o bien que puede existir pero el Servicio estaba abajo; por lo que debes de usar tu server SMTP de tu empresa, para lo cual debes de poner o en esos parametros que te di o la direccion IP (pone la direccion interna) de tu server SMTP o el DNS; ademas, de poner el parametro sendusing = 2.
Eso es por un lado, lo otro que debes de chequear es que tu firewall no tenga bloqueda la puerta 25 y tambien debes de consultar al ingeniero de sistemas o al encargado de sistemas que permita a tu pc enviar correos.
Eso es lo que puedo indicarte por ahora.....

Avisame despues como vas

Saludos

[u_goldman]

Iniciado por tomchat

No le veo la gracia, pero por hay no va la cosa con el mensaje puesto por u_goldman .

Bueno tendre que hacer las pruebas al momento de subir la pagina al servidor.

Gracias a todos por su tiempo.

Y si le indico el puerto, gracias mil veces otra ves por decirlo.

Pues la gracia reside en que en lugar de molestarte, deberias de leer lo que se te proporciona, ahi esta paso a paso descrito tu problema, pero sabes, tienes razon, para que molestarse mil veces en citar lo ya citado si de todas maneras es inutil...en fin, suerte con tu problema y todos los posteriores

[tomchat]

Ok gracias Monkyta, si ps eso pensava hacer ya que tambien el proxy esta dando problemas, ya que tengo que desconectarlo para trabajar con el IIS. OK mañana mismo lo prueba, ya que tengo que entregar el proyecto por la tarde.

Gracias.

[tomchat]

PS U_goldman si he leido la documentacion puesta por tu persona, y no me molesta que te cause gracia lo que expreso en este foro, Ok gracias por la documentacion. Y si me servio de ayuda no crea te desconosco de tal fuente.

[tomchat]

Gracias Monkyta por tu ayuda, ya pude enviar el mail, le cambie el STMP local por el de la empresa. Aqui esta el codigo para todo el foro. Y si envia sin error jaja.

<%
Origen = Request.Form("origen")
Destino = Request.Form("destino")
Asunto = Request.Form("asunto")
Mensaje = Request.Form("mensaje")
Destino ="[e-mail]"
Set myMail = Server.createObject("CDO.Message")
Set Config = Server.createObject ("CDO.Configuration")
With Config
.Fields("http://schemas.microsoft.com/cdo/configuration/smtpserver") = "www.alumnos.abaco-corp.edu.pe"
.Fields("http://schemas.microsoft.com/cdo/configuration/smtpserverport") = 25
.Fields("http://schemas.microsoft.com/cdo/configuration/sendusing") = 2
.Fields("http://schemas.microsoft.com/cdo/configuration/smtpconnectiontimeout") = 60
.Fields.update
End With
Set myMail.Configuration = Config

myMail.Subject = asunto
myMail.From = origen
myMail.To=Destino
myMail.TextBody = mensaje
myMail.Send
set myMail=nothing
%>



Ahora tengo que investiga para hacer otra aplicación pero enviando un correo con archvio adjunto.

Otra ves gracias Monkyta.

[monkyta]

Que bueno Tomchat que por fin lo lograste..... en todo caso para enviar un email con un archivo adjunto es muy sencillo ya que solo va la instruccion AddAttachment.... asi por ejemplo enviando un documento Word

myMail.AddAttachment "c:\tuarchivo.doc"

Y si quieres enviar varios archivos solo repites esta linea varias veces (una lina por cada archivo que desees enviar)

[tomchat]

SI ok, hoy lo haverigue.

Gracias Monkyta.