Una duda sobre diseño de Buscador

[jhelu]

OK.. he creado un buscador que cumple con el objetivo, ahora quiero hacerle algunos arreglos uno de ellos es el siguiente haber si me pueden ayudar...

Cuando arroja los resultados necesito saber como poner en negritas en los titulos el mismo dato que busco..

Ejemplo:

Supongamos que la la palabra clave que busco es Ana Gabriela, que esa misma palabra que salga en los URL que me la ponga en negrita..

es decir... si me arrojo este resultado .....

No es la política prioridad para Ana Gabriela
Reciben a Ana Gabriela como reina
Preparan recepción para Ana Gabriela

me explique?

Gracias ojala me puedan ayudar

[meru-kun]

Este código es el que tienen los Snitz Forums. Adaptalo a tus necesidades:

Código:

function SearchHiLite(fStrMessage)
	'function derived from HiLiTeR by 2eNetWorX
	fArr = split(replace(Request.QueryString("SearchTerms"),";",""), ",")
	strBuffer = ""
	for iPos = 1 to len(fStrMessage)
		bChange = False
		'Looks for html tags
		if mid(fStrMessage, iPos, 1) = "<" then
			bInHTML = True
		end if
		'Looks for End of html tags
		if bInHTML = True then
			if mid(fStrMessage, iPos, 1) = ">" then
				bInHTML = False
			end if
		end if
		if bInHTML <> True then  
			for i = 0 to UBound(fArr)
				if fArr(i) <> "" then
					if lcase(mid(fStrMessage, iPos, len(fArr(i)))) = lcase(fArr(i)) then
						bChange = True
						strBuffer = strBuffer & "<span class=""spnSearchHighlight"" id=""hilite"">" & _ 
						mid(fStrMessage, iPos, len(fArr(i))) & "</span id=""hilite"">"
						iPos = iPos + len(fArr(i)) - 1
					end if
				end if
			next
		end if
		if Not bChange then
			strBuffer = strBuffer & mid(fStrMessage, iPos, 1)
		end if
	next
	SearchHiLite = strBuffer
end function

[LeCLUB]

Yo utilizaría directamente Replace donde va el texto:

Supongamos que el buscador saca el título del registro donde encuentra una coincidencia, y en la variable "buscar" está el patrón de búsqueda, que en este caso sería : Ana Gabriela

<%= Replace(rs("titulo"), buscar, "<strong>" & buscar & "</strong>") %>