Como crear un rastro de un MC

[junihh]

Hola señores

Jugando un poco con Flash, se me ocurrio esto y como veran funciona bien cuando apretamos el boton correr.

El caso es que me gustaria que la pelotita dejara un rastro a medida que vaya corriendo. Trate usando parte del script de este tutorial, pero no me fue muy bien.

El siguiente es todo el script que maneja la creacion de objetos y movimiento de la pelotita, preparado por mi:

Código:

var cantPerseguidos = 5;
var velocidad = 8;
var perseNum;
//
//
//
function randomMinMax(min, max) {
	return Math.floor(random(max-min+1))+min;
}
//
//
//
function crearPerseguidos() {
	for (i=0; i<cantPerseguidos; i++) {
		attachMovie("perseguido", "perse"+i, i);
		_root["perse"+i]._x = randomMinMax(10, 290);
		_root["perse"+i]._y = randomMinMax(10, 150);
	}
}
//
//
//
function correrPerseguidor() {
	perseguidor.duplicateMovieClip("perseguidorDup", cantPerseguidos+5);
	//
	//createEmptyMovieClip("linea", 1);
	//linea.lineStyle(1, 0x000000, 100);
	//
	perseguidorDup.onEnterFrame = function() {
		//
		this._x += (_root["perse"+perseNum]._x-this._x)/velocidad;
		this._y += (_root["perse"+perseNum]._y-this._y)/velocidad;
		linea.moveTo(_root["perse"+perseNum]._x, _root["perse"+perseNum]._y);
		//
		if (perseguidorDup.hitTest(_root["perse"+perseNum])) {
			_root["perse"+perseNum].gotoAndStop(2);
			_root["perse"+perseNum]._alpha = 20;
			perseNum++;
			trace(perseNum);
			//
			if (perseNum>=cantPerseguidos) {
				correr_btn.enabled = true;
				correr_btn._alpha = 100;
			}
		}
	};
}
//
//
//
correr_btn.onPress = function() {
	perseNum = 0;
	//
	crearPerseguidos();
	correrPerseguidor();
	//
	this.enabled = false;
	this._alpha = 60;
};

Tienen alguna idea de como lograr que ponga ese rastro (o huellas) a medida que vaya corriendo, como la telaraña de una araña ????

Una pequeña aclaracion, el "perseguidor" del script es la pelotita y los "perseguidos" los cuadros verdes.

[webgeri]

a mi me funciona asi

Código:

function correrPerseguidor() {
	perseguidor.duplicateMovieClip("perseguidorDup", cantPerseguidos+5);
	//
	createEmptyMovieClip("linea", 1000);
	linea.lineStyle(1, 0x000000, 100);
	linea.moveTo(perseguidorDup._x, perseguidorDup._y);
	perseguidorDup.onEnterFrame = function() {
		//
		this._x += (_root["perse"+perseNum]._x-this._x)/velocidad;
		this._y += (_root["perse"+perseNum]._y-this._y)/velocidad;
		linea.lineTo(this._x, this._y);
		//
		if (perseguidorDup.hitTest(_root["perse"+perseNum])) {
			_root["perse"+perseNum].gotoAndStop(2);
			_root["perse"+perseNum]._alpha = 20;
			perseNum++;
			//
			if (perseNum>=cantPerseguidos) {
				correr_btn.enabled = true;
				correr_btn._alpha = 100;
			}
		}
	};
}

sldos

[webgeri]

tb jugando un poco mas
se puede hacer que el trazo no sea tan preciso asi

Código:

a = random(perseguidorDup._height/2);
linea.lineTo((this._x)+a, (this._y)+a);

o algo asi

Código:

linea.lineTo(this._x, this._y);
j += 0.2;
linea.lineStyle(j, 0x000000, 100);

seguro se puede ajustar un poco mas aun

sldos

[junihh]

Gracias Webgeri

Me funciono tal cual queria. Lo modifique un poco para que solo se vea cuando toca el ultimo objeto. El resultado es muy interesante.

Lo puedes ver aqui

Probe tambien el efecto de temblor del trazo. Me gusto el resultado y ya vere en que lo uso. Gracias nuevamente.