Problema con forzar descarga

[Sandino]

hola amigos tengo el siguiente problema, quiero descar un excel la cosa es que no me lo descarga ;si no que me baja el archivo "descarga" que el abrirlo tiene pura basura ... por favor espero me ayuden a encontrar el problema.. saludos cordiales.

<%
if request.querystring("descarga")="si"
Dim objStream, strFileName , archivo , carpeta
archivo = Request.QueryString("file")
carpeta = "/pagina/descarga/"
strFileName =""&carpeta&""&archivo&""
Set objStream = Server.CreateObject("ADODB.Stream")
objStream.Type = 1
objStream.Open
objStream.LoadFromFile Server.MapPath(strFileName)

Response.AddHeader "Content-Disposition", "attachment; filename=" & strFileName
Response.ContentType = "application/octet-stream"
Response.BinaryWrite objStream.Read
objStream.Close
Set objStream = Nothing
response.write"Descargando archivo"
else
response.write"<a href=""descarga.asp?descarga=si&file=archivo.xls"" >Descargar
este archivo</a>"

end if
%>

[Myakire]

mmmmm, quizá con algo como: http://www.soloasp.com.ar/foro_web/viewtopic.php?p=3041

[Sandino]

si , lo intente asi y pasa lo mismo , kizas el error esta en codigo q puse arriba, si alguien me puede ayudar por favor.

[daniel00]

Que tal sandino.

No estoy muy seguro, pero puedes intentar lo siguiente.

Cambia la línea que dice:

Response.ContentType = "application/octet-stream"


Por:

Response.ContentType = "application/vnd.ms-excel"



Quizá por eso te pone basura, porque no reconoce el formato, me imagino .


Saludos y suerte!

[Sandino]

tb lo intente jaaja

[firerider]

Hola a todos, tengo el mismo problema, el caso es que estoy haciendo una página donde pueden subir archivos, y no puedo saber que tipo de archivo están subiendo (no pienso escribir cada tipo de archivo <<espero >>). El caso es que quiero que cuando ingresen a la página, sin importar el tipo de archivos, puedan descargarlos. Y no abrirlos en el explorer.
Tengo el mismo código, y lo que me hace es descargar el archivo html donde está montada.

[fcastro]

Hola Sandino,

Por lo que veo el fallo creo que está en el nombre del archivo, prueba a sustituir esta linea ...

Código:

Response.AddHeader "Content-Disposition", "attachment; filename=" & archivo

Otra cosilla que imagino que no tienes mal en el código... en el primer IF no tienes un THEN

Ya nos contarás . Un saludo.

[sjam7]

a mi me funciona muy bien con casi todos, el problema es cuando quiero descargar archivos grandes me los descarga incompletos

[sonsecaweb]

' DE ESTA FORMA FUNCIONA PARA TODO TIPO DE ARCHIVOS, PEQUEÑOS Y GRANDES


Dim objStream, strFileName , archivo , carpeta
archivo = Request.QueryString("file")

strFileName = archivo
Set objStream = Server.CreateObject("ADODB.Stream")
objStream.Type = 1
objStream.Open
objStream.LoadFromFile Server.MapPath(strFileName)
Response.AddHeader "Content-Disposition", "attachment; filename=" & archivo
Response.ContentType = "application/octet-stream"

' ESTO ES LO REALMENTE IMPORTANTE
while not objStream.EOS
Response.BinaryWrite(objStream.Read(1024*256))
response.flush

wend
objStream.Close
Set objStream = Nothing