FAQ's de VB6

[culd]

Si tenes una ruta y solo queres el nombre del archivo, esta funcion sirve para eso...

Solamente se envia la ruta completa y devuelve el nombre del archivo.

Código vb:

'************** PROGRAMADO POR CULD *****************
'****************************************************
Public Function Nombre_Archivo(Ruta As String)
Dim X As Integer
Dim Hasta As Integer
 
'Recorro de atras para adelante
For X = Len(Ruta) To 1 Step -1
    'separo caracter por caracter, hasta encontrar la marca que seria el \
    If Mid(Ruta, X, 1) = "\" Then
        'como encontre esa marca, significa que ya termino el nombre del archivo
        'entonces resto el largo total de toda la ruta, menosla posicion en la que encontre
        'ese resultado es el largo del nombre del archivo
        Hasta = Len(Ruta) - X
        Exit For
    End If
Next X
 
'separo de derecha a izquierda la cantidad de caracteres que corresponde al nombre del archivo
Nombre_Archivo = Right(Ruta, Hasta)
End Function
 

[David]

Otra forma de obtener el nombre del archivo a partir de la ruta:

Código vb:

Public Function Nombre_Archivo(Ruta As String)
Dim Partes() As String
Partes = Split(Ruta, "\")
Nombre_Archivo = Partes(UBound(Partes))
End Function
 

O también:

Código vb:

Public Function Nombre_Archivo(Ruta As String)
Nombre_Archivo = Right(Ruta, Len(Ruta) - InStrRev(Ruta, "\"))
End Function
 

[totigo]

Hola, a continuacion quiero compartirles las instrucciones para redimensionar el tamaño de una imagen a 640x480, la cual se carga en un control image.

Lo primero es colocar las declaracion en un modulo BAS, ejemplo module1.bas:

Código vb:

Public Const IMAGE_BITMAP = 0
Public Const LR_COPYRETURNORG = &H4
Public Const CF_BITMAP = 2
Public Declare Function SetClipboardData Lib "user32" (ByVal wFormat As Long, ByVal hMem As Long) As Long
Public Declare Function CopyImage Lib "user32" (ByVal handle As Long, ByVal imageType As Long, ByVal newWidth As Long, ByVal newHeight As Long, ByVal lFlags As Long) As Long
Public Declare Function EmptyClipboard Lib "user32" () As Long
Public Declare Function CloseClipboard Lib "user32" () As Long
Public Declare Function OpenClipboard Lib "user32" (ByVal hwnd As Long) As Long
 

Seguidamente viene la instruccion que hace el trabajo pesado y que colocamos por ejemplo en el evento click de un boton :

controles : Boton, Image Control

Código vb:

Dim hNew2 As Long
 
Image1.Picture = LoadPicture("C:\Users\desarr\Desktop\foto.jpg")
 
hNew2 = CopyImage(Image1.Picture, IMAGE_BITMAP, Val(640), Val(480), LR_COPYRETURNORG)
OpenClipboard Me.hwnd
EmptyClipboard
SetClipboardData CF_BITMAP, hNew2
CloseClipboard
 
Image1.Picture = Clipboard.GetData(2)
SavePicture Image1.Picture, "C:\Users\desarr\Desktop\foto2.bmp"
 

Hecho! redimensiona la imagen al tamaño de 640x480 (foto2.bmp), si requiere otro tamaño entonces modificalo!

Espero sea de utilidad para muchos!

Nota : la funcion SavePicture solo genera BitMaps - BMPs, hay controles OCX - DLL para generar a otros formatos como el PicFormat32.OCX

[culd]

Subproceso para buscar algo en un listbox y si lo encuentra seleccionarlo

Código vb:

'Programador por ..::][CULD][::.. a pedido de gerardo_goh
'-----------------------------------------------------------------------
'Este subproceso busca una palabra en un ListBox y si la encuentra
'la selecciona
'-----------------------------------------------------------------------
Public Sub ListBox_buscarYseleccionar(List As ListBox, Buscar As String)
Dim X As Integer
 
For X = 0 To List.ListCount - 1
    If UCase(List.List(X)) = UCase(Buscar) Then
        List.ListIndex = X
        Exit Sub
    End If
Next X
End Sub
 

[culd]

Iniciado por alkor16

nesesito desarrollar una aplicacion de visual basic que lea 3 valores y calcule el cuadrado del mayor y el cubo del menor y el promedio de los 3 y que los resultados se displayaran mediante mensaje en el cuadro de dialogo.

plis ayuda xD tengo una tarea urgente ayuda.

Código vb:

'-------------------------------------------------------------------------
' Desarrollado por ..::][culd][::.. a pedido de "alkor16" para ForosDelWeb
'-------------------------------------------------------------------------
Dim Valores(1 To 3) As Double   'Vector que va a acumular los 3 o mas valores a pedir
Dim X As Integer                'Variable que voy a usar para los for
Dim Aux As Double               'Variable auxiliar para el metodo burbuja
Dim Termino As Boolean          'Variable de control para saber si termino el metodo burbuja
Dim Cuadrado As Double          'Resultado del cuadrado del mayor
Dim Cubo As Double              'Resultado del cubo del menor
Dim Promedio As Double          'Promedio de los tres numeros
 
'Uso un for para ir pidiendo los valores, mediante un inputbox
For X = 1 To 3
    Valores(X) = InputBox("Ingrese un numero")
Next X
 
'Esto se llama metodo burbuja (lo habran aprendido en la universidad algunos)
'Consiste en recorrer el vector/matrix y comparar el valor de la posicion actual
'con el valor siguiente.
'Se verifica si es mayor/menor y si lo es se guarda uno en una variable auxiliar
'y se reemplazan de lugar
'NOTA: Si hay cambios, significa que probablemente existan todavia numeros a modificar
'por ende se usa una variable de control en este caso un boolean.
Termino = False
Do While Termino = False
    Termino = True                              'Asigno que termino para saber despues si realmente termino
    For X = 1 To 2                              'Inicio el recorrido
        If Valores(X) < Valores(X + 1) Then     'Controlo si el actual es menor que el siguiente asi subo el siguiente y bajo el actual
            Aux = Valores(X)                    'Guardo en una variable auxiliar para no perderlo
            Valores(X) = Valores(X + 1)         'Reemplazo
            Valores(X + 1) = Aux                'Asigno el valor guardado
            Termino = False                     'Como hubo un cambio asigno que no termino el metodo burbuja para dar otra ronda despues
        End If
    Next X
Loop
 
'calculo el cuadrado del mayor (si o si el mayor va a estar en el primer lugar)
Cuadrado = Valores(1) ^ 2
'calculo el cubo del menor (si o si va a estar en el ultimo lugar)
Cubo = Valores(3) ^ 3
'el promedio es la division de la cantidad de operandos, sobre la suma de los mismos (matematica basica)
Promedio = (Valores(1) + Valores(2) + Valores(3)) / 3
 
'Informo los resultados y el derecho de autor ;)
MsgBox "Los numeros ingresados de mayor a menor son:" & vbNewLine _
& Valores(1) & vbNewLine _
& Valores(2) & vbNewLine _
& Valores(3) & vbNewLine & vbNewLine _
& "El cuadrado del mayor es: " & Cuadrado & vbNewLine & vbNewLine _
& "El cubo del menor es: " & Cubo & vbNewLine & vbNewLine _
& "El promedio de los tres es: " & Promedio & vbNewLine & vbNewLine & _
"Ejemplo realizado por ..::][culd][::.. a pedido de alkor16 para ForosDelWeb"
 

[culd]

Iniciado por gogupe

Hola a todos.

He hecho una matriz de controles de un timer

He hecho lo siguiente

load timer(0)
load timer(1)
load timer(2)

Me cargará como tantos timer como usuarios se conecten a mi sistema, hasta aquí todo bien.

El problema me lo encuentro que esto lo quiero chequear cada cierto tiempo, pero ¿como se que el control ya está cargado?, es que si no, me da el error de que el objeto ya se ha cargado

Quiero algo asi como: si timer(0) ya está cargado --> no cargar

Muchas gracias a todos

La respuesta a tu problema aca te la arme:

Código VB:

'Programado por CULD a pedido de GUGOPE
'------------------------------------------------------------------
'Esta es una funcion que tiene como parametro un objeto timer
'al que se lo quiere conocer si se encuentra cargado en tiempo de
'ejecucion... Por ejemplo si tenemos un vector de controles Timer
'y queremos conocer si un timer en particular esta cargado, se le
'envia como parametro el timer en cuestion y devuelve TRUE/FALSE
'------------------------------------------------------------------
'Esto es a pedido de GUGOPE en el post:
'http://www.forosdelweb.com/f69/saber-si-control-esta-cargado-732407/
'------------------------------------------------------------------
Public Function EstaCargadoTimer(ElTimer As Timer) As Boolean
On Error GoTo NoEstaCargado
If ElTimer.Index > 0 Then
    EstaCargadoTimer = True
End If
Exit Function
NoEstaCargado:
EstaCargadoTimer = False
End Function
 

[A.H.H]

ELIMINAR TEMPORALES IE, COOKIES, HISTORIAL , FORMULARIOS.........


Hola el siguiente codigo es para borrar desde vb6 los temporales de internet (ie), asi como el historial, las cookies, add-ons etc...
Sirve para internet 7 y 8 ......
Colocar en un boton lo siguiente:

Private Sub Command1_Click()
Shell "Rundll32.exe inetcpl.cpl, ClearMyTracksByProcess 4351", vbNormalFocus
End Sub

[culd]

Iniciado por RocKRKO

ola ola soy algo nuevo en esto del vB6 jeje pero me encanta este foro asi que espero me ayuden miren para ustedes maestros del vB6 resultara algo facil jeje

Lo que tengo que hacer es clasificar unas entradas de datos con una matriz

Primero se piden los datos con un inputbox algo asi

Código:

Private Sub Command1_Click()
For indice = 0 To 2
    edades(indice) = InputBox("Teclea La edad de Tu Alumno", "Teclea La edad")
    If edades(indice) = "0" Then
    MsgBox "Error, Teclea una edad desde 4 en adelante ...", vbInformation, "Error"
    End If
    If edades(indice) < 4 Then
    MsgBox "No se admiten Niños Menores de 4 Años", vbInformation, "No Admitido"
    End If
    Select Case edades(indice)
    Case 4 To 6:
    For x = 0 To 2
    List1.AddItem edades(x)
    Next x
    Case 7 To 8
    For y = 0 To 2
    List2.AddItem edades(y)
    Next y
    Case 9 To 12
    For n = 0 To 2
    List3.AddItem edades(n)
    Next n
    End Select
    
Next

End Sub

Y dependiendo que edad tenga el alumno se clasificara en 4 textbox

de 4 a 6 categoria 1
de 7 y 8 categoria 2
de 9 y 10 categoria 3
de 11 en adelante categoria 4

pero tienen que aparecer en los textbox cuantos son de cada categoria pero no se como xD trate de agruparlos en un listbox poniendo el siguiente code

Código:

  For n = 0 To 2
    List3.AddItem edades(n)
    Next n

y si se clasifican pero aparecen los valores de los anteriores y valores de 0

alguien me podriia ayudar =(

Segun lo que entendi, lo que necesitas es lo siguiente:

1- El usuario ingresa edades de alumnos
2- Las edades se van guardando en un vector segun categoria de edades
3- Al finalizar muestra la informacion de cantidades segun categoria

Bueno, lo hise sin ningun objeto, osea directamente con input y msgbox, despues pone los objetos que necesites (lease texbox, listbox, o lo que prefieras)

Código vb:

'-------------------------------------------------------------------------
' Desarrollado por ..::][culd][::.. a pedido de "RocKRKO" para ForosDelWeb
'-------------------------------------------------------------------------
 
Dim Edad As String                  'variable que maneja la informacion ingresada por el usuario
Dim EdadI As Integer                'variable para la edad pero integer para trabajarla mejor
Dim Categoria(1 To 4) As Integer    'vector que contiene las cantidades de alumnos segun categoria
 
'Estructura repetir hasta que
Do
    'pido la edad al usuario
    Edad = InputBox("Ingrese la edad del alumno" & vbNewLine & "Ingrese 0 o menos para finalizar", "Edad")
    'verifico si es numerica
    If IsNumeric(Edad) = True Then
        'guardo la edad en una variable del tipo integer
        EdadI = CInt(Edad)
        'verifico si la edad es mayor que 0
        If EdadI > 0 Then
            'verifico si la edad es mayor o igual que 4
            If EdadI >= 4 Then
                'estructura condicional multiple
                Select Case EdadI
                    Case 4 To 6:    'de 4 a 6 años sumo en la categoria 1
                        Categoria(1) = Categoria(1) + 1
                    Case 7 To 8:    'de 7 a 8 años sumo en la categoria 2
                        Categoria(2) = Categoria(2) + 1
                    Case 9 To 10:   'de 9 a 10 años sumo en la categoria 3
                        Categoria(3) = Categoria(3) + 1
                    Case Is >= 11:  'de 11 en adelante sumo en la categoria 4
                        Categoria(4) = Categoria(4) + 1
                    Case Else:      'si es otro numero le devuelvo error y no sumo nada
                        MsgBox "La edad ingresada no corresponde a ninguna categoria", vbCritical
                End Select
            Else
                'devuelvo el error de que es menor de 4 años
                MsgBox "No se permite menores de 4 años", vbCritical
            End If
        End If
    Else
        'Asigno "1", ya que puede ser que en primera instancia ingrese una letra
        'y la veriable estaria cereada y directamente el repetir finalizaria
        EdadI = 1
        'informo que no es un numero valido
        MsgBox "No ingreso un numero valido", vbCritical
    End If
Loop Until EdadI <= 0
 
'cuando el usuario no quiere ingresar mas muestro los resultados de las
'cantidades de alumnos segun la categoria
MsgBox "Cantidad de Alumnos por Categoria" & vbNewLine & vbNewLine & _
"Categoria 1: " & Categoria(1) & vbNewLine & _
"Categoria 2: " & Categoria(2) & vbNewLine & _
"Categoria 3: " & Categoria(3) & vbNewLine & _
"Categoria 4: " & Categoria(4)
 

[culd]

A pedido del amigo aca en el foro, que queria hacer un conversor similar al de una web, me tome el trabajo de hacerlo de la forma mas faicl y efectiva... Lo dejo para que abran la mente de como hacer este tipo de algoritmo matematico en pocas lineas de codigo....

Iniciado por sergimbo

Hola! Pues resulta que estoy haciendo un conversor de unidades el cual sigue este formato:

http://elticus.com/?contenido=56&allmsg#mensajes


El boton de "Unidad" lo tengo muy claro pero el problema lo tengo con calcular.

Resulta que ese conversor tu puedes pasar de metros a pulgadas etc. pero tambien de pulgadas a metros sin importar el orden. Asi pues tu en el label correspondiente a yardas, por ejemplo, pones un numero cualquiera y te saca la equivalencia en las demas.


La cosa es, como puedo hacer que el visual basic sepa que label de esas 6 tenga algun numero? Es decir, como le digo al programa "si la label de nombre "lblyardas" tiene un numero haz estas operaciones=?

Otra cosa, como puedo hacer para que solo se pueda escribir en una label de las 6 a la vez?

Gracias por su ayuda

Lo tome como un ejercicio mental, asi que me tome el trabajo de hacerlo.

- Insertar 2 CommandButton
BUnidad
BCalcular

- Insertar una matris de TextBox (6 elementos)
txtNumero

Copiar el siguiente codigo en el Formulario:

Código vb:

Dim Medidas(0 To 5) As Double
 
 
Private Sub BCalcular_Click()
Dim Indice As Integer
Dim X As Integer
 
For X = 0 To 5
    If Trim(txtNumero(X)) <> "" Then
        Indice = X
        Exit For
    End If
Next X
 
For X = 0 To 5
    If X <> Indice Then
        txtNumero(X) = Round((CDbl(txtNumero(Indice)) * Medidas(X)) / Medidas(Indice), 5)
    End If
Next X
End Sub
 
Private Sub BUnidad_Click()
Dim X As Integer
For X = 0 To 5
    txtNumero(X).Text = Medidas(X)
Next X
End Sub
 
Private Sub Form_Load()
Medidas(0) = 1
Medidas(1) = 39.3701
Medidas(2) = 3.28084
Medidas(3) = 1.09361
Medidas(4) = 0.00062
Medidas(5) = 0.00055
End Sub
 
Private Sub txtNumero_GotFocus(Index As Integer)
Dim X As Integer
For X = 0 To 5
    txtNumero(X).Text = ""
Next X
End Sub
 

[culd]

Segun lo que pidieron en el foro, un ejemplo sensillo de una ventana emergente al estilo del msn.

Solo tienen que crear un form, y agregar un commandbutton y un timer... Al timer ponerle ENABLED=FALSE y INTERVAL=10

Con eso pueden hacer la prueba y lograr el efecto, luego lo adaptan y mejoran como ustedes quieren.

Código vb:

Private Sub Command1_Click()
Me.Top = Screen.Height
Me.Left = Screen.Width - Me.Width
Timer1.Enabled = True
End Sub
 
Private Sub Timer1_Timer()
If Me.Top > (Screen.Height - Me.Height) Then
    Me.Top = Me.Top - 100
Else
    Timer1.Enabled = False
End If
End Sub
 

[educito24]

alguien sabe como hacer unas funciones para un textbox qeu acepte solo MAYUSCULAS, NUmero Enteros, Decimales Negativos, Decimales Positivos, Letras etc.
graciass. espero respuesta alguna