Inactividad del mouse y teclado VB

[Aioros-jms]

Hola que tal, esperando que me puedan ayudar con lo siguiente:

Por medio de Vb 6.0 como puedo saber que el usuario no ha movido el "Mouse" u oprimido alguna tecla. Pero que no presisamente este en la aplicación o en primer plano o tenga el focus. Espero haber dado a entender.

Un ejemplo; el Skype despues de un determiando tiempo (5 mins por ejemplo sin actividad en el ordenador) cambia su icono a ausente.

Bien que tengas un buen día!! saludos, desde ya mil gracias!!!

[seba123neo]

Hola, con la api llamada GetQueueStatus podes saber el tiempo inactivo...un ejemplo que se cierra despues de 5 segundos de inactividad..

Código vb:

Option Explicit
 
Private Declare Function GetQueueStatus Lib "user32" (ByVal fuFlags As Long) As Long
 
Private Const QS_KEY = &H1
Private Const QS_MOUSEMOVE = &H2
Private Const QS_MOUSEBUTTON = &H4
Private Const QS_MOUSE = (QS_MOUSEMOVE Or QS_MOUSEBUTTON)
Private Const QS_INPUT = (QS_MOUSE Or QS_KEY)
 
Public bCancel As Boolean
 
Public Sub Inactividad(ByVal TimeOut_InSec As Long)
    Dim t As Long
    t = Timer
    Do While bCancel = False
      If GetQueueStatus(QS_INPUT) Then
         t = Timer
         DoEvents
      End If
      If Timer - t >= TimeOut_InSec Then Exit Do
    Loop
    If bCancel = False Then MsgBox "La Aplicacion se cerro despues de " & Timer - t & " segundos inactiva": Unload Me
End Sub
 
Private Sub Form_Load()
    Me.Show
    Call Inactividad(5)
End Sub
 
Private Sub Form_Unload(Cancel As Integer)
    bCancel = True
End Sub
 

saludos.

[Aioros-jms]

Hola muchas gracias por tu aporte, me es de mucha ayuda, es precisamente lo que necesito, pero hay un detalle, solo que funciona solo si la ventana esta activa, pero por ejemplo si ando en el explorador de windows, etc, (eso quiere decir que estoy utilizando el ordenador), de acuerdo al codigo proporcionado, requiero que no se cierre el formulario si ando haciendo algo en el ordenador.

De ante mano gracias!!! espero que me puedan ayudar con ese pequeño detalle. saludos que pasen un tarde agradable.

[Marcelote]

Hola, mira este código. Lo consigue con relativa simplicidad, sin necesidad de subcalsificaciones que siempre son delicadas. Ejecútalo y espera unos 10 segundos.... incluso en segundo plano.

planet-source-code.com/vb/scripts/ShowCode.asp?txtCodeId=66065&lngWId=1

(ponle delante las tres w pues el sistema del Foro me considera novato y se ve que no se fía, no me deja poner enlaces)

Un saludo.

[seba123neo]

Iniciado por Aioros-jms

Hola muchas gracias por tu aporte, me es de mucha ayuda, es precisamente lo que necesito, pero hay un detalle, solo que funciona solo si la ventana esta activa, pero por ejemplo si ando en el explorador de windows, etc, (eso quiere decir que estoy utilizando el ordenador), de acuerdo al codigo proporcionado, requiero que no se cierre el formulario si ando haciendo algo en el ordenador.

De ante mano gracias!!! espero que me puedan ayudar con ese pequeño detalle. saludos que pasen un tarde agradable.

pues es simplemente agregale para que saque la ventana activa tambien y si la ventana activa es de tu aplicacion ahi recien empieza a contar...aclaro que eso no usa Timers...

saludos.

[Aioros-jms]

Hola que tal, de nuevo mil gracias por sus aportaciones, estuve investigando y resolvi mi cuestion con lo siguiente:

Código:

    Option Explicit
    Private Declare Function GetTickCount Lib "kernel32" () As Long
    Private Declare Function GetLastInputInfo Lib "user32" (plii As Any) As Long
    Private Type LASTINPUTINFO
        cbSize As Long
        dwTime As Long
    End Type

Private Sub Timer1_Timer()
    Dim lii As LASTINPUTINFO
    lii.cbSize = Len(lii)
    Call GetLastInputInfo(lii)
    With Label1
    .Caption = FormatNumber((GetTickCount() - lii.dwTime) / 1000, 0)
    .Refresh
    End With
    If CInt(Label1.Caption) = 10 Then
        MsgBox "Timed out."
    End If
End Sub

Con el código anterior se efectua exactamente lo que quiero. Como me acabo de dar cuenta de sus respuestas y no me a dado tiempo de checar sus aportaciones, pero con lo que nos dijo el amigo seba123neo no le entendi bien. Y con lo poco que vi sobre lo escribio Marcelote, pues creo que es solo para el "mouse" estaria faltando lo del teclado. Pero bueno de nuevo gracias. Que pasen una excelente tarde.

Saludos.!!!

[bluebox]

Hola! En vb.net como es el código?? Traté de adaptarlo pero no me hace lo que necesito

Saludos!