Paginación

[Owen-Bonilla]

Me baje el código de páginación de Asp Facil .

Lo quiero implementar en una página que estoy creando.

Me manda el siguiente error.


Argumentos incorrectos, fuera del intervalo permitido o en conflicto con otros.

/sistema/Ventas/ListadoG.asp, line 60



Linea 60:
s.AbsolutePage=PaginaActual

Y este es de la linea 60 para arriba de mi código.


Dim oConn, rs, SQL
Dim PaginaActual ' en qué pagina estamos
Dim PaginasTotales ' cuántas páginas tenemos
Dim TamPagina ' cuantos registros por pagina
Dim CuantosRegistros ' para imprimir solo el nº de registro por pagina que queramos

'MODIFICAR AQUI PARA CAMBIAR EL Nº DE REGISTRO POR PAGINA
TamPagina=15

'Leemos qué página mostrar. La primera vez será la inicial
if Request.Querystring("pagina")="" then
PaginaActual=1
else
PaginaActual=CInt(Request.Querystring("pagina"))
end if


set oConn=Server.CreateObject("ADODB.Connection")
oConn.Open "DRIVER={Microsoft Access Driver (*.mdb)}; DBQ=" & Server.MapPath("../db/acceso.mdb") & "; Password=bonilla "
SQL="SELECT grado, seccion, CC, fecha, nombre, apellidop, apellidom, pago FROM " & _
"ventas ORDER BY apellidop"

set rs=oConn.Execute(SQL)

' Defino el tamaño de las páginas
rs.PageSize=TamPagina
rs.CacheSize=TamPagina
%>


<%
'Cuento las páginas
PaginasTotales=rs.PageCount

'Compruebo que la pagina actual está en el rango
if PaginaActual < 1 then
PaginaActual = 1
end if
if PaginaActual > PaginasTotales then
PaginaActual = PaginasTotales
end if

'Por si la consulta no devuelve registros!
if PaginasTotales=0 then

Response.Write("No se encontraron resultados.")

else%>


<%
'Vamos a paginar
rs.AbsolutePage=PaginaActual
%>


En qué puede estar el error?...

Saludos y Gracias

[adolfito]

espero te sirva este codigo
<!--#include file="conection.asp"-->
set rslista = server.CreateObject("ADODB.recordset")
sqllista = "select id,usuario,nombre,activo from mayoreo_clientes"


NumRec = 30

with rslista
.ActiveConnection = dbInfo
.CursorLocation = 3
.CursorType = 3
.PageSize = NumRec
end with


rslista.open sqllista

'seleccion de la pagina a presentar
if trim(request("pagact")) = "" then
strPagAct = 1
else
strPagAct = trim(request("pagact"))
end if


select case trim(request("nav"))
case "1"
CurrentPage = strPagAct + 1
case "-1"
CurrentPage = strPagAct - 1
case ""
if trim(Request("pag")) = "" then
CurrentPage = strPagAct
else
CurrentPage = trim(Request("pag"))
end if
end select

if rslista.EOF and rslista.BOF then
NumTotal = 0
TotPaginas = 0
else
rslista.AbsolutePage = clng(CurrenTpage)
TotPaginas = rslista.PageCount

end if


%>

Esta parte es para lo de siguiente anteriro y pagina 1 2 3 ....
<tr>
<td colspan="5" align="center"> <font size="2" face="Verdana"> <%
strURl = "&PagAct=" & currentpage
strURL = "listado_clientes.asp?nav=-1" & strUrl
if cint(currentpage) <> 1 then
%> <a href="<%=strURL%>">Pagina anterior</a> <%end if%> &nbsp;&nbsp; <%
strURl = "&PagAct=" & currentpage
strURL = "listado_clientes.asp?nav=1" & strUrl
if cint(currentpage) < totpaginas then

%> <a href="<%=strURL%>">Siguiente pagina</a> <%end if%> </font>
</tr>
<tr>
<td colspan="5"> <%for i = 1 to rslista.PageCount%> <%if i = rslista.AbsolutePage then%>
<font face="Verdana, Arial, Helvetica, sans-serif" size="1" color="#FF0000"><b><%=i%>
• </b></font> <%else%> <a href="listado_clientes.asp?PagAct=<%=i%>"><font face="Verdana, Arial, Helvetica, sans-serif" size="1" color="#FF0000"><b><%=i%></b></font></a>
<%end if%> <%next%> </td>
</tr>

<%

cRec = 1
do while cRec <= rslista.PageSize and not rslista.EOF

%>

Aqui va el html q quieres desplegar

<%
cRec = cRec + 1
rslista.MoveNext()
loop
%>

[Owen-Bonilla]

Gracias
Deja pruebo el código que me dices y ahorita te cuento..

Gracias de nuevo !!!

Owen

[urjose]

mmm

weno man !

set rs=oConn.Execute(SQL)

esto no es un recordset llamemoslo simulación de recordset aunque mas bien es un metodo de objeto de conexion.

cambialo por esto y veras que funciona


set oConn=Server.CreateObject("ADODB.Connection")
oConn.Open "DRIVER={Microsoft Access Driver (*.mdb)}; DBQ=" & Server.MapPath("../db/acceso.mdb") & "; Password=bonilla "
SQL="SELECT grado, seccion, CC, fecha, nombre, apellidop, apellidom, pago FROM " & _
"ventas ORDER BY apellidop"

' Defino el tamaño de las páginas
rs.PageSize=TamPagina
rs.CacheSize=TamPagina

Rs.Open SQL,oConn,3,3
%>


Saludos

[Owen-Bonilla]

Sabes cual era el error ( o al menos el error que vi "notaba" ).. era el tipo de conexion, la cambie por esta:

set oConn=Server.CreateObject("ADODB.Connection")
set rs=Server.CreateObject("ADODB.Recordset")

' Conexión por OLEDB
oConn.Open "Provider=Microsoft.Jet.OLEDB.4.0; Data Source="&Server.MapPath("../db/acceso.mdb")&";"
SQL="SELECT grado, seccion, CC, fecha, nombre, apellidop, apellidom, pago FROM Ventas;"

Rs.Open SQL, oConn, 3,3

rs.PageSize=TamPagina
rs.CacheSize=TamPagina

y ya me funciono.....

pero ahora tengo otro problema...

los primeros 15 registros ( yo le indique que me mostrara 15 ) me losmuestra bien, con su respectivo boton de "15 Siguientes", pero al dar click me dice que no encuentra la página, me genera esta direcci´ón:

http://127.0.0.1/sistema/Ventas/rspagina.asp?pagina=2

Ahora en qué puedo estar mal !!!

Saludos y gracias

Owen

[urjose]

pos tienes que cambiar el link que esta en Pagina Siguiente y Pagina Anterior