Crear ComboBox y TextBox desde VB6.0

[XYON126]

Hola compañeros!

Hace tiempo que no pasaba por el foro debido a que estoy con otro soft pero ahora me encuentro con una duda y quisiera si alguien puede ayudarme.
Necesito hacer una macro donde pueda activando un botón abrir un TextBox y un ComboBox nuevo y naturalmente que el formulario se ajuste a la nueva linea. La idea es que en un formulario se visualicen varias filas iniciales y en cada fila habra un ComboBox y un textBox con un boton que hace que si no hay suficientes filas para introducir parejas de datos se habra automaticamente esta nueva fila. ¿Esto es posible? ¿Como me lo monto, que codigo, parametro o propiedad hace que se habra un nuevo ComboBox, textBox, etc.?

Un saludo y 1000 gracias por adelantado.

Aqui os envio dos pantallazos del macro.


Este es antes de presionar el boton lila.


Y este cuando solicitas una linea mas.(Boton lila presionado "NUEVA FILA").

[lokoman]

Hola!
Aquí tienes un ejemplo de como hacerlo:

• Agrega un Textbox con indice en cero (txt)
• Agrega un Label con indice en cero (lbl)
• Agrega un Command (cmd)

Código vb:

Private Sub cmd_Click()
    Dim IND As Integer
    
'PARA EL LABEL
    IND = lbl.UBound + 1
    
    Load lbl(IND)
    
    lbl(IND).Left = 120
    lbl(IND).Top = lbl(IND - 1).Top + lbl(IND - 1).Height + 45
    lbl(IND).Width = lbl(IND).Width
    lbl(IND).Caption = "Indice: " & IND
    lbl(IND).Visible = True
    
'PARA EL TEXTBOX
    IND = txt.UBound + 1
    
    Load txt(IND)
    
    txt(IND).Left = 2160
    txt(IND).Top = txt(IND - 1).Top + txt(IND - 1).Height + 45
    txt(IND).Width = txt(IND).Width
    txt(IND).Text = "Indice: " & IND
    txt(IND).Visible = True
    
'PARA EL COMMAND
    cmd.Top = txt(IND).Top + txt(IND).Height + 45
    
'PARA LA FORMA
    If Me.WindowState = 0 Then If cmd.Top >= 2580 Then Me.Height = Me.Height + cmd.Height
End Sub
 

Nos cuentas!!

[XYON126]

Hola lokoman!

Perfecto esto es lo que queria hacer pero tengo un par de consultas .:

1ª ¿Que hace la parte de "FORMA"? ya que no veo cambio alguno en el formulario y hace referencia al boton que ya tiene un desplazamiento en el apartado 'PARA EL COMMAND.

2ª ¿Hay alguna manera de no utilizar el Indice = 0? me explico, resulta que quiero hacer este macro pero para VBA CATIA, que utiliza un VB practicamente igual al VB 6.0, pero no tiene la propiedad de "Indice" en sus controles o no he sabido encontrarla.

3ª Veo que utilizas el comando "Load" para agregar comandos supongo que para lo inverso es exactamente igual pero con "Unload" y en vez de aumentar el Top se reduce naturalmente.

4ª ¿este metodo es valido para todo tipo de controles o es limitado solo para algunos?.

5º Y ultima, tanto si se utiliza el metodo con Indice=0 o si hubiese uno sin utilizar el Indice=0, ¿Como o que deben tener el resto de controles del formulario que no deban ser duplicados, o solo con el nombre personalizado y sin posible relación alguna a estos es suficiente para que no les afecte?


Muchas gracias un saludote

[lokoman]

1-El apartado "FORMA" hace lo que pediste: "el formulario se ajuste a la nueva linea", o sea, al añadir un nuevo TEXTBOX, LABEL, etc. el formulario AUMENTA su tamaño, pero esto solo pasa si los controles llegan a la parte inferior del formulario

2-El indice=0 es porque los controles que se cargan pertenecen a un ARREGLO, por eso la instruccion LOAD. Hay otra forma:

http://msdn.microsoft.com/en-us/libr...(v=vs.80).aspx

Código vb:

