Foros del web, para los que viven de bits

    Private Sub GuardarConfig(ByVal clave As String, ByVal valor As String)
        Dim xd As New XmlDocument
        Dim nombreWebConfig As String = Server.MapPath("../") & "web.config"
        xd.Load(nombreWebConfig)
        Dim Node As XmlElement = CType(xd.DocumentElement.SelectSingleNode( _
                                   "/configuration/appSettings/add[@key=""" & _
                                   clave & """]"), XmlElement)
        If Not Node Is Nothing Then
            'Clave encontrada, añade el valor
            Node.Attributes.GetNamedItem("value").Value = valor
        Else
            'Clave no encontrada, la crea
            Node = xd.CreateElement("add")
            Node.SetAttribute("key", clave)
            Node.SetAttribute("value", valor)

            'Busca el nodo
            Dim Root As XmlNode = xd.DocumentElement.SelectSingleNode("/configuration/appSettings")

            'Añade el nuevo nodo hijo (esta clave)
            If Not Root Is Nothing Then
                Root.AppendChild(Node)
            Else
                Try
                    'El nodo no existía, lo añade antes de crear el hijo
                    Root = xd.DocumentElement.SelectSingleNode("/configuration")
                    Root.AppendChild(xd.CreateElement("appSettings"))
                    Root = xd.DocumentElement.SelectSingleNode("/configuration/appSettings")
                    Root.AppendChild(Node)
                Catch ex As Exception
                    'Fallo al añadir el nodo, envía un error
                    Throw New Exception("Could not set value", ex)
                End Try
            End If
        End If

        'Finalmente, guarda la nueva versión del archivo de configuración
        xd.Save(nombreWebConfig)
    End Sub