Foros del Web » Creando para Internet » Flash y Actionscript »

Comparacion entre combobox

Estas en el tema de Comparacion entre combobox en el foro de Flash y Actionscript en Foros del Web. Hola compañeros/as del cyberespacio... estoy armando un formulario en base al que ofrecen en este sitio flaform.. el cual siempre me funciono perfectamente. Lo que ...
  #1 (permalink)  
Antiguo 01/11/2006, 15:18
Avatar de vec
vec
 
Fecha de Ingreso: junio-2001
Mensajes: 291
Antigüedad: 16 años, 5 meses
Puntos: 8
Pregunta Comparacion entre combobox

Hola compañeros/as del cyberespacio...

estoy armando un formulario en base al que ofrecen en este sitio flaform.. el cual siempre me funciono perfectamente.

Lo que le agregue en esta oportunidad fue 6 combo box, 4 de los cuales son iguales y los otros dos distintos a los primero pero iguales entre si.

Los dos ultimos combos son de colores, none,black,red,green, blue. Obviamente que se diferencian en el nombre de instancia.

Mi problema es que entre los dos combos de colores, si la persona elige uno de ellos el color el otro deberia quedar inactivo, en otroas palabras que no le permita elegir un color en el otro combo..... como hago eso??

Desde ya muchas gracias por su aporte....
__________________
[email protected]
  #2 (permalink)  
Antiguo 01/11/2006, 15:39
Avatar de TMeister
Crazy Coder
 
Fecha de Ingreso: enero-2002
Ubicación: En la Oficina
Mensajes: 2.880
Antigüedad: 15 años, 11 meses
Puntos: 193
aver si entendi bien. quieres bloquear el combo Z si el combo X fue seleccionado y viceversa.

bien.

Aqui te dejo una clasesilla que lo hace

Código:
import mx.controls.ComboBox;
class comboControls extends MovieClip
{
	private var combo1 : ComboBox
	private var combo2 : ComboBox
	public function comboControls ()
	{
	}
	public function onLoad ()
	{
		setCombos ();
	}
	private function setCombos ()
	{
		combo1.addItem ("-----------", 0);
		combo2.addItem ("-----------", 0);
		for (var a = 1; a <= 10; a ++)
		{
			combo1.addItem (a, a);
			combo2.addItem (a, a);
		}
		combo1.addEventListener ("change", checkCombo);
		combo2.addEventListener ("change", checkCombo);
	}
	private function checkCombo (obj : Object)
	{
		trace (obj.target._name)
		switch (obj.target._name)
		{
			case "combo1" :
				//"Selecciono del Combo1"
				if (obj.target.selectedIndex != 0)
				{
					//Bloqueamos el combo 2
					obj.target._parent.combo2.enabled = false;
				} else
				{
					//Si es el primer item del combo -------- DesBloqueamos el combo2
					obj.target._parent.combo2.enabled = true;
				}
				break;
			case "combo2" :
				//"Selecciono del Combo1"
				if (obj.target.selectedIndex != 0)
				{
					//Bloqueamos el combo 2
					obj.target._parent.combo1.enabled = false;
				} else
				{
					//Si es el primer item del combo -------- DesBloqueamos el combo2
					obj.target._parent.combo1.enabled = true;
				}
				break;
		}
	}
}
ahora si no quieres usar Clases. Lo hacemos con Codigo normal lo pones el el Frame donde tienes tus combos

Código:
function setCombos() {
	combo1.addItem("-----------", 0);
	combo2.addItem("-----------", 0);
	for (var a = 1; a<=10; a++) {
		combo1.addItem(a, a);
		combo2.addItem(a, a);
	}
	combo1.addEventListener("change", checkCombo);
	combo2.addEventListener("change", checkCombo);
}
function checkCombo(obj:Object) {
	trace(obj.target._name);
	switch (obj.target._name) {
	case "combo1" :
		//"Selecciono del Combo1"
		if (obj.target.selectedIndex != 0) {
			//Bloqueamos el combo 2
			obj.target._parent.combo2.enabled = false;
		} else {
			//Si es el primer item del combo -------- DesBloqueamos el combo2
			obj.target._parent.combo2.enabled = true;
		}
		break;
	case "combo2" :
		//"Selecciono del Combo1"
		if (obj.target.selectedIndex != 0) {
			//Bloqueamos el combo 2
			obj.target._parent.combo1.enabled = false;
		} else {
			//Si es el primer item del combo -------- DesBloqueamos el combo2
			obj.target._parent.combo1.enabled = true;
		}
		break;
	}
}
setCombos ();

Saludos!!
  #3 (permalink)  
Antiguo 01/11/2006, 15:56
Avatar de vec
vec
 
Fecha de Ingreso: junio-2001
Mensajes: 291
Antigüedad: 16 años, 5 meses
Puntos: 8
Sonrisa

Sos un genio.. funciono pipicucu.... muchisimas gracias
__________________
[email protected]
  #4 (permalink)  
Antiguo 01/11/2006, 15:58
Avatar de TMeister
Crazy Coder
 
Fecha de Ingreso: enero-2002
Ubicación: En la Oficina
Mensajes: 2.880
Antigüedad: 15 años, 11 meses
Puntos: 193
pipicucu. jeje Nunca lo habia escuchado
Atención: Estás leyendo un tema que no tiene actividad desde hace más de 6 MESES, te recomendamos abrir un Nuevo tema en lugar de responder al actual.
Respuesta




La zona horaria es GMT -6. Ahora son las 11:35.