attachMovie con delay

[spike777]

Buenas,

Mi duda es la siguiente: genero unos botones dinamicos desde flash mediante un for y attachMovie, el codigo que uso es el siguiente:

Código:

for (aa=0; aa<marcas.length; aa++) {

	this.attachMovie("bot", "bot"+aa, aa);

	this["bot"+aa]._x = 20;
	this["bot"+aa]._y = this["bot"+aa]._height*aa
	
	this["bot"+aa].titulo = marcas[aa];
}

Eso esta bien, lo que quiero ahora es que los botones aparezcan con cierto delay entre cada uno, he probado esto, pero no sale:

Código:

delay = 50;
aa = 0;
control = setInterval(function () {
	if (aa<=marcas.length) {
		
	this.attachMovie("bot", "bot"+aa, aa);

	this["bot"+aa]._x = 20;
	this["bot"+aa]._y = this["bot"+aa]._height*aa
	
	this["bot"+aa].titulo = marcas[aa];
		
		aa++;
	} else {
		clearInterval(control);
	}
}, delay);

que esta mal ?
desde ya muchas gracias!

[luistar]

yo lo haría así:

Código PHP:

  /*CODIGO ACTION SCRIPT*/ 
//declaramos las variables que vamos a usar 
var marcas:Array = new Array('uno', 'dos', 'tres', 'cuatro','cinco','seis','siete','ocho','nueve'); 
var delay:Number = 50; 
var cuantos_van:Number = 0; 
var cuantos_son:Number = marcas.length; 
//funcion para agregar un boton 
function agregar_boton() { 
    if (cuantos_van<cuantos_son) { 
        var bot_ref:MovieClip = attachMovie('bot', 'bot'+cuantos_van, cuantos_van); 
        with(bot_ref){titulo = marcas[cuantos_van]; _x=20; _y=_height*cuantos_van;} 
        cuantos_van++; 
    } else { 
        clearInterval(comienza_agregar); 
    } 
} 
//usamos setInterval 
var comienza_agregar = setInterval(agregar_boton, delay); 
//-------> 
stop();  
   

:D

[spike777]

Hola amigo, desde ya muchas gracias por responder,
pero sin emargo hago esos cambios y sigue sin funcionar,
vos lo probaste ?

[luistar]

algo debiste hacer mal
revisa tu código y compáralo con este
http://es.geocities.com/leo020588/delay/delay.html
http://es.geocities.com/leo020588/delay/delay.zip

:D

[spike777]

ya encontre la falla, la tenia yo, estaba exportando como actionscript 1.0 en vez de 2.0.

gracias!