¿Como puedo hacer esto?

[santafesino_lagunero]

Hola, buenas noches. Necesitaría que me dén una mano para un proyecto que estoy haciendo pero...quizá lo más importante no me sale. Tengo un sistema en Access 2003 que es para busqueda de coincidencia de números. La cuestión es que tengo una tabla con cuatro números fijos y tengo cuatro cajas de textos para ingresar números. ¿Como puedo hacer para que me busque coincidencias entre los datos que ingreso en las cuatro cajas de textos con los cuatro números que tengo en la tabla guardados y me diga la cantidad de 'aciertos' que hubo?.

Desde ya muchas gracias y mil gracias. Necesito poder resolver esto porque es para un proyecto de estudio, y me estoy rompiendo la cabeza y no me sale y ya ando un poco entre desausiado y desesperado.

Gracias, y saludos.

[Uran]

Hola santafesino_lagunero,


necesitaría muchos más datos para contestar adecuadamente a tu pregunta:

• ¿Usas o debes usar código VBA?
• ¿La comprobación se hace a través de un botón?
• ¿Has de comprobar que no se repitan valores ente unos cuadros de texto y otros?
• etc...

En adelanto te pongo un pequeño código con una de las mil maneras de resolver tu dilema.

Yo me he creado un formulario con 4 cuadros te texto (numero1,...,numero4) y he creado un botón al que le he agregado el siguiente código:

Código:

Private Sub BuscarAciertos_Click()
    Dim db As Database
    Dim SQLText As String
    Dim rst As DAO.Recordset
    Dim contador As Integer
        
    Set db = CurrentDb()
    contador = 0
    
    SQLText = " SELECT * FROM Numeros" _
            & " WHERE Numero = " & Me![numero1]
    Set rst = db.OpenRecordset(SQLText, dbReadOnly)
    If Not (rst.BOF And rst.EOF) Then
        contador = contador + 1
    End If

    SQLText = " SELECT * FROM Numeros" _
            & " WHERE Numero = " & Me![numero2]
    Set rst = db.OpenRecordset(SQLText, dbReadOnly)
    If Not (rst.BOF And rst.EOF) Then
        contador = contador + 1
    End If
    
    SQLText = " SELECT * FROM Numeros" _
            & " WHERE Numero = " & Me![numero3]
    Set rst = db.OpenRecordset(SQLText, dbReadOnly)
        
    If Not (rst.BOF And rst.EOF) Then
        contador = contador + 1
    End If
    
    SQLText = " SELECT * FROM Numeros" _
            & " WHERE Numero = " & Me![numero4]
    Set rst = db.OpenRecordset(SQLText, dbReadOnly)
    If Not (rst.BOF And rst.EOF) Then
        contador = contador + 1
    End If
    
    MsgBox ("Aciertos: " & contador)

End Sub

Éste código no comprueba que los valores de los cuadros sean idénticos, además se podría hacer con un For pero sería algo más complejo.

Para dar una respuesta adecuada a tu solicitud, tendrías que dar más datos (entre ellos los conocimientos que tienes/deberías tener).

De todos modos, si es por un tema de estudios, imagino que debes tener tanto la información como los medios para resolver tu dilema... pero no me quiero meter donde no me llaman.

Espero que mi código te sirva de pista, pero insisto en que hay que modificarlo para añadirle muchas cosas (como resetear las variables, controlar errores, etc)

Un saludo

[santafesino_lagunero]

URAN, gracias por la respuesta. Todavía no me puse a probar eso que me mostraste.

Mirá, la verdad es que... algo claro tengo de Visual Basic pero no tanto. Con el paso del tiempo fuí perdiendole un poco la maña. Estaba estudiando y por cuestiones laborales tuve que dejar y ahora que volví a retomar después de unos años para parte del proyecto de finalización me pidieron que resuelva eso pero la verdad, no recuerdo como hacerlo y hay cosas de VB que por no sentarme con tiempo (por falta de tiempo aclaro) lo fuí perdiendo.

