Ayuda con cookies con flash

[jhonynemonic]

tengo un selector en flash donde el usuario tiene que elegir ente dos botones que saltan a dos paginas diferentes...lo que yo quiero hacer es que una vez que el usuario haga click en cualquiera de esos botones la animación guarde esa elección (mediante sharedobject) y la próxima vez que entre NO tenga que realizarla y salte directamente a la pagina eligida la vez anterior...

estube viendo los tutoriales en la web y hay varios ...pero son todos sobre como guardar info de formularios y demás....
Aca estan algunos de los tutoriales muy buenos y avanzados que he visitado...tal vez le sirvan a alguien....

http://www.kadazuro.com/tutoriales/sharedObject/

http://www.cristalab.com/vertutorial.php?id=10

si alguien me pudiese ayudar con el código...POR FAVORRRRRR!!!!!

[jhonynemonic]

por lo visto no hay nadie que me pueda ayudar... :(

espero que por lo menos las direcciones que estan aqui les sirvan para algo....

igual gracias a quienes leyeron esto...

[TMeister]

A ver si esto te sirve....

Copia pega y prueba...

Todo esta explicado en los comentarios...

si queda alguna duda pregunta...

Código:

/**********************************************
para armar los Elementos del Escenario
***********************************************/
MovieClip.prototype.cuadro = function(ancho, largo, prof) {
	tm_mc = this.createEmptyMovieClip("tempo"+prof, prof);
	tm_mc.lineStyle(1);
	tm_mc.beginFill(0xf1f1f1);
	tm_mc.lineTo(0, 0);
	tm_mc.lineTo(0+ancho, 0);
	tm_mc.lineTo(0+ancho, 0+largo);
	tm_mc.lineTo(0, 0+largo);
	tm_mc.lineTo(0, 0);
	tm_mc.createTextField("label_txt", 2, 0, 0, 0, 0);
	tm_mc.label_txt.autoSize = true;
	tm_mc.label_txt.type = "dynamic";
	return tm_mc;
};
/***********************************************
Creamos y asignamos las acciones de los Botones
***********************************************/
b1_mc = this.cuadro(100, 15, 1);
b1_mc.label_txt.text = "www.tmeister.net";
b1_mc._x = 10;
b1_mc._y = 80;
b2_mc = this.cuadro(120, 15, 2);
b2_mc.label_txt.text = "www.forosdelweb.com";
b2_mc._x = 120;
b2_mc._y = 80;
/***********************************************
El Campo de Salida
***********************************************/
this.createTextField("salida_txt", 3, 20, 20, 0, 0);
salida_txt.autoSize = true;
salida_txt.multiline = true;
/***********************************************
Checamos si es la primera vez que entra
SharedObject.getLocal("miCookie"); hace referencia al 
archivo miCookie.sol.
cookie.data.url  checa si en dicho archivo existe
una variable llamada url, si dicha variable existe
la toma y carga la url
***********************************************/
cookie = SharedObject.getLocal("miCookie");
if (cookie.data.url != null) {
	salida_txt.text = "Ya entraste y escogiste la url:"
	salida_txt.text += cookie.data.url;
	getURL(cookie.data.url, "_blank");
} else {
	salida_txt.text = "Es tu primera vez escoge una URL";
}
/******************************************
Esta funcion lo que hace es:
si no existe el archivo miCookie.sol lo crea
cookie.data.url -> asigna la variable url a dicho 
archivo..
cookie.flush -> escribe todas las variables asignadas
al objeto cookie en el Archivo.sol
***********************************************/
function creaCookie(url) {
	cookie = SharedObject.getLocal("miCookie");
	cookie.data.url = url;
	cookie.flush();
}
/***********************************************
Las acciones de los Botones.
Al dar click abre la url y crea o modifica tu cookie..
***********************************************/
b1_mc.onRelease = function() {
	url = "http://"+this.label_txt.text;
	creaCookie(url);
	getURL(url, "_blank");
};
b1_mc.onRelease = function() {
	url = "http://"+this.label_txt.text;
	creaCookie(url);
	getURL(url, "_blank");
};

Saludos!!