Crear una DLL ActiveX partiendo de mi codigo ASP

[JuanRAPerez]

Bueno antes que nada está es una pequeña guía para hacerlo, la encontré por ahí y pues pensé en que quizás pueda ser usada por algunas personas

que porque no la puse en las FAQ ¿?, pues pretendo poner mas funciones y cosas hasta tener terminada una DLL que.

+ se conecte a una base de datos
+ pagine resultados
+ use un CSS para verse "decente" la tabla
+ entre otras ideas



Iniciando la DLL en Visual Basic:
EDITO: Microsoft Visual Basic 6.0
+ Nuevo proyecto
+ Seleccionamos "DLL ActiveX"


+ Una vez creado el proyecto le damos clic derecho a “Proyecto”, seleccionamos “Propiedades de proyecto”.


+ Una vez entramos al las propiedades le cambiamos nombre a “ForosDelWebDLL”.

+ Damos clic a “Aceptar”

+ Luego seleccionamos “class1”, y cambiamos el nombre y colocamos de nombre “funciones”.


+ Luego Menú “Proyecto” opción “Referencias”,

++ Adicionamos
+++ Microsoft Active Server Pages Object Library
+++ Microsoft Active Server Pages Object Context Object Library


+++ COM+ 1.0 Admin Type Library
+++ COM+ Services Type Library


+++ Microsoft ActiveX Data Objects 2.8 Library
+++ Microsoft ActiveX Data Objects Recordset 2.8 Library


+ Damos clic en “aceptar”.
+ Creamos en c:\ un directorio llamado MIDLLASP (con el fin de hacer la prueba completa de este ejemplo) - c:\ MIDLLASP
+ Guardamos en ese directorio nuestro Proyecto y Clase
Pegamos en nuestra Clase llamada Funciones el siguiente código:

NOTA IMPORANTE: favor tomar en cuenta que algunos saltos de línea son provocados por el programa que utilizo para la redacción.

Código asp:

Option Explicit
 
Private ScriptingContext As ScriptingContext
Private Application As Application
Private Request As Request
Private Response As Response
Private Server As Server
Private Session As Session
 
Public Sub OnStartPage(PassedScriptingContext As ScriptingContext)
     Set ScriptingContext = PassedScriptingContext
     Set Application = ScriptingContext.Application
     Set Request = ScriptingContext.Request
     Set Response = ScriptingContext.Response
     Set Server = ScriptingContext.Server
     Set Session = ScriptingContext.Session
End Sub
 
Public Sub OnEndPage()
     Set ScriptingContext = Nothing
     Set Application = Nothing
     Set Request = Nothing
     Set Response = Nothing
     Set Server = Nothing
     Set Session = Nothing
End Sub
 
Public Sub Mensaje(Texto As String)
     Response.Write "<b><font color='red'>" & Texto & "</font></b>"
End Sub
 

+ Guardamos el proyecto una vez más.
+ Clic derecho al “Proyecto”, Clic a la opción “Publicar”, y luego seleccionamos “Generar resultados…”


+ Si los pasos se han hecho como se ha explicado en este proceso (guardando antes de generar, en el fólder que indicamos se ha creado la DLL correspondiente a este proyecto)


+ Si no esta en el fólder puede ser por 1 sola razón no guardaron antes de “generar el resultado”



Cargando la DLL

Antes que nada un par de aclaraciones.

Hay que registrar la DLL, una vez que la DLL esta registrada, cada vez que deseemos actualizar la DLL tenemos que reemplazar la DLL, cuando la DLL se ha utilizado una vez (se ha probado en el web), da error a la hora de reemplazar asi que lo que yo hice para poder estar seguro que se estaba reemplazando es lo siguiente

+ Detener el servicios de publicación WWW
+ Des registramos la DLL
+ Eliminar la DLL en el directorio que la instale
+ Copiamos la DLL
+ Registramos la DLL
+ Iniciar el servicio de publicación WWW

