_width y _height de MC??

[stock]

Hola, alguien sabe como leer esas propiedades de un MC?? necesito saber cuanto mide cuando le he cargado una imagen externa, esto es lo que tengo:

Código:

var mcl:MovieClipLoader = new MovieClipLoader();
var listener:Object = new Object();
mcl.addListener(listener);

listener.onLoadComplete = function(target_mc:MovieClip):Void{
	trace("termino! "+imagen.foto._width+"x"+imagen.foto._height);
	
}

function cargar(img:String):Void{
	var foto:MovieClip = imagen.createEmptyMovieClip("foto",1);
	mcl.loadClip(img,foto);
}

tns1.onRelease = function():Void{
	cargar("galeria/fechas/2006/10/01/001.jpg");
}

tns2.onRelease = function():Void{
	cargar("galeria/fechas/2006/10/01/014.jpg");
}

pero, siempre me arroja 0x0

alguien sabe como poder saber el tamanio exacto??

[stock]

ya lo solucione

jaaaaa, lo que pasa es que cuando onLoadComplete se dispara, este espera por onLoadInit, entonces, en este ultimo evento, ya puedes interactuar con las nuevas propiedades

el code me quedo asi:

Código:

var mcl:MovieClipLoader = new MovieClipLoader();
var listener:Object = new Object();
mcl.addListener(listener);

listener.onLoadComplete = function(target_mc:MovieClip):Void{
trace("completado! "+target_mc._width+"x"+target_mc._height); //0x0
}
listener.onLoadInit = function(target_mc:MovieClip):Void {
	trace("ready para trabajar! "+target_mc._width+"x"+target_mc._height); //400X600
}
function cargar(img:String):Void{
	var foto:MovieClip = imagen.createEmptyMovieClip("foto",1);
	mcl.loadClip(img,imagen);
}

tns1.onRelease = function():Void{
	cargar("galeria/fechas/2006/10/01/001.jpg");
}

tns2.onRelease = function():Void{
	cargar("galeria/fechas/2006/10/01/014.jpg");
}


tns3.onRelease = function():Void{
	cargar("galeria/fechas/2006/10/01/002.jpg");
}


tns4.onRelease = function():Void{
	cargar("galeria/fechas/2006/10/01/011.jpg");
}

tns5.onRelease = function():Void{
	cargar("galeria/fechas/2006/10/01/012.jpg");
}

have funnnnnn