Foros del Web » Creando para Internet » Flash y Actionscript »

AS3 error 1046

Estas en el tema de AS3 error 1046 en el foro de Flash y Actionscript en Foros del Web. 1046: Type was not found or was not a compile-time constant: BotonLista. Tengo este error. Me dice que no lo entiende. La que no lo ...
  #1 (permalink)  
Antiguo 05/07/2009, 16:59
Avatar de darkgaze  
Fecha de Ingreso: febrero-2006
Ubicación: Madrid, España
Mensajes: 462
Antigüedad: 14 años, 8 meses
Puntos: 2
AS3 error 1046

1046: Type was not found or was not a compile-time constant: BotonLista.


Tengo este error. Me dice que no lo entiende. La que no lo entiende aquí soy yo.

Os pongo el código para que veáis que no hago nada raro. Estoy mosqueadísima. Te da poquísimas pistas esto...
A ver si me podéis ayudar, porque yo ya no sé qué hacer.

Código:
package{

	import flash.display.MovieClip;
	import flash.text.TextField;
	import flash.text.TextFieldType;
	import flash.events.Event;
	import flash.events.MouseEvent;
	import flash.net.*;

	import utils.BotonLista;

	public class Main extends MovieClip { 
	
		var secciones:XMLList;
		var textoExplicativo:TextField;
		
		public function Main() { 
        	        stop();
			
			textoExplicativo = new TextField();
			textoExplicativo.type = TextFieldType.DYNAMIC;
			cargarSecciones();
      	       } 

		function cargarSecciones():void {
			var loader:URLLoader = new URLLoader();
			loader.addEventListener(Event.COMPLETE, cargaSecciones);
			loader.load(new URLRequest("secciones.xml"));
		}
		
		function cargaSecciones(event:Event):void {
			// guardo datos en la listaXML
					var datos:XML = new XML(event.target.data);
					secciones = datos.seccion;
					
					//mostramos la lista de secciones a la izquierda
					var pos:uint = 150;
					var item:XML;
					for each(item in secciones) {
						var bot:BotonLista = new BotonLista(50,pos,100,30,[email protected]);
						pos += 50;
						
						bot.addEventListener(MouseEvent.CLICK, cargarSubsecciones);
						
						addChild(bot);		
						
					}
					

		}
		
		function cargarSubsecciones(event:Event):void {
			...
		}		
		
	}
}

Dice que no entiende Boton lista. Esta clase está situada desde este main en utils/BotonLista.as

y su contenido es:


Código:
package utils {

	import flash.display.Sprite;
	import flash.events.MouseEvent;
	import flash.text.TextField;
	import flash.text.TextFieldAutoSize;
	import flash.text.TextFieldType;
	import flash.text.AntiAliasType;
	import flash.text.TextFormat;
	import flash.display.SimpleButton;
	import flash.display.DisplayObject;

	import utils.BotonListaDisplayState;
	
	class BotonLista extends SimpleButton {
		private var upColor:uint   = 0xCCCCCC;
		private var overColor:uint = 0xFFFFFF;
		private var downColor:uint = 0xFFFFFF;

		public function BotonLista(posX:uint, posY:uint, tamX:uint, tamY:uint, texto:String) {
			downState      = new BotonListaDisplayState(downColor, tamX, tamY);
			overState      = new BotonListaDisplayState(overColor, tamX, tamY);
			upState        = new BotonListaDisplayState(upColor, tamX, tamY);
			hitTestState   = new BotonListaDisplayState(upColor, tamX, tamY);
			useHandCursor  = true;
		}
	}	
}
No tiene nada raro... tiene LOS mismos parámetros que le doy y sin embargo dice que no lo entiende...


Esto es de locos U_U



Gracias chicos
__________________
Darkgaze
  #2 (permalink)  
Antiguo 05/07/2009, 18:27
 
Fecha de Ingreso: mayo-2008
Ubicación: Murcia, España
Mensajes: 313
Antigüedad: 12 años, 5 meses
Puntos: 5
Respuesta: AS3 error 1046

Puede ser que esta aplicación fuera de CS3 y la hayas abierto con CS4?
  #3 (permalink)  
Antiguo 05/07/2009, 19:10
Avatar de Lynxcraft  
Fecha de Ingreso: noviembre-2007
Ubicación: yecla murcia
Mensajes: 1.346
Antigüedad: 12 años, 10 meses
Puntos: 51
Respuesta: AS3 error 1046

y que pone en el archivo BotonListaDisplayState.as ??? el cual es importado por el archivo BotonLista
__________________
Sobran las ideas cuando faltan ganas de trabajar en ellas
Lynxcraft
  #4 (permalink)  
