Problema con posición aleatoria (AS3)

[Nemutagk]

Que tal compañeros, vengo a consultarles...

Verán, tengo una película que mediante AS3 creo unas mmm "bolitas" de manera aleatoria pero de alguna manera siempre manteniéndose en un radio al centro de la película, hasta aquí todo bien, ahora, lo que intento hacer es animar cada bolita y que se mueva a una posición aleatoria pero que ahora abarque toda la película, ya logre animarla, pero no obtener realmente alguna posición aleatoria, ya que siempre obtengo que se muevan a la esquina inferior derecha, lo que quiero es que algunas se vallan hacia arriba y a la derecha o a la izquierda y que otras lo mismo pero hacia abajo...

Les dejo el código AS3 que eh generado hasta el momento...

Código actionscrip:

package  {
    import flash.display.Shape;
    import flash.utils.Timer;
    import flash.events.TimerEvent;
    import flash.display.Sprite;
    import fl.transitions.Tween;
    import fl.transitions.easing.*;
    import fl.transitions.TweenEvent;
    
    public class burbujas extends Sprite {
 
        public function burbujas() {
            inicio();
        }
        
        private function inicio() {
            var tmTiempo:Timer = new Timer(100,50);
            tmTiempo.addEventListener(TimerEvent.TIMER, crear);
            tmTiempo.start();
        }
        
        private function crear(evento:TimerEvent) {
            var posX:uint = Math.round((Math.random() * 100) + 150);
            var posY:uint = Math.round((Math.random() * 50) + 100);
            var posXfin:uint = Math.floor(Math.random() * 200);
            var posYfin:uint = Math.floor(Math.random() * 100);
            
            trace("posicion final: " + posX.toString());
            var spBurbuja:Shape = new Shape();
            spBurbuja.graphics.beginFill(Math.random() * 0xFFFFFF);
            spBurbuja.graphics.drawCircle(posX,posY,5);
            addChild(spBurbuja);
            
            var animacionX:Tween = new Tween(spBurbuja, "x", Strong.easeOut, spBurbuja.x, posXfin, 4, true);
            var animacionY:Tween = new Tween(spBurbuja, "y", Strong.easeOut, spBurbuja.y, posYfin, 4, true);
            
            //animacionX.addEventListener(TweenEvent.MOTION_FINISH, finalizar);
        }
        
        private function finalizar(evento:TweenEvent) {
            //evento.target.
        }
    }
    
}
 

De antemano muchas gracias

[Nemutagk]

Al final, me respondo a mi mismo >.< ajaja...

Cuando se crea el objeto burbuja (shape) en la propiedad drawCircle tenia que poner 0 en las opciones X y Y, y por medio de la posición eh "global" (no se como realmente se llama) de X y Y posicionar el objeto, abajo para que se entienda mejor pongo el código...

Código actionscript:

private function crear(evento:TimerEvent) {
            var posX:uint = Math.round((Math.random() * 100) + 150);
            var posY:uint = Math.round((Math.random() * 50) + 100);
            var posXfin:uint = Math.random() * stage.stageWidth; //Obtengo un numero random sin pasar el ancho de la película
            var posYfin:uint = Math.random() * stage.stageHeight; //Obtengo un numero random sin pasa el alto de la película
            
            trace("posicion final: " + posX.toString());
            var spBurbuja:Shape = new Shape();
            spBurbuja.graphics.beginFill(Math.random() * 0xFFFFFF);
            spBurbuja.graphics.drawCircle(0, 0, 5); //Creo el objeto, pero en la posición 0 para X y Y
            spBurbuja.x = posX; //Ahora posiciono el objeto en las coordenadas indicadas
            spBurbuja.y = posY;
            addChild(spBurbuja);
            
            var animacionX:Tween = new Tween(spBurbuja, "x", Strong.easeOut, spBurbuja.x, posXfin, 4, true);
            var animacionY:Tween = new Tween(spBurbuja, "y", Strong.easeOut, spBurbuja.y, posYfin, 4, true);
        }