Basados en mi maquina (Windows XP realice el siguiente proceso)
Cree un directorio dentro del “wwwroot” llamado “PruebaDLL”, dentro de el copiamos creamos otro llamado “DLL”.

En mi directorio MiDLLASP cree un BAT para evitar estar haciendo este proceso a cada rato y así hacerlo un poco más dinámico.

NOTA: al registrar la DLL el bat enviara un mensaje de que se ha registrado correctamente.

registrar.bat

@echo off
echo Deteniendo IIS
C:\Windows\System32\net stop w3svc
echo .
del C:\Inetpub\wwwroot\PruebaDLL\ForosDelWebDLL.dll
echo Eliminado DLL
echo .
copy "C:\MIDLLASP\ForosDelWebDLL.dll" "C:\Inetpub\wwwroot\PruebaDLL\DLL"
echo Copiando DLL
echo .
C:\Windows\System32\regsvr32 C:\Inetpub\wwwroot\PruebaDLL\DLL\ForosDelWebDLL.dl l
echo Registrado DLL
echo .
C:\Windows\System32\net start w3svc
echo Iniciando IIS
echo .

Creando el ASP para mostrar el contenido de la DLL
+ Abrimos nuestro programa para diseño de Paginas Web y pegamos el siguiente código. (yo usare Notepad++
+ Guardamos la página en c:\inetpub\PruebaDLL\default.asp.

default.asp

Código asp:

<html>
<head>
    <title>Mi DLL ASP</title>
</head>
<body>
    <&#37;
    Dim PobarMiDLL
    On Error Resume Next
        Set PobarMiDLL = Server.CreateObject("ForosDelWebDLL.funciones")
    If Err <> 0 then
        response.write "<h2>Error cargando DLL</h2>"
        response.end
    else
        PobarMiDLL.Mensaje "Este sera el mensaje que se imprimira" 
        Set PobarMiDLL = Nothing
    End If
    %> 
</body>
</html>
 

+ Muestro navegador nos mostrara esto:


Regresando al código nuestro sub utilizado es el siguiente:

Código asp:

Public Sub Mensaje(Texto As String)
     Response.Write "<b><font color='red'>" & Texto & "</font></b>"
End Sub
 

En el cual vemos como se imprime el texto enviado al sub, en color rojo y negrito.

Espero que a alguien le sea de ayuda:

Enlace del recurso original:
http://www.elguruprogramador.com.ar/...ar-con-asp.htm


suerte

EDITO:

para esta guía Microsoft Visual Basic 6.0 :)

[Shiryu_Libra]

buenos las funciones, hace tiempo hice un similar pero en el foro de Visual Basic

muy bueno lo que has hecho Juan

[JuanRAPerez]

Iniciado por Shiryu_Libra

buenos las funciones, hace tiempo hice un similar pero en el foro de Visual Basic

muy bueno lo que has hecho Juan

realmente lo siento maestro

realmente busque información pero uso solo el sub foro de ASP y nunca busco completo en el sitio

asi que un moderador que elimine este post :)

[Shiryu_Libra]

Iniciado por JuanRAPerez

realmente lo siento maestro

realmente busque información pero uso solo el sub foro de ASP y nunca busco completo en el sitio

asi que un moderador que elimine este post :)

no no no.... esta muy bien aki tambien, recordemos que entre mas informacion mejor y sobre todo para ASP, a lo mejor animamos a los usuarios a que utilicen diferentes programaciones para la WEB.... como debe ser

ademas lo que hice fue superficial, lo que hiciste fue mas especifico, como conexiones a tablas etc



anexo.... estaria bueno que trajeras las funciones de encriptacion, y las pusieras en un solo mensaje para anexarlas a las FAQS juan... que piensas???

[JuanRAPerez]

Iniciado por Shiryu_Libra

...
anexo.... estaria bueno que trajeras las funciones de encriptacion, y las pusieras en un solo mensaje para anexarlas a las FAQS juan... que piensas???
...

claro trabajare en ello

grx

[JuanRAPerez]

