Combobox

[dargento]

Buenas.
Tengo en ASP un combobox. Este coge valores para rellenar la lista de una base de datos. Yo necesito que me ponga un valor seleccionado por defecto y se pueda elegir el resto. Este valor a mostrar en principio esta en una variable.
No se como puedo hacerlo. Si alguien me puede ayudar.
Muchas gracias.
[email protected]

[nicket]

Hola dargento,

mira, te pono un procedimiento que uso el cual pongo en un archivo llamado funciones.asp que incluyo en las páginas que necesito.

'************************************************* **************************************
' mSQL -> Consulta del estilo "SELECT id,provincia FROM Provincias"
' nomCamp -> nombre del campo
' id -> valor que quieres que te quede seleccionado
'************************************************* **************************************
Sub construir_combo_selected(mSQL,nomCamp,id)
dim db,rs

set db = Server.CreateObject("ADODB.Connection")
db.open strConnexio

set rs = db.Execute(mSQL)

%>
<select name="<%=nomCamp%>" id="<%=nomCamp%>">
<option value="0">- - -</option>
<%
do while not rs.eof
if CInt(id) = CInt(rs.Fields(0)) then
%><option value="<%=rs.Fields(0)%>" selected><%=rs.Fields(1)%></option><%
else
%><option value="<%=rs.Fields(0)%>"><%=rs.Fields(1)%></option><%
end if
rs.movenext
loop
%>
</select>
<%

rs.close
set rs = nothing
db.close
set db = nothing

End Sub

Y la llamada desde tu página seria algo como:

<%call construir_combo_selected(<consultaSQL>,<nombreCamp o>,<valor>)%>

Espero que te ayude....