Duda existencial

[kavik666]

Saludos:

Tengo una seria duda a cerca de las posibilidades de las sentencias SQL. Intentaré explicarme.

He hecho lo siguiente:

Código:

	sql_1="select * from tabla "
	rst1.open sql_1
		
	if rst1.EOF <> TRUE then
		rst1.MoveFirst
		Do While rst1.EOF <> TRUE

                        ' Aqui me falta el codigo q no se ejecutar

			rst1.MoveNext
		Loop
	end if

Mi pregunta es si puedo mostrar el contenido de la tabla sin saber los campos de la misma. Con ésto intento crear un archivo base con el cual pueda abrir cualquier tabla y mostrar todos los campos sin necesidad de hacer un cliente=rst("cliente").

Otra cosilla, si lo de antes se puede hacer, ¿cómo puedo saber el nombre del campo q estoy ejecutando? Es para mostrarlo como cabecera de una tabla, donde mostraría todos los campos y su contenido de la tabla.

Espero q me puedan ayudar. Gracias

[AlZuwaga]

me parece que este mensaje estaría mejor ubicado en el foro ASP en vez del foro Bases de Datos

[kavik666]

Si y no. Mi duda es a cerca de la sintaxis de SQL.

Lo pondré también en el foro de ASP. Gracias

[AlZuwaga]

no! ya estamos en el foro ASP... moví el mensaje

[kavik666]

Ok. Gracias.

Pero y la respuesta a mi pregunta ???????

[AlZuwaga]

Ya va, ya va... paciencia. Te lo estoy haciendo.

Antes de nada, quiero decirte que estás confundido... tu duda no es a cerca de la sintaxis de SQL.
Ahora si:

Código:

Dim oConn, rs, SQL, i, ncampos

set oConn=Server.CreateObject("ADODB.Connection")
set rs=Server.CreateObject("ADODB.Recordset")

oConn.Open "driver={Microsoft Access Driver (*.mdb)};;DBQ=" & Server.MapPath("base.mdb")

SQL = " SELECT * FROM Noticias "
rs.Open SQL, oConn

ncampos = rs.fields.count - 1

Response.Write "<table>" & vbcrlf
Response.Write "<tr>" & vbcrlf
For i = 0 to ncampos
	Response.Write "<td valign='top' align='center'>"
	Response.Write "<b>"
	Response.Write rs(i).name
	Response.Write "</b>"
	Response.Write "</td>" & vbcrlf
Next

if rs.EOF <> TRUE then
rs.MoveFirst
Do While rs.EOF <> TRUE

Response.Write "</tr>" & vbcrlf

Response.Write "<tr>" & vbcrlf

For i = 0 to ncampos
	Response.Write "<td valign='top'>"
	Response.Write rs(i)
	Response.Write "</td>" & vbcrlf
Next
Response.Write "</tr>" & vbcrlf

rs.MoveNext
Loop
Response.Write "</table>" & vbcrlf

end if

rs.close
oconn.close
set rs = nothing
set oconn = nothing

saludos

[kavik666]

Muchas gracias.

Perdona mi impaciencia, pero es q es para el curro y me urgía.

Lo probaré el lunes

Gracias de nuevo

[AlZuwaga]

Ahh no!!! Luego de tipear todo eso me vas a hacer esperar hasta el lunes para saber si te sirve?



suerte

[Nochero]

PLOP!

[kavik666]

Hola dazuaga:

Ya he probado el código q me mandaste. Muchas gracias, pq es justo lo q yo quería

Ahora solo me falta darle la presentación q utilizo en el curro.

Hasta otra

[AlZuwaga]

Bien. Me alegro que te sirva.

Con respecto a las modificaciones, la presentación es algo que debés cambiar ya que sólo era a modo de ejemplo... pero además corregile algunas estupideces que hice como:

Response.Write "<table>" & vbcrlf
Response.Write "<tr>" & vbcrlf


... podrían haber quedado directamente así:

Response.Write "<table>" & vbcrlf & "<tr>" & vbcrlf

saldos

[kavik666]

Una última cosa, q significa

Código:

 & vbcrlf

?????

Es lo único q no entiendo del código

Gracias de nuevo ;)

[AlZuwaga]

es un salto de línea... lo podés omitir totalmente. Es para que el código fuente final HTML quede un poco mas ordenado.

por ejemplo, si ponés:

Código:

Response.Write "<table>"
Response.Write "<tr>"
Response.Write "<td>"
Response.Write "</td>"
Response.Write "</tr>"
Response.Write "</table>"

El resultante HTML va a ser:

Código:

<table><tr><td></td></tr></table>

mientras que si usàs:

Código:

Response.Write "<table>" & vbcrlf 
Response.Write "<tr>" & vbcrlf 
Response.Write "<td>" & vbcrlf 
Response.Write "</td>" & vbcrlf 
Response.Write "</tr>" & vbcrlf 
Response.Write "</table>" & vbcrlf

El resultante HTML será:

Código:

<table>
<tr>
<td>
</td>
</tr>
</table>

Se entiende?