Mostrar Estructura de una Tabla

[chcma]

Buenas Tardes a todos.

Bueno, pues esa es mi duda, ¿Como podría mostrar la estructura de una tabla?

Vamos, lo que quiero hacer es de una tabla que no se cuales son los nombres de sus campos, mostrar los datos de la siguiente manera:

Nombre Campo NombreOtroCampo
Datos Datos
datos Datos
datos Datos

En fin, espero que puedan ayudarme, y desde ya gracias.

[buliwyf]

siendo RS el Recordset:

<table><tr>
<% for each item in rs.fields%>
<td> <%=item.name%></td>
<%next%> </tr>
<%do while not rs.eof%>
<tr>
<% for each item in rs.fields%>
<td> <%=item.value%></td>
<%next%>
</tr>
<%rs.movenext
loop%>
</table>

[AlZuwaga]

Suponiendo que tu recordset se llame "Rs", este fragmento debería hacer lo que necesitás sin problemas:

Código:

<%
' Acá va la conexión y apertura del recordset como habitualmente

miTabla = Rs.GetRows

Response.Write "<table>"

'Creamos la primer línea con los encabezados
Response.Write "<tr>"
For Each Campo in RS.Fields
Response.Write "<td align=""center""><b>" & Campo.Name & "</b></td>"
Next
Response.Write "</tr>" ' fin de los encabezados

'Ahora iteramos el array creado con el GetRows...
'para mostrar los registros:
for Variable_I = 0 to UBound(miTabla,2) 
Response.Write "<TR>"
for Variable_J = 0 to Ubound(miTabla, 1)
Response.Write "<td>" & miTabla(Variable_J, Variable_I) & "</td>"
next
Response.Write "</tr>"
next
Response.Write "</table>"
%>

[AlZuwaga]

aunque la opción de buliwyf me parece más fácil ;)