Listar Tabla VisualB + Access

[JoseAlejandro_Realza]

Hola Amigos, tengo una duda sobre un Query en Visual Basic con VisualBasic; Yo trabajo con sistemas en la Web, PHP, Javascript, ActionScript, pero en Visual no tengo la misma habilidad.

El Problema es el siguiente:

Quiero listar los registros de una tabala sobre categorias de un inventario, todo bien, pero cuando quiero listar todos los datos almacenados, solo me arroja un array con los datos del primero que encuentre, en vez de arrojarme un arreglo multidimensional como lo hace PHP, para poder mostrar todos los que consiga. El codigo que estoy utilizando es el siguiente

Código:

Tabla.Source = "SELECT * FROM Categorias ORDER BY Categoria_Nombre"
Tabla.Open
    
    For Each Datos In Tabla()
    MsgBox (Datos)
    Next

Ya intente colocandole el Query en el Open, pero sigue haciendo igual. Espero me puedan ayudar, Saludos

[-rommel_]

Estas usando ADO?...
en el buscador del foro hay varios temas de Conexiones de Base de Datos... Si este paso ya lo hiciste entonces... dinos a que Contenedor (grid, MshFlexGrid, etc etc) estas poniendo la data... y que resultado te da...

Saludos...

[pana99]

Hola, por favor proba asi que tendría que funcionar

Código:

Sql = "SELECT * FROM Categorias ORDER BY Categoria_Nombre"
Cn.Open provider="Microsoft.jet.oledb.4.0; data Source = C:\TuBase.mdb"
rs.Open Sql, Cn, adOpenDynamic, 3

'te deja el recordset en el primer registro
While Not rs.EOF
    'mostrar el campo que quieras
    MsgBox rs!NombreDelCampo
    avanzas un registro
    rs.MoveNext
Wend
'Cierra, Libera la memoria
    rs.Close
    Set rs = Nothing
    Cn.Close
    Set Cn = Nothing
End Sub

[JoseAlejandro_Realza]

Bueno, yo estaba utilizando ADODB, pero no consigo hacerlo, Pana99, utilice el codigo que me das, pero no se como hacerlo correr. Intente de esta manera y me da error:

Código:

Dim Conectar As New ADODB.Connection
Dim Query As New ADODB.Recordset
SQL = "SELECT * FROM Categorias ORDER BY Categoria_Nombre"

Conectar.Open Provider = "Microsoft.jet.oledb.4.0; data Source = C:\Users\Admin\Documents\Database_ARE[MJ].mdb"

Query.Open SQL, Cn, adOpenDynamic, 3

'te deja el recordset en el primer registro
While Not rs.EOF
    'mostrar el campo que quieras
    MsgBox ("Hola")
    
    rs.MoveNext
Wend
'Cierra, Libera la memoria
    Tabla.Close
    Set rs = Nothing
    Conexion.Close
    Set Cn = Nothing

[-rommel_]

mira este post amigo... seguro que te va a ayudar bastante...
http://www.forosdelweb.com/f69/conec...-basic-475315/

[pana99]

bueno habia algunos errores en lo que cambiaste.
Aca va de nuevo probado con una base en mi pc.
Observa los comentarios de las referencias que debes usar

Código:

Private Sub Command1_Click()
Dim Conectar As New Connection, Query As New Recordset, Sql As String
'Desde el menu / Proyecto debes hacer referencia a
'Microsoft AxctiveX Data Object 2.6 library....... y a
'Microsoft Jet and Replication objects 2.6........

Sql = "SELECT * FROM Categorias ORDER BY Categoria_Nombre"
Conectar.Open "Provider = Microsoft.jet.oledb.4.0; data Source = C:\bd1.mdb"
Query.Open Sql, Conectar, adOpenDynamic, 3

'te deja el recordset en el primer registro
While Not Query.EOF
    'mostrar el campo que quieras si es mas de uno debes concatenarlos
    MsgBox Query!Categoria_Nombre
    Query.MoveNext
Wend
'Cierra, Libera la memoria
    Query.Close
    Set Query = Nothing
    Conectar.Close
    Set Conectar = Nothing
    
End Sub

Esepro te sirva

[JoseAlejandro_Realza]

Muchas Gracias Pana, con eso ya logre mostrar lo que quería, Ahora voy a buscar como poder listar los datos en un Grid o algo similar.. ¿ Algún consejo?

[-rommel_]

de esa manera seteas al DataGRid..

set me.DataGrid1.DataSource = Query

[JoseAlejandro_Realza]

Rommel Coloque ese codigo tal cual y me da un error que dice: El conjunto de filas no admite marcadores

[-rommel_]

muestrame el codigo... completo incluido donde seteas al DataGrid

[JoseAlejandro_Realza]

Código:

Sql = "SELECT * FROM Categorias ORDER BY Categoria_Nombre"
Conectar.Open "Provider = Microsoft.jet.oledb.4.0; data Source = C:\Users\Admin\Documents\Database_ARE[MJ].mdb"
Query.Open Sql, Conectar, adOpenDynamic, 3
Set tRs = Conectar.Execute(Sql)