continuando con la idea aquí hay una función para limpiar cadenas (la cual puede ser modificada al antojo)

de nuevo abrimos el proyecto y pegamos la siguiente información:

Adicionamos a las declaraciones de variables al inicio de la aplicación:

Código asp:

Public str As String
 

Adicionamos la función.

Código asp:

Public Function limpia_cadena(str As String)
    str = Trim(str)
    str = LCase(str)
    str = Replace(str, "'", "")
    str = Replace(str, ";", "")
    str = Replace(str, """""", "")
    str = Replace(str, "'", "''")
    str = Replace(str, """""", "")
    str = Replace(str, "<", "&lt;")
    str = Replace(str, ">", "&gt;")
    str = Replace(str, "href=", "")
    str = Replace(str, "<a>", "")
    str = Replace(str, "</a>", "")
    str = Replace(str, "<p>", "")
    str = Replace(str, "</p>", "")
    str = Replace(str, "http-equiv=refresh", "")
    str = Replace(str, "refresh", "")
    str = Replace(str, "url=http://", "")
    str = Replace(str, "email:", "")
    str = Replace(str, "http", "")
    str = Replace(str, "=", "")
    str = Replace(str, " or ", "")
    str = Replace(str, " and ", "")
    str = Replace(str, "(", "")
    str = Replace(str, ")", "")
    str = Replace(str, "<", "[")
    str = Replace(str, ">", "]")
    str = Replace(str, " having ", " ")
    str = Replace(str, " group by ", " ")
    str = Replace(str, " union select sum ", " ")
    str = Replace(str, " union select min ", " ")
    str = Replace(str, "--", "")
    str = Replace(str, " select ", " ")
    str = Replace(str, " insert ", " ")
    str = Replace(str, " update ", " ")
    str = Replace(str, " delete ", " ")
    str = Replace(str, " drop", "")
    str = Replace(str, " -shutdown ", " ")
    str = Replace(str, "!!", "")
    limpia_cadena = str
End Function
 

Luego:
+ Generamos la DLL
+ Ejecutamos el BAT de registro
+ Esperamos que termine el Bat

Editamos nuestra página asp y quedaría así:

Código asp:

<html>
<head>
    <title>Mi DLL ASP</title>
</head>
<body>
    <%
    Dim PobarMiDLL
    On Error Resume Next
        Set PobarMiDLL = Server.CreateObject("ForosDelWebDLL.funciones")
    If Err <> 0 then
        response.write "<h2>Error cargando DLL</h2>"
        response.end
    else
        PobarMiDLL.Mensaje "Este sera el mensaje que se imprimira" 
        CadenaALimpiar = "Esta es la cadena que limpiaremos; así drop la tabla hara un delete de estos comandos ;;;; si o si -- comando insert into mitabla values "
        response.write "<p>Cadena a limpiar: " & CadenaALimpiar & "</p>"
        CadenaYaLimpia = PobarMiDLL.limpia_cadena (""& CadenaALimpiar &"")
        response.write "<p>Cadena limpia: " & CadenaYaLimpia & "</p>"
        Set PobarMiDLL = Nothing
    End If
    %> 
</body>
</html>
 

El resultado en el navegador seria


Dado que las imágenes no las puedo subir a este sitio, y en los sitios que puedo no debo, prometo pronto subir la versión de pdf de este material.

suerte

[Myakire]

Dado que las imágenes no las puedo subir a este sitio, y en los sitios que puedo no debo

a caray! ¿cómo esta eso?

Puedes subir imágenes a sitios especializados para ese fin y aquí colocar las ligas .... ¿o no estoy entendiendo?

PD. Buen trabajo JuanRAPerez:

[JuanRAPerez]

Maestro: myakire pues las subí en un sitio pero no se ven

y pues en los sitios de mi oficina no las puedo publicar por eso "en los sitios que puedo no debo" hehehehe

recomendaciones para un sitio donde las pueda subir y enlazarlas

menos geocities dado que ahí están originalmente

