Tratar cadenas

[angel_dope]

Hola a tod@s, tengo un formulario donde los usuarios introducen varios datos. Antes de insertar estos datos quiero coger uno de los campos y quitar cualquier espacio, punto, guion, barra etc etc que le hayan podido poner, es decir, que se queden solo numeros y letras. Hay alguna forma de conseguirlo?? Gracias

[tammander]

Yo uso esta clase

Código:

class clsRegExp
    private obj, pattern, gg, ic
    
    property let setPattern(str)
        pattern = str
    end property

    property let setGlobal(str)
        gg = str
    end property

    property let setIgnoreCase(str)
        ic = str
    end property

    property get strPattern
        strPattern = pattern
    end property

  '*********************************************************************
  ' Initialization/Termination            BOF
  '*********************************************************************

  'Initialize Class Members
  Private Sub Class_Initialize()
    pattern = ""
    gg = true
    ic = false
  End Sub

  'Terminate and unload all created objects
  Private Sub Class_Terminate()
    ' Terminate 
  End Sub
  '*********************************************************************
  ' Initialization/Termination            EOF
  '*********************************************************************

  
  public function isValidData(esto)
      dim obj, found
        set obj = New RegExp 
        with obj
             .Pattern = pattern
             .Global = gg
             .IgnoreCase = ic
        end with
        isValidData = obj.test(esto)
        set obj = nothing
  end function

  public function substract(esto)
      dim obj, found
        set obj = New RegExp 
        with obj
             .Pattern = pattern
             .Global = gg
             .IgnoreCase = ic
        end with
        Set Matches = obj.Execute(esto)
        found = ""
        for each m in Matches
            found = found & m.value
        next
        substract = found
        set obj = nothing
  end function
  
end class

Para usarla, te dejo un ejemplo:

b = "4'32#frffwDDF-;"
set r = new clsRegExp
r.setPattern = "\w"
response.Write("<br>" & r.substract(b))
set r = nothing


espero te sirva


Un saludo

[angel_dope]

Lo he intentado pero al entrar en la página, me sale el siguiente error:

Error de compilación de Microsoft VBScript error '800a03ea'

Error de compilación de Microsoft VBScript error '800a03ea'

Error de sintaxis

/pruebanif.asp, línea 13

class clsRegExp
^

Que está fallando?? Ahh y una pregunta, para que sirve esto: r.setPattern = "\w"?? Supongo que para que elimine las W, no?? Como habría que ponerlo si quiero eliminar más de un carácter??

[tammander]

Iniciado por angel_dope

Error de compilación de Microsoft VBScript error '800a03ea'



Que está fallando??

Dime donde has puesto la clase. Te recomiendo que la metas en un archivo y la anexes con un include file. Tambien dime lo que hay en la linea justamente anterior. Si lo metes en el mismo archivo, ponlo al principio. Justo despues de

<%@LANGUAGE="VBSCRIPT" CODEPAGE="1252"%>

Iniciado por angel_dope

para que sirve esto: r.setPattern = "\w"?? Supongo que para que elimine las W, no?? Como habría que ponerlo si quiero eliminar más de un carácter??

Los pattern o patrones son la piedra angular del objeto regExp de ASP VBScript. Son patrones de busqueda que resuelven cientos de lineas de código en una sola.

\w --> Significa que busque todas las apariciones de letras y numeros (solo letras y numeros, nada de comillas, puntos, etc) en la cadena pasada

Una forma simple del uso de patrones es este:

b = "Solo quiero saber si aparece la palabra ASP en este texto"
set r = new clsRegExp
r.setPattern = "ASP"
r.setGlobal = true
r.setIgnoreCase = true

if r.isValidData(b) then response.Write("En esta frase: <b>" & b & "</b> existe este patron de búsqueda: " & r.strPattern )


set r = nothing



Páginas de Interés:

Tutorial en español de las expresiones regulares

Lo más básico

Toda una página dedicada a las expresiones regulares

Algo mas avanzado

[angel_dope]

Ok, ya he conseguido que funcione moviendolo al principio del archivo como tu decías. Muchas gracias por todo

P.D.: He estado haciendo pruebas, y elimina todos los caracteres excepto el guión bajo "_" a que se debe esto??

Nuevamente, muchas gracias, salu2

[tammander]

Si, asi es. El comodín /w (en minusculas) es para caracteres alfanumericos y el caracter _ . Otra expresión regular muy buena es

[^a-zA-Z0-9]

Lo mejor es echarle un vistazo a las webs que te puse antes. Verás que se abre todo un mundo nuevo con las expresiones regulares y que es casi un lenguaje en si mismo.


Un saludo

[angel_dope]

Ok, gracias, he usado el patron que me has puesto, pero sin el ^ que es para negar.

Esas páginas que me has puesto van directas a la sección de favoritos jeje. Salu2

P.D.: Os están llegando los avisos de que alguien ha respondido?? Porque a mi no :|

[Myakire]

P.D.: Os están llegando los avisos de que alguien ha respondido?? Porque a mi no :|

Cielos!, no sabia que alguien usaba esa opción! nah, es broma

[angel_dope]

Vaya, este último si que me ha llegado como toca