arrastrar movie clip con botones

[shinotriana]

Hola a tosos:
Quisiera saber si alguien sabe como puedo mover un clip de pelicula que tenga botones y estos me funcionen despues de moverl el clip, lo he intentado con startdrag y el movie clpi se mueve pero luego no me funcionan los botones.

Gracias

[dualklip]

No se muy bien como irá tu proyecto pero a ver si te vale esto:

Imitando las barras de las ventanas de un sistema operativo creas dentro de tu mc otro diferente que este en la parte superior, luego le das la orden de arrastre a ese en lugar de al mc general, algo así:

Código:

mc.miBarrita.onPress = function(){
	mc.startDrag(false);
}
mc.miBarrita.onRelease = function(){
	mc.stopDrag();
}
	
mc.btn1.onRelease = function(){
	getURL("http://www.forosdelweb.com", "_blank", "GET");
}

[shinotriana]

te dejo un enlace a una web que tiene algo parecido a lo que busco es (www.schematic.com),cunado haces click fuera de la ficha esta se reduce y puedes mover la pantalla entera y cuando quieras se puede clickar en cualquier ficha y esta se amplia,,,soy novato en actionscript.

[dualklip]

Código:

var oyenteDeRaton:Object = new Object();
oyenteDeRaton.onMouseDown = function() {
    ratonPulsado = true;
    comienzoMovX = _xmouse;
    comienzoMovY = _ymouse;
    posIX = _root.mc._x;
    posIY = _root.mc._y;
}
oyenteDeRaton.onMouseMove = function(){
    if(ratonPulsado == true){
        _root.mc._x = posIX - (comienzoMovX - _xmouse);
        _root.mc._y = posIY - (comienzoMovY - _ymouse);
    }
}
oyenteDeRaton.onMouseUp = function() {
    ratonPulsado = false;
}
Mouse.addListener(oyenteDeRaton);

mc.btn1.onRelease = function(){
    getURL("http://www.forosdelweb.com", "_blank", "GET");
}

[shinotriana]

GRACIAS¡¡¡¡¡¡¡ Parece que ya funciona

[shinotriana]

Otra pregunata dualklip, para hacer que el movie clip al dejar de arrastrarlo me haga el efecto de que siga arrastrandose un poco como en la web http://www.bio-bak.nl ,,como sería???

Gracias

[dualklip]

Aquí lo tienes, pero lo he tenido que hacer muy rápido así que si miras un poco el código seguro que puedes depurarlo:

Código:

var oyenteDeRaton:Object = new Object();
oyenteDeRaton.onMouseDown = function() {
    ratonPulsado = true;
    margenX = mc._x - _xmouse;
    margenY = mc._y - _ymouse;
    desliz = 10;
    mc.onEnterFrame = function(){
        trace(movX + " - " + movY);
        if(ratonPulsado == true){
            movX = Math.round((this._x - _xmouse - margenX)/desliz);
            movY = Math.round((this._y - _ymouse - margenY)/desliz);
        } else {
            movX = Math.round((this._x - posRatonX - margenX)/desliz);
            movY = Math.round((this._y - posRatonY - margenY)/desliz);
        }
        if(this._x == Math.round(_xmouse - margenX) && this._y == Math.round(_ymouse - margenY)){
            this.onEnterFrame = Void;
        } else {
            this._x -= movX;
            this._y -= movY;
        }
    }
}
oyenteDeRaton.onMouseMove = function(){
    if(ratonPulsado == true){
        posRatonX = _xmouse;
        posRatonY = _ymouse;
    }
}
oyenteDeRaton.onMouseUp = function() {
    ratonPulsado = false;
}
Mouse.addListener(oyenteDeRaton);

mc.btn1.onRelease = function(){
    getURL("http://www.forosdelweb.com", "_blank", "GET");
}

[shinotriana]

ok muchas gracias ya le hecho un vistazo,,,,gracias