y pues siempre tratando de ayudar a la mara hehehehe

[JuanRAPerez]

Continuo

LEctura a una base de datos desde mi DLL
+ Bueno para el ejemplo usaremos SQL 2005
+ Creamos una base llamada “mibase”
+ Dentro de ella una tabla llamada “nombres_comunes”

Código asp:

USE [mibase]
GO
/****** Object:  Table [dbo].[nombres_comunes]    Script Date: 09/17/2008 19:36:28 ******/
SET ANSI_NULLS ON
GO
SET QUOTED_IDENTIFIER ON
GO
SET ANSI_PADDING ON
GO
 
CREATE TABLE [dbo].[nombres_comunes](
      [id] [int] IDENTITY(1,1) NOT NULL,
      [nombre] [varchar](50) COLLATE Modern_Spanish_CI_AI NULL,
      [veces] [numeric](18, 0) NULL,
      [genero] [varchar](1) COLLATE Modern_Spanish_CI_AI NULL
) ON [PRIMARY]
 
GO
SET ANSI_PADDING OFF
 

+ Luego insertamos algunos registros para tener valores en la tabla (nota insertare solo algunos registros pero prometo entregar un listo mas completo de datos)

Insertar registros: nombres_comunes

Código asp:

insert into nombres_comunes values ('ALEJANDRO', 252,'M')
insert into nombres_comunes values ('DANIEL', 244,'M')
insert into nombres_comunes values ('ADRIAN', 198,'M')
insert into nombres_comunes values ('PABLO', 177,'M')
insert into nombres_comunes values ('JAVIER', 157,'M')
insert into nombres_comunes values ('DAVID', 152,'M')
insert into nombres_comunes values ('GABRIEL', 150,'M')
insert into nombres_comunes values ('ALVARO', 137,'M')
insert into nombres_comunes values ('JORGE', 128,'M')
insert into nombres_comunes values ('DIEGO', 126,'M')
insert into nombres_comunes values ('SERGIO', 110,'M')
insert into nombres_comunes values ('CARLOS', 101,'M')
insert into nombres_comunes values ('SAMUEL', 96,'M')
insert into nombres_comunes values ('RAUL', 87,'M')
insert into nombres_comunes values ('HUGO', 86,'M')
insert into nombres_comunes values ('MIGUEL', 76,'M')
insert into nombres_comunes values ('LUCIA', 228,'F')
insert into nombres_comunes values ('PAULA', 221,'F')
insert into nombres_comunes values ('DANIELA', 179,'F')
insert into nombres_comunes values ('LAURA', 161,'F')
insert into nombres_comunes values ('MARIA', 152,'F')
insert into nombres_comunes values ('CARLA', 142,'F')
insert into nombres_comunes values ('ANDREA', 139,'F')
insert into nombres_comunes values ('CLAUDIA', 137,'F')
insert into nombres_comunes values ('ALBA', 116,'F')
insert into nombres_comunes values ('MARTA', 104,'F')
insert into nombres_comunes values ('SARA', 101,'F')
insert into nombres_comunes values ('NEREA', 91,'F')
insert into nombres_comunes values ('ADRIANA', 81,'F')
insert into nombres_comunes values ('ELENA', 74,'F')
insert into nombres_comunes values ('ALEJANDRA', 67,'F')
insert into nombres_comunes values ('CRISTINA', 63,'F')
 

Código para la lectura de la base de datos

Código asp:

