Urgentisimo. Uso De Variables De Sesion

[sweet2002]

HOLA!, NECESITARIA QUE ALGUIEN ME DIJERA COMO PUEDO ASIGNAR UNA MATRIZ A UNA VARIABLE DE SESION PARA RECOGER DICHO VALOR EN OTRA PAGINA.

MONICA
GRACIAS

[AlZuwaga]

De la documentación del IIS:

Si almacena una matriz en un objeto Session, no debe intentar modificar directamente los elementos de la matriz almacenada. Por ejemplo, la secuencia de comandos siguiente no funcionaría.

<% Session("MatrizAlmacenada")(3) = "nuevo valor" %>

Esto se debe a que el objeto Session está implementado como una colección. El elemento de la matriz MatrizAlmacenada(3) no recibe el nuevo valor. En su lugar, el valor se indiza en la colección, sobrescribiendo cualquier información almacenada en dicha ubicación.

Se recomienda que si almacena una matriz en el objeto Session recupere una copia de la matriz antes de recuperar o modificar cualquiera de los elementos de la matriz. Cuando haya terminado de trabajar con la matriz, debe volver a almacenar la matriz en el objeto Session para guardar las modificaciones realizadas. Esto se demuestra en el ejemplo siguiente.

---file1.asp---
<%
'Crear e inicializar la matriz
Dim MiMatriz()
Redim MiMatriz(5)
MiMatriz(0) = "hola"
MiMatriz(1) = "otra cadena de texto"

'Almacenar la matriz en el objeto Session
Session("MatrizAlmacenada") = MiMatriz

Response.Redirect("file2.asp")
%>

---file2.asp---
<%
'Recuperar la matriz del objeto Session
'y modificar su segundo elemento
LocalArray = Session("MatrizAlmacenada")
LocalArray(1) = " allí"

'imprimir la cadena "hola allí"
Response.Write(LocalArray(0)&LocalArray(1))

'Volver a almacenar la matriz en el objeto Session
'Esto sobrescribe los valores de MatrizAlmacenada con los valores nuevos
Session("MatrizAlmacenada") = LocalArray
%>