como convertir a assci o ansi??

[Sir Matrix]

Hola...

Alguien sabe cómo puedo convertir un archivo .dat de codificación UTF8 a ASCII a través de VB 6, ya sea antes de abrir el archivo o al leerlo.

Esto porque los acentos y "eñes" me los lee el Visual como la mona.



saludssss

[dogduck]

http://groups.google.es/group/micros...f3c3fd8182563e

Private Const CP_UTF8 = 65001


Private Declare Function MultiByteToWideChar Lib "kernel32" ( _
ByVal CodePage As Long, ByVal dwFlags As Long, _
ByVal lpMultiByteStr As Long, ByVal cchMultiByte As Long, _
ByVal lpWideCharStr As Long, ByVal cchWideChar As Long) As Long


Public Function sUTF8ToUni(bySrc() As Byte) As String
' Converts a UTF-8 byte array to a Unicode string
Dim lBytes As Long, lNC As Long, lRet As Long


lBytes = UBound(bySrc) - LBound(bySrc) + 1
lNC = lBytes
sUTF8ToUni = String$(lNC, Chr(0))
lRet = MultiByteToWideChar(CP_UTF8, 0, VarPtr(bySrc(LBound(bySrc))),
lBytes, StrPtr(sUTF8ToUni), lNC)
sUTF8ToUni = Left$(sUTF8ToUni, lRet)
End Function


Public Sub ConvertUTF8File(sUTF8File As String, sANSIFile As String)
Dim iFile As Integer, bData() As Byte, sData As String, lSize As Long


' Get the incoming data size
lSize = FileLen(sUTF8File)
If lSize > 0 Then
ReDim bData(0 To lSize - 1)


' Read the existing UTF-8 file
iFile = FreeFile()
Open sUTF8File For Binary As #iFile
Get #iFile, , bData
Close #iFile


' Convert all the data to Unicode (all VB Strings are Unicode)
sData = sUTF8ToUni(bData)
Else
sData = ""
End If


' Now write it all out to the ANSI file
iFile = FreeFile()
Open sANSIFile For Output As #iFile
Print #iFile, sData
Close iFile
End Sub

salu2

[Sir Matrix]

o_O!!!
graciassss, no pense que respondieran tan rapido. Yo acabo de encontrar otra solución en: http://www.planet-source-code.com/vb...9&lngWId=1#zip

y funciona... bueno, pero muchisimas gracias de todos modos

[elbano66]

pana de casulidad sabes como hace para convertir un programa en vb en aplicacion, es decir una vez creado el programa hacerlo aplicacion.

[hadt]

com hago para utilizar ese codigo... apenas estoy empezando en VB y necesito solucionar ese mismo problema.. ya que necesito leer los archivos LOG que hace mi backup de cinta, pero tengo problrmas porque vienen en UNICODE..