Public Sub CrearTabla(strServer As  String, strDB As  String)
On Error GoTo errores
    Dim objctx As ObjectContext
    Dim Resp As ASPTypeLibrary.Response
    Dim adCon As ADODB.Connection
    Dim adRS As ADODB.Recordset
    Dim iCount As Integer
 
    Dim msConstring As String
    Dim msSQL As String
    Dim miBorder As Integer
 
    msConstring = "driver={SQL Server};server=" + strServer + "; uid=SA; pwd=pruebas; database=" + strDB + ";"
    msSQL = "select * from dbo.nombres_comunes order by id"
 
    Set objctx = GetObjectContext()
    Set Resp = objctx.Item("Response")
   
    Set adCon = New ADODB.Connection
    Set adRS = New ADODB.Recordset
    adCon.ConnectionString = msConstring
    adCon.Open
    Set adRS.ActiveConnection = adCon
    adRS.Open msSQL, , adOpenForwardOnly, adLockReadOnly
    If adRS.EOF And adRS.BOF Then
        Resp.Write "NO RECORDS RETURNED<BR>"
        Exit Sub
    End If
   
    With Resp
        .Write "<TABLE BORDER = " & miBorder & ">"
        .Write "<TR>"
        For iCount = 0 To adRS.Fields.Count - 1
            .Write "<TD>" & adRS.Fields(iCount).Name & "</TD>"
        Next
        .Write "</TR>"
        Do While Not adRS.EOF
            .Write "<TR>"
            For iCount = 0 To adRS.Fields.Count - 1
                .Write "<TD>" & adRS.Fields(iCount).Value & "</TD>"
            Next
            .Write "</TR>"
            adRS.MoveNext
        Loop
        .Write "</TABLE>"
    End With
    Set Resp = Nothing
    adRS.Close
    adCon.Close
    Set adRS = Nothing
    Set adCon = Nothing
    Set objctx = Nothing
errores:
If Err.Number <> 0 Then
    Response.Write "<p>Error en la conexion SQL</p>"
    Response.Write "<p>.</p>"
    Response.Write "<p>Error número: " + CStr(Err.Number) + "</p>"
    Response.Write "<p>Error descripción: " + CStr(Err.Description) + "</p>"
    Exit Sub
End If
End Sub
 

Para los programadores el código se explica fácilmente para los que no somos tan duchos necesitaremos algunas explicaciones.

Lo básico es enviar en los parámetros de nuestro ASP,

+ la dirección IP de el SQL Server
+ el nombre de la base,
+ dentro hacemos la consulta
++ Podríamos enviar el usuario y la clave también desde el ASP pero no quise profundizar en ello mucho en ello

creando la pagina ASP para la lectura

Código asp:

<html>
<head>
    <title>Mi DLL ASP - Lectura Base de datos</title>
</head>
<body>
    <&#37;
    Dim PobarMiDLL
    On Error Resume Next
        Set PobarMiDLL = Server.CreateObject("ForosDelWebDLL.funciones")
    If Err <> 0 then
        response.write "<h2>Error cargando DLL</h2>"
        response.end
    else
        PobarMiDLL.CrearTabla "localhost","mibase"
        Set PobarMiDLL = Nothing
    End If
    %> 
</body>
</html>
 

el resultado en el navegador seria:

EDITO:

la fuente original es: http://support.microsoft.com/kb/299988/es
en ella encontaran la forma de enviar la variable de conexion y el SQL
yo decidí incorporarlas en mi código... ahí al gusto del cliente.

---- espero que les sea de utilidad ---

[Shiryu_Libra]

solo como anotacion a tu primera parte del post

seria mejor que el nombre a crear, fuera predispuesto por el usuario, que quedara como parametro para la creacion, no te parece....

hay un post del Master of Darkness, donde utiliza un codigo para SQL2005, en el cual se crea la tabla a utilizar...

a lo mejor te puede funcionar Juan... que opinas???

asi se haria todo mas automatico y el codigo solo se encargaria de lo mas pesado, y el usuario simplemente pasaria parametros al final de cuentas

[JuanRAPerez]

yeap me parece perfecto
lo tomare en cuenta

grx

[Jamati]

Todo este post sirve para lo siguiente:

necesito enchufar a través del puerto paralelo un dispositivo que le enviará datos a la CPU, la cual, necesito tener un programita (Visual, C++, Java, etc) para que me reciba ese dato, y luego enviar de vuelta un resultado a la salida para que el Dispositivo haga una determinada acción.

Esto me sirve ?, ustedes podrían orientarme ?