' Visual Basic 6.0
Private Sub Command1_Click()
    ' Declare a new Control variable.
    Dim c As Control
    ' Create and add the new control.
    Set c = Controls.Add("VB.TextBox", "Text1")
    ' Make the new control visible.
    c.Visible = True
    ' Set the initial text.
    c.Text = "Hello"
    ' Retrieve the text from the new TextBox.
    If Controls.Count > 1 Then
        MsgBox (Controls("Text1").Text)
    End If
    ' Remove the new control.
    Controls.Remove (Text1)
    ' The following line causes a compilation error.
    ' You cannot remove controls added at design time.
    Controls.Remove (Command1)
End Sub
 

3-El UNLOAD es para descargar objetos, el TOP no se reduce automáticamente, cuando uso el LOAD el TOP lo calculo para que no queden los controles unos sobre otros, el UNLOAD solo quita el objeto que le dices, si quitas el TEXTBOX numero 3, el TEXTBOX numero 4 (que esta abajo), no va a subir, hay que calcularle el TOP

4-Es valido para todos los controles de VB, si son un arreglo (indice=0)

5-Con el codigo de ejemplo del punto numero 2, puedes cargar cualquier objeto, solo debes ponerle un nombre diferente a cada uno

[XYON126]

Hola lokoman!

Entonces, si no he entendido mal, esta nueva opción seria crear tantas colecciones como controles quiera duplicar, por ejemplo:

Código vb:

Dim txt, lbl As Control
 
Set txt = Controls.Add("VB.TextBox", "Text1")
 
Set lbl = Controls.Add("VB.Label", "Label1")
 

¿y para poder controlar e identificar cada control, estos los deberia de tener tambien en otra matriz o como/que deberia hacer para poderles situar e identificar?.

Un saludo

PDTA: Por cierto el otro metodo lo he realizado y para VB6.0 me queda de coña pero no me funciona en VBA CATIA. Por si a alguien le interesa aqui posteo el codigo con TextBox y Label dinamicos y un boton para duplicar y otro para borrar.

Código vb:

Private Sub Form_Load()
 
    IND = lbl.UBound
     
    If IND = 0 Then cmd_BorrarLinea.Enabled = False
    
End Sub
Private Sub cmd_BorrarLinea_Click()
    'Dim IND As Integer
       
    'PARA EL LABEL
        IND = lbl.UBound
             
        Unload lbl(IND)
       
               
    'PARA EL TEXTBOX
        IND = txt.UBound
       
        Unload txt(IND)
       
    'PARA EL COMMAND
        cmd_NuevaLinea.Top = txt(IND - 1).Top - 45
        cmd_BorrarLinea.Top = txt(IND - 1).Top - 45 'txt(IND).Height - 45
       
    'PARA LA FORMA
        
        Me.Height = Me.Height - cmd_NuevaLinea.Height
        If IND = 1 Then cmd_BorrarLinea.Enabled = False
End Sub
 
    Private Sub cmd_NuevaLinea_Click()
        'Dim IND As Integer
       cmd_BorrarLinea.Enabled = True
    'PARA EL LABEL
        IND = lbl.UBound + 1
       
        Load lbl(IND)
       
        lbl(IND).Left = 240
        lbl(IND).Top = lbl(IND - 1).Top + lbl(IND - 1).Height + 45
        lbl(IND).Width = lbl(IND).Width
        lbl(IND).Caption = "Indice: " & IND
        lbl(IND).Visible = True
       
    'PARA EL TEXTBOX
        IND = txt.UBound + 1
       
        Load txt(IND)
       
        txt(IND).Left = 3480
        txt(IND).Top = txt(IND - 1).Top + txt(IND - 1).Height + 45
        txt(IND).Width = txt(IND).Width
        txt(IND).Text = "Indice: " & IND
        txt(IND).Visible = True
       
    'PARA EL COMMAND
        cmd_NuevaLinea.Top = txt(IND).Top + 45
        cmd_BorrarLinea.Top = txt(IND).Top + 45 'txt(IND).Height + 45
        
    'PARA LA FORMA
        
        Me.Height = Me.Height + cmd_NuevaLinea.Height
        
    End Sub
 

[lokoman]

Con este codigo le puedes asignar los eventos:

Código vb:

Option Explicit
Dim WithEvents txtTexto As VB.TextBox
 
Private Sub cmd_Click()
    Set txtTexto = Controls.Add("VB.TextBox", "Text1")
    txtTexto.Visible = True
End Sub
 
Private Sub txtTexto_Click()
    MsgBox "Tengo el foco!!"
End Sub