E-mail

Bluesman74cl · #1 (**permalink**) 17/03/2003, 15:55

Señores... primero que todo Muy buenas tardes.

Lo que necesito hacer es un envio automático de mails desde mi página.. Por ejemplo mandar la respuesta a un formulario cuando se registran, es decir mandar una confirmación de registro en mi página..
Cómo lo hago?

Manoloweb · #2 (**permalink**) 17/03/2003, 16:22

Te paso un script que hice yo para una página...

Código:

  Dim enviaMail, HTML
  Set enviaMail = CreateObject("CDONTS.NewMail")
  
  HTML =  "<html>"
  HTML = HTML & "<head>"
  HTML = HTML & "<meta http-equiv=""Content-Type"""
  HTML = HTML & " content=""text/html; charset=iso-8859-1"">"
  HTML = HTML & "<title>Email desde la p&aacute;gina</title>"
  HTML = HTML & "</head>"
  HTML = HTML & "<body>"
  HTML = HTML & "<font face='Arial' size='3' color='#006699'><b>Solicitud de informaci&oacute;n desde la p&aacute;gina</b></font><br><br> "
  HTML = HTML & "<font face='Arial' size='2' color='#000000'><b>Nombre: </b>" &request.form("nombre")& "</font><br>"
  HTML = HTML & "<font face='Arial' size='2' color='#000000'><b>Empresa: </b>" &request.form("empresa")& "</font><br>"
  HTML = HTML & "<font face='Arial' size='2' color='#000000'><b>Correo Electr&oacute;nico: </b>" &request.form("email")& "</font><br>"
  HTML = HTML & "<font face='Arial' size='2' color='#000000'><b>Tel&eacute;fono: </b>" &request.form("telefono")& "</font><br>"
  HTML = HTML & "<font face='Arial' size='2' color='#000000'><b>Ciudad: </b>" &request.form("ciudad")& "</font><br>"
  HTML = HTML & "<font face='Arial' size='2' color='#000000'><b>Pa&iacute;s: </b>" &request.form("pais")& "</font><br>"
  HTML = HTML & "<p><font face='Arial' size='2' color='#000000'><b>Comentarios: </b><br>" &request.form("comentarios")& "</font></p>"
  HTML = HTML & "</body>"
  HTML = HTML & "</html>"
  
  enviaMail.From = request.form("email")
  enviaMail.To = "[email protected]"
  enviaMail.Cc = "[email protected]"
  enviaMail.Subject = "Desde el Web Site"
  enviaMail.BodyFormat = 0
  enviaMail.MailFormat = 0
  enviaMail.Body = HTML
  enviaMail.Send
  Set enviaMail = Nothing

maestro · #3 (**permalink**) 17/03/2003, 17:13

Ya que el te lo ha puesto con CDONTS yo te paso uno con ASPEMAIL.

registro.htm
<form method="POST" action="alta.asp">
<input type="text" name="email" size="20">
<input type="submit" value="Enviar">
<input type="reset" value="Restablecer">
</form>

alta.asp
<%
email=request("email")
Set Mail = Server.CreateObject("Persits.MailSender")

Mail.Host = "smtp.tusitio.com"
Mail.From = "[email protected]"
Mail.FromName = "Departamento de Altas"
Mail.AddAddress email

Mail.Subject = " Tu registro en www.tusitio.com"
Mail.body = "Gracias por registrarte, etc etc etc"

On Error Resume Next
Mail.Send ' ó Mail.SendToQueue
If Err <> 0 Then
Response.Write "Ha ocurrido un error: " & Err.Description
End If
%>

Bluesman74cl · #4 (**permalink**) 18/03/2003, 07:16

Cita:

Mensaje Original por maestro
Ya que el te lo ha puesto con CDONTS yo te paso uno con ASPEMAIL.

Que direncia hay entre uno y el otro. Son sistemas de envio distintos? Hay que tener algo adiciona a parte del IIS?

maestro · #5 (**permalink**) 18/03/2003, 07:20

Huy que verdes estamos....

Para poder enviar correo primero debes saber que objetos soporta tu servidor, puede ser CDONTS, ASPEMAIL, JMAIL y otro monton.

Cada uno de ellos usa unas propiedades para enviar correo y debes usar el codigo correspondiente.

¿Que hosting usas?, para que te digamos fijo que usar.

Bluesman74cl · #6 (**permalink**) 18/03/2003, 08:41

Todavia no utilizo ningun hosting estoy trabajando a nivel del IIS en mi PC en un trabajo para mis estudios que pensamos entregar por ahi por fines de este primer semestre... lo que pasa es que es bastante ambisioso el proyecto por eso nos estamos dando ese tiempo....

maestro · #7 (**permalink**) 18/03/2003, 08:53

Si usas win2000 o NT podras usar CDONTS.
Sin embargo si usas XP deberas intalar alguno de los componentes que te hemos comentado, porque a los señores de microsoft no le dio la gana incluir CDONTS en IIS 5.0

deprabado · #8 (**permalink**) 18/03/2003, 11:50

incluye una nueva version de cdonts no recuerdo el nombre, tambien publique hace no mucho un script que te dice que componentes soporta tu server, correlo si soporta cdonts te lo va a decir, revisa en el buscador.