[Shiryu_Libra]

Iniciado por Jamati

Todo este post sirve para lo siguiente:

necesito enchufar a través del puerto paralelo un dispositivo que le enviará datos a la CPU, la cual, necesito tener un programita (Visual, C++, Java, etc) para que me reciba ese dato, y luego enviar de vuelta un resultado a la salida para que el Dispositivo haga una determinada acción.

Esto me sirve ?, ustedes podrían orientarme ?

en este caso, lo mas recomendable es que miraras los subforos de ASP, Phyton o similares, para buscar informacion sobre lo que pretendes

ya en este caso, tendrias que empezar a realizar funciones de como recojer los datos, para que en (cualquiera de los lenguajes que tomes), te puedan dar mejor orientacion a tu problema

:Adios:

[Jamati]

Gracias Shiryu_Libra, pero por eso mismo no sé por donde empezar; ya que no se que lenguaje me serviría mejor para poder realizar esto que digo.

[Shiryu_Libra]

Iniciado por Jamati

Gracias Shiryu_Libra, pero por eso mismo no sé por donde empezar; ya que no se que lenguaje me serviría mejor para poder realizar esto que digo.

pues sobre lo obio y facil... ve a VB, seria uno de los mas sencillos

leer datos desde LPT del equipo con VB

[Trulala de cordoba]

MUY PERO MUY bueno, te pasas JuanRAPerez, gracias por el aporte y ya estoy guardando esta pagina a mis listados de codigos.

Ahora queria saber si no seria posible si no me podes mandar a mi mail el codigo fuente de la aplicaciones de vb y el asp, o si podes subirlo a algun hosting para bajarlo.
Mil gracias !!!!!!!!!!!!!!!!

[JuanRAPerez]

hi como vas, claro que lo colgare pero al final de el proceso aun me falta postear lo de la paginan y lo de uso del css

espero que esta semana termine eso

[Trulala de cordoba]

Mil gracias JuanRAPerez, me estoy revisando este post de tanto en tanto para ver si esta el código.
Saludos y gracias!!!

[msyll]

Tengo una consulta para cualquiera...

En caso de Windows Server el uso de la DLL Activex plantea restricciones de seguridad por lo cual implica que hay que Registrar la DLL como un componente y darle permisos para que pueda ejecutarse.

En eso no he tenido ningún problema, sin embargo, si no inicio sesión los usuarios que se conectan al servidor web les aparece un error que les dice que no se puede crear el objeto. Al iniciar sesion, el sistema funciona bien. ¿Alguiensabe como solucionar este problema?

[u_goldman]

Iniciado por msyll

Tengo una consulta para cualquiera...

En caso de Windows Server el uso de la DLL Activex plantea restricciones de seguridad por lo cual implica que hay que Registrar la DLL como un componente y darle permisos para que pueda ejecutarse.

En eso no he tenido ningún problema, sin embargo, si no inicio sesión los usuarios que se conectan al servidor web les aparece un error que les dice que no se puede crear el objeto. Al iniciar sesion, el sistema funciona bien. ¿Alguiensabe como solucionar este problema?

Tendríamos que saber cuáles con las restricciones de seguridad de tu sistema, por lo que describes a mi me suena como que el usuario anónimo del IIS no cuenta con los permisos suficientes para consumir el componente. Comienza por ahí, revisa que permisos necesita tu dll y trata de asignarle al usuario anónimo del IIS dichos permisos.

Saludos

[moishefire]

hola gente, muy bueno el aporte de todos, resulta que probe este tema de los activex y me funciona bien, pero cuando intento usar el objeto printer para realizar impresiones me devuelve error de impresora, probe las mismas funciones en el codigo de un boton en un formulario comun en vb y me corre la impresion sin problemas, pero dentro del activex no me ha resultado, es posible que los navegadores a pesar de que los activex tengan permisos denegan algunas acciones? como la de imprimir...
bueno estoy con este tema hace un par de dias
cualquier ayuda sera bienvenida
saludos !!