consulta!!!

[lala_mtts]

Hola a todos:

tengo una consulta, yo trabajo con delhpi donde guardo las imagenes y tambien con asp donde tambien las guardo, pero lo hago en forma independiente, o sea con delphi de una forma y con asp de otra.

por lo que me gustaria saber si habrá alguna forma de tomar esa imagen guardada en delphi, y mostrarla con asp.

[u_goldman]

La verdad no entendí bien tu pregunta, podrías explicar un poco más que es lo que pretendes?

Saludos

[richardinj]

???

Te refieres a mostrar la imagen que grabó delphi no?

Donde esta esa imagen.. en una BD o una Carpeta?

Saludos.

[lala_mtts]

la imagen la guarda directamente en la base de datos, tanto para delphi, como para asp, por lo que mi pregunta es si se puede sacar esa imagen guardada en delhpi, y luego mostarla con asp, sin tener que guardar esa imagen que esta grabada en delphi.

[tammander]

ummm el objeto Response tiene un metodo llamado BinaryWrite que sirve para escribir codigo binario (imagenes, etc). Te pongo un ejemplo que viene en el Dreamweaver:

Código:

<% 

' The following code retrieves a binary object
' (in this case a JPG image) and writes it to the
' client using BinaryWrite. (For more information
' on ActiveX Data Objects usage, see Chapter 12.)

' Create an ADO connection object.
Set adoCon = Server.CreateObject("ADODB.Connection")

' Use the Open method of the Connection object
' to open an ODBC connection with the database
' represented by the DSN ImageDatabase.
adoCon.Open "ImageDatabase"

' Use the Execute method of the ADO Connection object
' to retrieve the binary data field from the database.
Set adoRecImgData = adoCon.Execute _
   ("SELECT ImageData FROM Images WHERE ImageId = 1234")

' Create a Field object by setting one equal to a
' specific field in the recordset created previously.
Set adoFldImage = adoRecImgData("ImageData")

' Use the ActualSize property of Field object to retrieve
' the size of the data contained in the Field object. After
' this line you will know how many bytes of data reside in
' the Field object.
lngFieldDataLength = adoFldImage.ActualSize

' Use the BinaryWrite method to write 4K bytes of binary
' data at a time. So, first we need to determine how many
' 4K blocks the data in the Field object represents.
lngBlockCount = lngFieldDataLength / 4096

' Now let's get how many bytes are left over after removing
' lngBlockCount number of bytes.
lngRemainingData = lngFieldDataLength Mod 4096

' We now must set the HTTP content type Response header
' so that the browser will recognize the data being sent
' as being JPEG image data.
Response.ContentType = "image/JPEG"

' Loop through and write the first lngBlockCount number
' of binary blocks of data.
For intCounter = 1 to lngBlockCount
   Response.BinaryWrite adoFldImage.GetChunk(4096)
Next

' Now write the last remainder of the binary data.
Response.BinaryWrite adoFldImage.GetChunk(lngRemainingData)

' Close the recordset.
adoRecImgData.Close
%>

¿Es esto lo que necesitas?


Un saludo

[El_Metallick]

no entiendo bien... me das a entender que son 2 bases de datos??? porque de otra forma deveria funcionar... pero no entiendo muy bien tu duda