problema con sonido

[dexter_x740]

estoy haciendo un flash que carga sonido externo con el sig. codigo:

Código PHP:

  stop(); 
mess="cargando movie"; 
cargador.onEnterFrame=function(){ 
    this.barra._xscale=(_root.getBytesLoaded()/_root.getBytesTotal())*100; 
    if(this.barra._xscale>98){ 
        mess="cargando sonido"; 
        s=new Sound(); 
        s.loadSound("rola.mp3",true); 
        delete this.onEnterFrame; 
        this.onEnterFrame=function(){ 
            c=s.getBytesLoaded(); 
            t=s.getBytesTotal(); 
            this.barra._xscale=(c/t)*100; 
            if(c==t){ 
                delete this.onEnterFrame; 
                gotoAndStop("done",1); 
            } 
        } 
    } 
}  
   

el problema es que la cancion empieza antes de que se termine de llenar la barra, he aqui la direccion para que lo vean:
http://mx.geocities.com/dexter_1313/sonido.html

[pcMan]

El método loadSound tiene como segundo parámetro un valor boleano que indica si se cargará la secuencia de audio con streamming o no.

Código:

s.loadSound("rola.mp3",true);

Aquí en tu código, true indica que la carga del sonido será de tipo streamming, así que empieza a reproducir el mp3 cada vez que el buffer se ha llenado.
Para evitar esto solo cambia el valor a false y flash esperará a que termine de cargar la canción para empezar a reproducir.

Saludos ;)

[dexter_x740]

ya le he puesto False al parámetro pero cuando se termina de cargar la barra, el sonido no se reproduce :S

[pcMan]

Para reproducir un mp3 que ha sido cargado necesitas usar el evento Sound.onLoad y dentro de este usar el metodo Sound.start() para poder empezar a reproducir.

Prueba esto:

Código:

s = new Sound();
s.loadSound("http://mx.geocities.com/dexter_1313/rola.mp3", false);
id = setInterval(revisar, 100);
function revisar() {
	total = s.getBytesTotal();
	listo = s.getBytesLoaded();
	kb = Math.floor(listo/1024);
	porcentaje = Math.floor(listo/total*100);
	if (porcentaje>0) {
		trace(porcentaje+"% => "+kb+"Kb cargados");
	} else {
		trace("conectando...");
	}
	if (listo == total) {
		trace("carga completada");
		clearInterval(id);
	}
}
// al terminar de cargar...
s.onLoad = function(ok) {
	if (ok) {
		s.start();
	} else {
		trace("error al cargar la rollita");
		clearInterval(id);
	}
};
stop();

Saludos =)

[dexter_x740]

Gracias ya funciona bien, solo faltaba ponerle start()