'te deja el recordset en el primer registro
While Not Query.EOF
    'mostrar el campo que quieras si es mas de uno debes concatenarlos
    MsgBox (Query!Categoria_Nombre)
    Set DataGrid1.DataSource = Query

    Query.MoveNext
Wend

'Cierra, Libera la memoria
    Query.Close
    Set Query = Nothing
    Conectar.Close
    Set Conectar = Nothing

[-rommel_]

Código vb:

Sql = "SELECT * FROM Categorias ORDER BY Categoria_Nombre"
Conectar.Open "Provider = Microsoft.jet.oledb.4.0; data Source = C:\Users\Admin\Documents\Database_ARE[MJ].mdb"
Query.Open Sql, Conectar, adOpenDynamic, 3
Set tRs = Conectar.Execute(Sql)
 
Set DataGrid1.DataSource = Query
 
 
'te deja el recordset en el primer registro
While Not Query.EOF
    'mostrar el campo que quieras si es mas de uno debes concatenarlos
    MsgBox (Query!Categoria_Nombre)
    Query.MoveNext
Wend
 
'Cierra, Libera la memoria
    Query.Close
    Set Query = Nothing
    Conectar.Close
    Set Conectar = Nothing
 

de verdad no entiendo tu codigo...
-- Declaracion de Variables (ADODB.Connection -> ADODB.Recordset)
-- Conexion de ADODB.Connection
-- Conexion de ADODB.Recordset con el ADODB.Connection y la Consulta
-- Setear El DataGrid con el ADODB.Recordset
-- Recorrer el ADODB.Recordset
-- Cerrar ADODB.Recordset y ADODB.Connection
en ese orden... ahi no se cual es tu Recordset... si tRs o Query... pero el Seteo del DataGrid ponlo fuera del WHILE...

[JoseAlejandro_Realza]

Disculpa, esta linea: Set tRs = Conectar.Execute(Sql), era probando uno de los ejemplos, el Recordset es Query. Ya coloque el Set Me.DataGrid1.DataSource = Query fuera del bucle y me da el mismo error.

[-rommel_]

ya se donde esta... el error te falta algo.. el cursorLocation...
antes de Conectar.Open

coloca Conectar.CursorLOcation = adUseClient

y con eso funcionara... Saludos...

[-rommel_]

te envio el codigo que hago yo normalmente...
espero te ayude, claro necesitas un Command y un DataGrid

Código vb:

Public dbConex As ADODB.Connection
Public rsConsulta As ADODB.Recordset
 
Private Sub Command1_Click()
    Dim strQuery As String
    'Seteamos rsConsulta
    Set rsConsulta = New ADODB.Recordset
    'hacemos la consulta
    strQuery = "Select * from Authors"
    'Conectamos nuestro Recordset
    rsConsulta.Open strQuery, dbConex, adOpenDynamic, adLockOptimistic
    'Seteamos a me.DataGrid1
    Set Me.DataGrid1.DataSource = rsConsulta
End Sub
 
Private Sub Form_Load()
    Dim strDire As String
    '----------------------------------------------
    'Declaramos la direccion de nuestra BD
    strDire = "C:\Archivos de programa\Microsoft Visual Studio\VB98\BIBLIO.MDB"
    'Seteamos dbConex
    Set dbConex = New ADODB.Connection
    'Coloca esto para que no te salga QUE LAS FILAS NO ADMITEN MARCADORES
    dbConex.CursorLocation = adUseClient
    'Conectamos nuestra Base de Datos
    dbConex.ConnectionString = "Provider=Microsoft.Jet.OLEDB.4.0;Data Source=" & strDire & ";Persist Security Info=False"
    'Abrimos la Base de Datos
    dbConex.Open
End Sub
 
Private Sub Form_Unload(Cancel As Integer)
    rsConsulta.Close
    dbConex.Close
End Sub
 

Saludos!!!

[JoseAlejandro_Realza]

Ya lo modifique segun comprendi, no me genera error, mas no carga los datos dentro del DataGrid

Código vb:

Dim Conectar As New Connection, Query As New Recordset, Sql As String
Conectar.CursorLocation = adUseClient
Sql = "SELECT * FROM Categorias ORDER BY Categoria_Nombre"
Conectar.Open "Provider = Microsoft.jet.oledb.4.0; data Source = C:\Users\Admin\Documents\Database_ARE[MJ].mdb"
Query.Open Sql, Conectar, adOpenDynamic, adLockOptimistic
 
 Set Me.DataGrid1.DataSource = Query
 
    Query.Close
    Set Query = Nothing
    Conectar.Close
    Set Conectar = Nothing
 

[-rommel_]

es que amigo... esta Cerrando la conexion del Conectar y del Query... esa conexion debes cerrarla despues...

hay una forma de dejar la conexion abierta aun cuando el CONECTAR se cierra... pero no recuerdo como es... busca en San google... Recordset en Caliente o en frio algo asi no recuerdo...

Pero si no cierras tus objetos quedaran tus datos... Saludos