te paso el link de las faqs donde esta el script que busca componentes

http://www.forosdelweb.com/showthrea...330#post343330

cosagaucha · #9 (**permalink**) 20/03/2003, 22:37

Cita:

Mensaje Original por maestro
Ya que el te lo ha puesto con CDONTS yo te paso uno con ASPEMAIL.

registro.htm
<form method="POST" action="alta.asp">
<input type="text" name="email" size="20">
<input type="submit" value="Enviar">
<input type="reset" value="Restablecer">
</form>

alta.asp
<%
email=request("email")
Set Mail = Server.CreateObject("Persits.MailSender")

Mail.Host = "smtp.tusitio.com"
Mail.From = "[email protected]"
Mail.FromName = "Departamento de Altas"
Mail.AddAddress email

Mail.Subject = " Tu registro en www.tusitio.com"
Mail.body = "Gracias por registrarte, etc etc etc"

On Error Resume Next
Mail.Send ' ó Mail.SendToQueue
If Err <> 0 Then
Response.Write "Ha ocurrido un error: " & Err.Description
End If
%>

hola, una pregunta.. intente hacer andar este mismo ejemplo (cambiandole el smtp y demas..) y me tiro este error.. alguien sabe a que se puede deber??

The page cannot be displayed
There is a problem with a program on the page you are trying to reach, and the page cannot be displayed.

--------------------------------------------------------------------------------

Please try the following:

Open the www.apa.org.ar home page, and then look for links to the information you want.
Click the Refresh button, or try again later.

HTTP 403.1 Forbidden: Execute Access Forbidden
Internet Information Services

--------------------------------------------------------------------------------

Technical Information (for support personnel)

Background:
You have attempted to execute a CGI, ISAPI, or other executable program from a directory that does not allow programs to be executed.

More information:
Microsoft Support

--------------

gracias al que pueda tirarme una soga!!

maestro · #10 (**permalink**) 21/03/2003, 05:34

No tienes permisos de ejecucion de scripts en esa carpeta o bien tu proveedor no te permite hacer uso de ASPEMAIL.

Aunque lo mas facil es que sea lo primero

cosagaucha · #11 (**permalink**) 21/03/2003, 21:21

hola, gracias por responderme, "teoricamente", mi proveedor acepta el aspemail...???? pero mi form sigue sin funcionar... y yo no puedo cambiarle los permisos a las carpetas..

que puedo hacer?... ponerles una bomba al host?...

maestro · #12 (**permalink**) 22/03/2003, 09:19

Prueba con alguno de los ejemplos de la pagina de ASPEMAIL, son mas sencillos, sin variables ni cosas raras.

http://aspemail.com/codesample.html

<%
Set Mail = Server.CreateObject("Persits.MailSender")
Mail.Host = "smtp.smtp-server.com" ' Specify a valid SMTP server
Mail.From = "[email protected]" ' Specify sender's address
Mail.FromName = "VeryHotCakes Sales" ' Specify sender's name

Mail.AddAddress "[email protected]", "Andrew Johnson, Jr."
Mail.AddAddress "[email protected]" ' Name is optional
Mail.AddReplyTo "[email protected]"
Mail.AddAttachment "c:\images\cakes.gif"

Mail.Subject = "Thanks for ordering our hot cakes!"
Mail.Body = "Dear Sir:" & Chr(13) & Chr(10) & _
"Thank you for your business."

On Error Resume Next
Mail.Send
If Err <> 0 Then
Response.Write "Error encountered: " & Err.Description
End If
%>

Henry Zapata · #13 (**permalink**) 22/03/2003, 10:39

Hola:

El CDONTS 1.2.1 como su nombre lo indica (objetos de colaboración de datos para NT) viene con sistemas NT; para windows 2000 o Windows XP es OTRO y se llama simplemete CDO.

Aqui tienes un ejemplo usando un servidor de correo remoto.

Set objMessage = CreateObject("CDO.Message")
objMessage.Subject = "Asunto del mensaje"
objMessage.Sender = "[email protected]"
objMessage.To = "[email protected]"
objMessage.TextBody = "Cuerpo del Mensaje"

objMessage.Configuration.Fields.Item _
("http://schemas.microsoft.com/cdo/configuration/sendusing") = 2

objMessage.Configuration.Fields.Item _
("http://schemas.microsoft.com/cdo/configuration/smtpserver") = "smtp.telefonica.net.pe"

objMessage.Configuration.Fields.Item _
("http://schemas.microsoft.com/cdo/configuration/smtpserverport") = 25

objMessage.Configuration.Fields.Update
objMessage.Send

Aqui encontraras mas ejemplos :

http://www.paulsadowski.com/WSH/cdo.htm

cosagaucha · #14 (**permalink**) 23/03/2003, 17:55

hola Maestro, y graaaacias una vez mas, no se que habra pasado, o si habilitaron el servicio para mi cuenta desde mi mail con la queja, pero ahora me anda bien, solo me faltaria lo ultimo...

como puedo hacer para que una vez que se envio el mail, me redirija a una pagina 'x' de mi sitio?? ya que anduve por aspemail buscando ese dato pero no lo encontre...

gracias una vez mass!!!

maestro · #15 (**permalink**) 24/03/2003, 08:25

<%response.redirect("tupagina.htm")%>