Capitalizar en asp

[messer]

Un saludo a los camaradas del foro.

Mi pregunta es como capitalizar texto en asp, es decir pasar texto de mayuscula a minuscula y viceversa.

Gracias.

[drmkace]

Con UCase(string) para pasar a mayusculas y LCase(string) a minusculas.
Saludos.

[AlZuwaga]

response.write UCase("texto en minusculas que pasará a mayusculas")
response.write LCase("TEXTO EN MAYUSCULAS QUE PASARA A MINUSCULAS")

[messer]

Que bien!, pero en caso de querer pasar x parte del texto a M o a m entonces, es decir solo una parte desde una base de datos, por ejemplo "ResPOnSe" donde en la base de datos se encuentra almacenado response, como podría lograr esto??

[AlZuwaga]

Pero... ¿de manera comnpletamente aleatoria, siguiendo algúna regla o patrón o qué?

[Muzztein]

yo aconsejo ingresar los datos a una BD en minusculas y trimeados.
luego con CSS se ve como lo muestras, si es que en mayusculas, minusculas o capitalizados. (primera con mayuscula y el resto en minuscula)

[messer]

Bueno de las dos maneras preferiblemente, ya que como dice muzztein y si no me equivoco me estas diciendo que ingrese texto formateado en la bd, pero si es de una manera aleatoria es mejor ya que siguiendo un patrón creo que es mas sencillo, pero también es valido, si tienen la manera de hacerlo...

[AlZuwaga]

De manera aleatoria:

Código:

<%
Function MayMinAleatorias(Txt)
	For i = 0 To Len(Txt)
		Randomize
		MayMin = int(rnd*2)
		Letra = Mid(Txt, i + 1, 1)
		If MayMin = 0 Then Letra = LCase(Letra)
		If MayMin = 1 Then Letra = UCase(Letra)
		MayMinAleatorias = MayMinAleatorias & Letra
	Next
End Function 


Response.Write MayMinAleatorias("hola, veamos como sale esto.. no le veo el sentido, pero en fin jajaja")
%>

El resultado es más o menos lo que se ve en un sitio cuando es "jaqueado" por algún lammer

[lexus]

como qu eya respondieron, pero aqui hay una forma es para dejar la primer letra en mayuscula y las demas en minusculas

cadena = ucase(left(cadena,1)) & lcase(right(cadena,len(cadena)-1))

[rpolanco]

Aquí teneis una función bastante completa para la conversión de un texto a versales. Las palabras excepcionales de la función que se encuentren dentro del texto no se tocarán.

Código:

<%
'***********************************************************************************
' La función LetrasVersales devuelve una cadena de texto con formato Texto Versal  *
'***********************************************************************************

Function LetrasVersales(strText)
	PalabrasExcepcionales = "y,sus,al,el,la,los,las,es,son,sean,un,uno,una,unos,unas,da,donde,se,que,del,ello,ella,ellos,ellas,a,ante,bajo,cabe,con,contra,de,desde,en,entre,hasta,hacia,para,por,según,segun,si,sí,so,sobre,tras,BBB,BIC,CYL,JCYL,I,II,III,VI,VII,VIII,IX,X,XI,XII,XIII,XIV,XV,XVI,XVII,XVIII,XIX,XX,XXI,XXII,I.,II.,III.,VI.,VII.,VIII.,IX.,X.,XI.,XII.,XIII.,XIV.,XV.,XVI.,XVII.,XVIII.,XIX.,XX.,XXI.XXII."
	arrayLetrasVersales = Split(strText, " ")
	arrayPalabrasExcepcionales = Split(PalabrasExcepcionales, ",")
	For arrayIdxLV = 0 To UBound(arrayLetrasVersales)
		If Len(arrayLetrasVersales(arrayIdxLV)) > 0 Then
			Procesar = True
			ProcesarExcepcion = True
			If arrayIdxLV > 0 Then
				If InStr(arrayLetrasVersales(arrayIdxLV - 1), ".") <> 0 Or InStr(arrayLetrasVersales(arrayIdxLV), "(") <> 0 Then
					ProcesarExcepcion = False
				End If
			End If
			If arrayIdxLV > 0 And ProcesarExcepcion = True Then
				For arrayIdxPE = 0 To UBound(arrayPalabrasExcepcionales)
					If UCase(arrayPalabrasExcepcionales(arrayIdxPE)) = UCase(arrayLetrasVersales(arrayIdxLV)) Then
						arrayLetrasVersales(arrayIdxLV) = arrayPalabrasExcepcionales(arrayIdxPE)
						Procesar = False
					End If
				Next
			End If
			If Procesar = True Then
				If Left(arrayLetrasVersales(arrayIdxLV), 1) = "(" Then
					If Len(arrayLetrasVersales(arrayIdxLV)) > 1 Then
						arrayLetrasVersales(arrayIdxLV) = UCase(Left(arrayLetrasVersales(arrayIdxLV), 2)) & LCase(Right(arrayLetrasVersales(arrayIdxLV), Len(arrayLetrasVersales(arrayIdxLV)) - 2))
					Else
						arrayLetrasVersales(arrayIdxLV) = UCase(Left(arrayLetrasVersales(arrayIdxLV), 1)) & LCase(Right(arrayLetrasVersales(arrayIdxLV), Len(arrayLetrasVersales(arrayIdxLV)) - 1))
					End If
				Else
					arrayLetrasVersales(arrayIdxLV) = UCase(Left(arrayLetrasVersales(arrayIdxLV), 1)) & LCase(Right(arrayLetrasVersales(arrayIdxLV), Len(arrayLetrasVersales(arrayIdxLV)) - 1))
				End If
			End If
		End If
	Next
	LetrasVersales = Join(arrayLetrasVersales, " ")
End Function
%>

[messer]

Gracias por sus respuestas, probaré todos los codigos aqui descritos; estoy seguro que también se puede jugar con los colores tamaños etc.

Desde el punto de vista de utilidad, pues nunca sabes con que cliente o que trabajo pueda requerirlo, así que es bueno estar preparado.

Saludos a todos!!