Antiguo 05/07/2009, 19:31
 
Fecha de Ingreso: mayo-2008
Ubicación: Murcia, España
Mensajes: 313
Antigüedad: 12 años, 5 meses
Puntos: 5
Respuesta: AS3 error 1046

Esque he tenido este tipo de errores al exportar un documento CS3 a CS4, errores sin sentido
  #5 (permalink)  
Antiguo 05/07/2009, 19:39
Avatar de Lynxcraft  
Fecha de Ingreso: noviembre-2007
Ubicación: yecla murcia
Mensajes: 1.346
Antigüedad: 12 años, 10 meses
Puntos: 51
Respuesta: AS3 error 1046

es posible XDXD como actualmente trabajo sobre Cs3 no me ha ocurrido nada de eso pero puede ser ya que he visto a muchos quejarse de algunos fallos con el cs4 al abrir archivos cs3
__________________
Sobran las ideas cuando faltan ganas de trabajar en ellas
Lynxcraft
  #6 (permalink)  
Antiguo 06/07/2009, 12:51
Avatar de darkgaze  
Fecha de Ingreso: febrero-2006
Ubicación: Madrid, España
Mensajes: 462
Antigüedad: 14 años, 8 meses
Puntos: 2
Respuesta: AS3 error 1046

Yo he empezado con flash directamente con Cs4. Así que ese error nada. Además he comenzado aquí directamente a desarrollar. No está importado.


El archivo ese no creo que tenga nada raro. Está también en la carpeta utils.
Te lo posteo.

Código:
package utils {
	
	import flash.display.Shape;

	class BotonListaDisplayState extends Shape {
		private var bgColor:uint;
		private var sizeX:uint, sizeY:uint;
		
		public function BotonListaDisplayState(bgColor:uint, tamX:uint, tamY:uint) {
			this.bgColor = bgColor;
			this.sizeX   = sizeX;
			this.sizeY   = sizeY;
			draw();
		}
		
		private function draw():void {
			graphics.beginFill(bgColor);
			graphics.drawRect(0, 0, sizeX, sizeY);
			graphics.endFill();
		}
	}
}
Qué raruno....
__________________
Darkgaze
  #7 (permalink)  
Antiguo 06/07/2009, 12:56
 
Fecha de Ingreso: mayo-2008
Ubicación: Murcia, España
Mensajes: 313
Antigüedad: 12 años, 5 meses
Puntos: 5
Respuesta: AS3 error 1046

Código actionscript:
Ver original
  1. private var bgColor:uint;
  2.         private var sizeX:uint, sizeY:uint;
  3.        
  4.         public function BotonListaDisplayState(bgColor:uint, tamX:uint, tamY:uint) {
  5.             this.bgColor = bgColor;
  6.             this.sizeX   = sizeX;
  7.             this.sizeY   = sizeY;
  8.             draw();
  9.         }

Esto si es algo raro, estás recibiendo tamX y tamY y estás inicializando con sizeX y sizeY ;)
  #8 (permalink)  
Antiguo 06/07/2009, 13:41
Avatar de jahepi
Colaborador
 
Fecha de Ingreso: diciembre-2004
Ubicación: Querétaro
Mensajes: 1.124
Antigüedad: 15 años, 10 meses
Puntos: 43
Respuesta: AS3 error 1046

Hola darkgaze !

Ese error es debido a que no encuentra la clase en el paquete, por lo que veo la clase BotonLista no tiene modificador de acceso:

Código actionscript:
Ver original
  1. class BotonLista extends SimpleButton
  2. {
  3. }

Tienes que definirla de la siguiente forma para que tengas acceso desde otros paquetes:

Código actionscript:
Ver original
  1. public class BotonLista extends SimpleButton
  2. {
  3. }

Un saludote !
__________________
Una contraseña es como la ropa interior. No deberías dejarlas afuera a la vista de otras personas, deberías cambiarla regularmente, y ni se te ocurra prestarla a extraños.
  #9 (permalink)  
Antiguo 06/07/2009, 14:39
Avatar de darkgaze  
Fecha de Ingreso: febrero-2006
Ubicación: Madrid, España
Mensajes: 462
Antigüedad: 14 años, 8 meses
Puntos: 2
Respuesta: AS3 error 1046

no jodas.... O_O
espera que pruebo... xD


Genial. Eso era xDDD
problema resuelto. MUCHAS GRACIAS!
__________________
Darkgaze
Atención: Estás leyendo un tema que no tiene actividad desde hace más de 6 MESES, te recomendamos abrir un Nuevo tema en lugar de responder al actual.
Respuesta




La zona horaria es GMT -6. Ahora son las 17:29.