funcion buscar palabra que retorna cierto o falso

[negu]

necesito una macro para excel que me haga lo mismo que la opcion de buscar, pero que la funcion me devuelva cierto si encontro la palabra, o falso sino la encontro.

Algo parecido a esto, pero con la condicion anteriormente especificada, ya que esta función la utilizo para buscar palabras en diferentes archivos excel llamándola desde una aplicación externa, que espera, para cada archivo excel, un cierto o un falso.

Sub buscar(cadena As String) As boolean

Cells.Find(What:="hola", After:=ActiveCell, LookIn:=xlFormulas, LookAt _
:=xlPart, SearchOrder:=xlByRows, SearchDirection:=xlNext, MatchCase:= _
False, SearchFormat:=False).Activate

// Aquí me faltaría la condición de si la ha encontrado o no, y retornar cierto o falso

End Sub

[3pies]

Prueba esto:

Código:

Sub buscar()
'en caso de error, que continúe
On Error Resume Next
'definimos la palabra (o frase a buscar)
palabreja = "hola"
'la buscamos y nos situamos sobre ella
Cells.Find(What:=palabreja).Activate
'si no le hemos encontrado, nos dará error nº 91
If Err = 91 Then
    'en caso de error, la hemos jodido
    dato = False
Else
    'si no hay error, mucho mejor :-)
    dato = True
End If
'escribimos el dato en un msgbox
MsgBox (dato)
End Sub

Saludos.

[negu]

Muchas gracias.

Hoy lo he probado y me a sido de gran utilidad la parte del error. Mi código queda así:

' funcion que de vevuelve cierto si encuentra una palabra o falso si no esta
Function Buscar(cadena As String) As Boolean

'en caso de error, que continúe
On Error Resume Next
'buscamos la palabra y nos situamos sobre ella
Cells.Find(What:=cadena).Activate
'si no le hemos encontrado, nos dará error nº 91
If Err = 91 Then
'en caso de error, devolvera que no la ha encontrado
dato = False
Else
'si no hay error, devolvera que la ha encontrado
dato = True
End If
'retornemos el parametro
Buscar = dato

End Function



Ahora sólo me falta una cosilla para que sea exactamente lo que necesito. Que consiga buscarme la palabra en todas las hojas del archivo Excel, no sólo en la hoja activa.

Gracias de antemano.

Saludos.

[mrocf]

Hola! Negu.
Podrías intentar algo así:

Código PHP:

  Function BuscarCadena(cadena As String) As Boolean 
Dim Celda As Range, Hoja As Object 
 
For Each Hoja In ActiveWorkbook.Sheets 
  Set Celda = Hoja.Cells.Find(What:=cadena, LookIn:=xlValues, LookAt:=xlWhole) 
  If Not Celda Is Nothing Then 
    BuscarCadena = True: Set Celda = Nothing: Exit Function 
  End If 
Next Hoja 
 
BuscarCadena = False 
End Function  
   

Saludos, Cacho.

[negu]

Esto es exactamente lo que necesitaba.

Muchísimas gracias a los dos.

Saludos.

[mrocf]

Gracias en nombre de "3pies" y mío por la devolución (tardía... pero devolución al fin).