Email con VB6

[juaco14]

Alguien sabe como enviar el contenido de 2 textbox y 1 combo a un email especifico?.

Al clickear un cmd que envie esos datos a un mail especifico sin que ocurra nada.
Probe varias maneras pero ninguna me funciono.
Gracias!!

[cborrero]

Explicate mejor.!!!

si es hacer un cliente de enviar correos en google hay muchos ejemplos.

http://www.recursosvisualbasic.com.ar/htm/ocx-componentes-activex-dll/77-ocx-para-enviar-email.htm

[STK_Pablo]

Mira, yo utilizo esta rutina que lo que realiza es enviar el mail al Outlook y desde alli se envia al destinatario.... Posee varias opciones porque yo la utilizo en un sistema que envio distyintos tipos de email y los tengo personalizados con templates pero es bastante sencillo de entender, espero te sirva:

Código vb:

Public Sub EnviarEmail(emlTO As String, Optional emlPROFESIONAL As String = "", Optional emlPACIENTE As String = "", Optional emlADJUNTOS As String = "", Optional emlTITULO As String = "[ROA srl] - Informe de Estudio", Optional emlTEMPLATE As String = "DEFAULT")
  ' Iniciar Outlook.
  ' Si ya se está ejecutando, utilizará la misma instancia...
  Dim olApp As Outlook.Application
  Dim imgs() As String
  Dim adjuntos() As String
  Dim emlBODY As String
  Set olApp = CreateObject("Outlook.Application")
  'Inicio de sesión. No importa si ya lo está ejecutando y tiene iniciada una sesión...
  Dim olNs As Outlook.NameSpace
  Set olNs = olApp.GetNamespace("MAPI")
  olNs.Logon
  ' Enviar un mensaje
  Dim olMail As Outlook.MailItem
  Set olMail = olApp.CreateItem(olMailItem)
  olMail.BodyFormat = olFormatHTML
  olMail.ReadReceiptRequested = True      'Solicito confirmación de lectura
  olMail.OriginatorDeliveryReportRequested = True
  ' Rellenar y enviar el mensaje...
  'Cargar datos pasados como parametros
  If SISTEMA_DEBUG Then
    olMail.To = "[email protected]"
  Else
    olMail.To = emlTO
  End If
  olMail.Subject = emlTITULO
  'Levanto desde la configuracion del template
  oSQL = "SELECT * FROM templates WHERE nombre = '" & emlTEMPLATE & "';"
  ConectarDB
  CrearRST (oSQL)
  If Not stkRST.EOF Then
    imgs = Split(stkRST!IMAGENES, ";")
    For Cont = LBound(imgs) To UBound(imgs)
      olMail.Attachments.Add App.Path & "\graphs\templates\" & imgs(Cont)
    Next Cont
    emlBODY = Replace(stkRST!Body, "<-PROFESIONAL->", emlPROFESIONAL)
    emlBODY = Replace(emlBODY, "<-PACIENTE->", emlPACIENTE)
    olMail.HTMLBody = emlBODY
  Else
    MsgBox "ERROR: No se encuentra el TEMPLATE solicitado"
  End If
  CortarDB
  'Imagenes adjuntas...
  If emlADJUNTOS <> "" Then
    adjuntos = Split(emlADJUNTOS, "|")
    For Cont = LBound(adjuntos) To UBound(adjuntos)
      olMail.Attachments.Add adjuntos(Cont)
    Next Cont
  End If
  olMail.Save
  olMail.Send
  olNs.Logoff
  Set olNs = Nothing
  Set olMail = Nothing
  Set olApp = Nothing
End Sub
 

No te olvides de hacer referencia desde tu proyecto a la libreria del Microsoft Outlook xx.xx Object Library

Eso es todo

[gasafonso]

Como es el tema de los templates ?

Me lo podes explicar mejor

gracias por el aporte !!!!!!!!!!!!!!!!!!!!

[STK_Pablo]

El ejemplo que te pase lo saque de un proyecto que estoy desarrollando en estos momentos, y una de las necesidades que posee es poder personalizar el formato de los correos segun el destinatario (profesional, paciente, obra social, backup, etc) por esto trabajo con una tabla de acces donde en un campo MEMO pongo el codigo html del correo a enviar segun el caso y dentro de este html tengo variables del tipo <-PACIENTE-> que en el momento de generar el correo y enviarlo las reemplazo por el valor que corresponde para poder personalizar el correo.
Para ello utilizo un simple txtHTML=Replace(txtHTML,"<-NOMBRE->",variableNombre)
Espero haber aclarado un poco el tema....

[smoke001]

Con este codigo puedes enviar un email desde vb sin html configurando tu servidor SMTP

Código Visual Basic:

Private Sub Command1_Click()
Call Enviar
End Sub
 
 
Private Sub Enviar()
Const sch = "http://schemas.microsoft.com/cdo/configuration/"
 
Dim INI_PATH As String
Dim loCfg As Object
Dim loMsg As Object
Dim loBP As Object
Dim i As Long
Dim DestImg As String
Dim TempHTML As String
Dim TempHTMLMail As String
Dim strImg As String
 
 
 
 
 
Me.Enabled = False
FrmProgress.Show , Me
DoEvents
 
Set loCfg = CreateObject("CDO.Configuration")
 
With loCfg.Fields
  .Item(sch & "smtpserver") = "localhost"
  .Item(sch & "smtpserverport") = "25"
  .Item(sch & "sendusing") = 2
  .Item(sch & "sendusername") = "[email protected]"
  .Item(sch & "sendpassword") = "1234"
  .Item(sch & "smtpusessl") = "0"
  .Item(sch & "smtpconnectiontimeout") = 30
  .Item(sch & "smtpauthenticate") = "1"
End With
 
loCfg.Fields.Update
 
Set loMsg = CreateObject("CDO.Message")
 
With loMsg
  .Configuration = loCfg
  
  
  .From = ("[email protected]")
  .To = TxtPara
  .TextBody = Text1.Text
  .Subject = TxtAsunto
     
    'Prioridad
    ' -1=Low, 0=Normal, 1=High
    .Fields("urn:schemas:httpmail:priority") = 1
    .Fields("urn:schemas:mailheader:X-Priority") = 1
    'Importancia
    '0=Low, 1=Normal, 2=High
    .Fields("urn:schemas:httpmail:importance") = 2
    
        
    .Fields.Update
    .send
End With
Me.Enabled = True
Unload FrmProgress
     Email.Check1.Value = 1
 
 
 
Exit Sub
End Sub
 
Private Sub Form_Load()
Set HTML = Text1
End Sub
 

[okmancera]

Muchas gracias por ese aporte tan importante, definitivamente muy importante el comentario de activar la libreria de Ouutllok, dado que sin eso NO funcional el código.