declara una variable tipo picturebox

[Betina232022]

Hola a todos, espero se encuentren bien.

Declaro una variable tipo picturebox y después le asigno una imagen de la siguiente manera

dim Pic as PictureBox
Pic.Picture = LoadPicture("imagen.wmf")

me marca el siguiente error:
Object variable or with block variable not set

le pongo el Set antes del Pic.Picture y nada sigue igual.

Alguien sabe que me falta?

gracias y buen día

[pkj]

Un picture lo propio es agregarlo como objeto en tiempo de diseño y te evitas complicaciones.

Si tienes necesidad de hacerlo desde código creo que este es el modo:

' declaras el picture como PicTemp1
Dim PicTemp1 As VB.PictureBox
Set PicTemp1 = Form1.Controls.Add("VB.PictureBox", "PicTemp1", Form1)

' Y a partir de aquí lo tienes que mostrar, redimensionar y colocar donde deba ir, (aparte de cargarle la imagen).
PicTemp1.Picture = LoadPicture("foto.jpg")
PicTemp1.Visible = True
PicTemp1.Top = 0
PicTemp1.Left = 0
PicTemp1.Height = 500
PicTemp1.Width = 500
' como no se redimensiona solo tienes que buscarte la vida para darle el tamaño adecuado al picture.

' Para eliminar el picture se usa esto
Form1.Controls.Remove "PicTemp1"

Puede que te interese mejor usar un control image que puede redimensionar la imagen al tamaño del objeto de modo que solo tienes que darle el tamaño que desees.

Dim Image1 As VB.Image
Set Image1 = Form1.Controls.Add("VB.Image", "Image1", Form1)

' para que se ajuste la imagen al tamaño del control
Image1.Stretch = True

Image1.Picture = LoadPicture("foto.jpg")

Image1.Visible = True
Image1.Top = 0
Image1.Left = 0
Image1.Height = 1000
Image1.Width = 1000

' cuando quieras eliminarla:
Form1.Controls.Remove "Image1"

Saludos

[erbuson]

Hola:

Intenta con esto, creo que es como debe hacerse.

Código:

 ' Dimensionar Objeto Picture
 Dim Pic As IPictureDisp
 ' Cargarlo, con una imagen  
 Set Pic = LoadPicture("C:\PerroSalchicha.jpg")

 ' Asignar la imagen a un Picture para ver que funciona
 Picture1.Picture = Pic
 ' Borrar la imagen del Objeto Picture 
 Set Pic = Nothing

Saludos

Pd: Te amplio la información para tí o para otros en el futuro.
Cargar Imagen en Variable

Como no, de RECURSOS VISUAL BASIC

[Betina232022]

Hola, muchas gracias por su ayuda, ya funciono.