detener por cierto tiempo?

[biffly]

hola, como puedo con actionscript detener la ejecucion de una pelicula por n seg.? gracias:)

[luistar]

hola
para detener la reproduccion de un MovieClip yo uso un método añadido (prototype)

este código al principio de todo

Código:

MovieClip.prototype.detener = function(milisegundos:Number){
	//establecemos un tiempo de inicio
	var tiempo_incio:Number = getTimer();
	
	//definimos una variable haciendo referencia a este movieClip (ya que por se pierde la referencia dentro de setInterval)
	var cual_movie:MovieClip = this;

	//detenemos la reproduccion
	cual_movie.stop();
	
	//creamos una función para verificar si ya ha transcurrido el tiempo
	var verificar_tiempo:Function = function(){
		if(getTimer() - tiempo_incio >= milisegundos){
			//si ya se cumplió el tiempo reproducimos la película y elminamos la verificacion
			clearInterval(comienza_a_verificar);
			cual_movie.play();
		}
		//cuanto tiempo pasó
		trace(getTimer() - tiempo_incio);
	}
	var comienza_a_verificar:Number = setInterval(verificar_tiempo,10);
}
//--------------------------------->

y para usarlo es tan sencilo como hacer: pelicula_mc.detener(5000);

por ejemplo:
haz un MovieClip con una animación siemple de unos 100 fotogramas
y ponle nombre de instancia: animacion

ahora con este código lo que haremos es que a la mitad de la animación se detenga por 10000 milisegundos (10 seg)

Código:

animacion.onEnterFrame = function(){
	if(this._currentframe == Math.round(this._totalframes/2)){
		this.detener(10000);
		delete this.onEnterFrame;
	}
}

descarga ejemplo

[biffly]

ok gracias, lo voy a probar, pero como seria si lo que quiero detener es una animacio que corre en el root y en el frame 33? para darte un ejemplo

[luistar]

en el fotograma 33 tendrías que poner: this.detener(10000);

:D

[rusoftware]

Creo que este código que una vez posteó Bandit es menos engorroso y más práctico...

En el fotograma donde quieres detener la película pon lo siguiente:

stop();
segundos = 5;
espera = function () {
play();
clearInterval(a);
};
a = setInterval(espera, segundos*1000);

Eso lo detendrá 5 segundos, si quieres más o menos, cambia el 5 por la cantidad de segundos que desees.

Un abrazo

[luistar]

Iniciado por rusoftware

este código ... es menos engorroso y más práctico...

creo que confundes un poco las cosas

si tuvieras que hacer 10 veces pausas en distintos lugares
tendrías que repetir innecesariamente 10 veces el mismo código
cosa que no es muy práctico

en cambio es más sencillo y tiene más precisión poner en cualquier contexto

_root.movieClip.detener(5000);
this._parent.detener(1000);
clip_mc['p'+n].detener(60000);

usando el mismo código

el echo de que un código sea mas pequeño no quiere decir que sea más practico y funcional

:D

[rusoftware]

Es cierto, pero en la pregunta no interpreté que el quería hacer 10 pausas, sino solo una...

Un abrazo