El tema que me plantearon es simple: Tenés una tabla en una base de datos con 20 números previamente cargados y tenés 8 textboxs con números para ingresar. Lo que hay que hacer es buscar la mayor cantidad de coincidencias (hasta 8) en esos 20 números y que te muestre en un cuadro de texto cuantos números coinciden.

Espero haberme expresado bien y, gracias por tanta ayuda.

[Uran]

Hola de nuevo,


mira se me ha ocurrido una manera de realizar lo que dices con un código bastante simple (aunque tal vez algo largo):

1) Crear una tabla (Numeros), con un campo (numero) de tipo número y la he rellenado
2) He creado un formulario con 9 campos, 8 para los numeros a buscar (numero1, ..., numero8) y uno para los aciertos (aciertos).
3) He creado un botón al que le he agregado (en el evento _Click) el siguiente código:

Código vb:

Private Sub buscarAciertos_Click()
On Error GoTo Err_buscarAciertos_Click
 
    Dim db As Database
    Dim SQLText As String
    Dim rst As DAO.Recordset
    Dim numero1 As Boolean
    Dim numero2 As Boolean
    Dim numero3 As Boolean
    Dim numero4 As Boolean
    Dim numero5 As Boolean
    Dim numero6 As Boolean
    Dim numero7 As Boolean
    Dim numero8 As Boolean
    Dim numero As Integer
    Dim aciertos As Integer
            
    Set db = CurrentDb()
    
    numero1 = False
    numero2 = False
    numero3 = False
    numero4 = False
    numero5 = False
    numero6 = False
    numero7 = False
    numero8 = False
    numero = 0
    aciertos = 0
    
    SQLText = " SELECT * FROM Numeros "
    Set rst = db.OpenRecordset(SQLText, dbReadOnly)
    
    If Not (rst.BOF And rst.EOF) Then
        With rst
            Do While Not .EOF
                numero = .Fields("numero")
                If numero = Me!numero1 Then
                    numero1 = True
                End If
                If numero = Me!numero2 Then
                    numero2 = True
                End If
                If numero = Me!numero3 Then
                    numero3 = True
                End If
                If numero = Me!numero4 Then
                    numero4 = True
                End If
                If numero = Me!numero5 Then
                    numero5 = True
                End If
                If numero = Me!numero6 Then
                    numero6 = True
                End If
                If numero = Me!numero7 Then
                    numero7 = True
                End If
                If numero = Me!numero8 Then
                    numero8 = True
                End If
                .MoveNext
            Loop
        End With
        If numero1 Then
            aciertos = aciertos + 1
        End If
        If numero2 Then
            aciertos = aciertos + 1
        End If
        If numero3 Then
            aciertos = aciertos + 1
        End If
        If numero4 Then
            aciertos = aciertos + 1
        End If
        If numero5 Then
            aciertos = aciertos + 1
        End If
        If numero6 Then
            aciertos = aciertos + 1
        End If
        If numero7 Then
            aciertos = aciertos + 1
        End If
        If numero8 Then
            aciertos = aciertos + 1
        End If
        Me.aciertos = aciertos
    Else
        MsgBox ("Tabla no encontrada o no hay números para comparar.")
    End If
 
    Set rst = Nothing
    Set db = Nothing
    
Exit_Err_buscarAciertos_Click:
    Set rst = Nothing
    Set db = Nothing
    Exit Sub
 
Err_buscarAciertos_Click:
    MsgBox Err.Description
    Resume Exit_Err_buscarAciertos_Click
End Sub
 

Como ves funciona correctamente. Pero en el momento en el que se te añada un campo más al formulario hay que modificar el código...

Mira a ver si éste código te vale.

[santafesino_lagunero]

Hola Uran, te agradezco por el enorme esfuerzo que dedicás en ayudarme. También confieso que me ayuda mucho después de tanto tiempo ver código de otros programadores para "pulir" formas de programar o tratar quizás de entender mejor el lenguaje. Cuando lo pruebe bien te digo como fué.

[Uran]

No hay de qué, prueba y nos cuentas