Problemas para borrar e insertar

[Mocho]

Hola amigos tengo una base de datos acces en una carpeta bd y una página de donde quiero eliminar e insertar registros, pero me da un error, http 500 error interno del servidor, No se puede mostrar la página.
Lo que si puedo hacer es consultar, la dirección es:
http://www.clubmaporal.com
Gracias.

[AlZuwaga]

Microsoft JET Database Engine error '80040e09'

Cannot update. Database or object is read-only .

/default.asp, line 64

[Mocho]

dazuaga que se supone que esta sucediendo, este es un problema del IIS, ??? disculpa mi ingenuidad.
Gracias.

[urjose]

Es un problema de permisos del directorio o la BD o de la forma que estas abriendo el Recordset

Saludos

[Mocho]

Este es el código que utilizo
Si me puedes decir donde esta mal ??
Gracias


<%
Sub Consulta ()
Dim oConn, rs, SQL
Dim nombre

set oConn = Server.CreateObject("ADODB.Connection")
'Access con OLEDB:
oConn.Open "Provider=Microsoft.Jet.OLEDB.4.0; Data Source=" & Server.MapPath("bd\registro.mdb")
'Access con ODBC:
'oConn.Open "Driver={Microsoft Access Driver (*.mdb)}; DBQ=" & Server.MapPath("bd\registro.mdb")

SQL="SELECT * FROM empleado"
'Creo un Recordset (set rs) a partir de la ejecución de la consulta (oConn.Execute)
set rs = oConn.Execute(SQL)

if rs.EOF then
Response.Write("<center><h3>No hay ningún registro para mostrar</h3></center>")
else
Response.Write( "<TABLE BORDER='1' align='center'>" & vbCrlf)
Response.Write( "<TR>" & vbCrlf)
Response.Write( "<TD><B>NUMERO</B></TD>" & vbCrlf )
Response.Write( "<TD><B>NOMBRE</B></TD>" & vbCrlf )
Response.Write( "<TD><B>CEDULA</B></TD>" & vbCrlf )

while not rs.EOF
Response.Write( "<TR>" & vbCrlf )
Response.Write( "<TD>" & rs.Fields("numero") & "</TD>" )
Response.Write( "<TD>" & rs.Fields("nombre") & "</TD>" )
Response.Write( "<TD>" & rs.Fields("cedula") & "</TD>" )
Response.Write( "</TR>" & vbCrlf )
rs.MoveNext
wend
Response.Write("</TABLE>")
end if
rs.Close
set rs = nothing
oConn.Close
set oConn = nothing

Response.write("<br><center><form method='POST' action='default.asp?ac=4'>")
Response.write("<br><input type='submit' value='Eliminar' name='B1'>")
Response.write("</form></center>")
End Sub

Sub f_Insertar ()
Response.write("<form method='POST' action='default.asp?ac=3'>")
Response.write("Nombre: <input type='text' name='xnombre' size='10'><br>")
Response.write("Cédula: <input type='text' name='xcedula' size='10'><br>")
Response.write("<input type='submit' value='Guardar' name='B1'>")
Response.write("</form>")
End Sub

Sub Insertar ()
Dim oConn, rs, SQL

set oConn = Server.CreateObject("ADODB.Connection")
set rs = Server.CreateObject("ADODB.Recordset")
oConn.Open "Provider=Microsoft.Jet.OLEDB.4.0; Data Source=" & Server.MapPath("bd\registro.mdb")
'oConn.Open "Driver={Microsoft Access Driver (*.mdb)}; DBQ=" & Server.MapPath("bd\registro.mdb")
SQL="SELECT * FROM empleado"
rs.Open SQL, oConn, 1, 2
rs.AddNew
rs.Fields("nombre")= Request.Form("xnombre")
rs.Fields("cedula") = Request.Form("xcedula")
rs.Update

rs.Close
set rs = nothing
oConn.Close
set oConn = nothing
End Sub

Sub Eliminar ()
Dim oConn, rs, SQL, iCuantos, iRegistro
set oConn = Server.CreateObject("ADODB.Connection")
set rs = Server.CreateObject("ADODB.Recordset")

oConn.Open "Provider=Microsoft.Jet.OLEDB.4.0; Data Source=" & Server.MapPath("bd\registro.mdb")
'oConn.Open "Driver={Microsoft Access Driver (*.mdb)}; DBQ=" & Server.MapPath("bd\registro.mdb")

SQL="SELECT * FROM empleado"
rs.Open SQL, oConn, 2, 2

rs.MoveFirst

rs.Delete
rs.Update

rs.Close
set rs = nothing
oConn.Close
set oConn = nothing
End Sub

Response.write("<center><a href='default.asp?ac=1'>Consultar y Eliminar Registros</a><br>")
Response.write("<center><a href='default.asp?ac=2'>Insertar Registro a Base de Datos</a><br>")

Response.write("<a href='default.asp'>Limpiar</a></center><br>")


accion=CStr(Request.QueryString("ac"))

Select Case accion
Case "1"
Consulta
Case "2"
f_Insertar
Case "3"
Insertar
Response.write("Registro Insertado")
Case "4"
Eliminar
Response.write("Registro Eliminado")
End Select
%>

[lubetpic]

sin leer mucho el codigo ( no se si esta bien o no) creo que el error es que no tienes permiso de escritura sobre la base de datos

[bakanzipp]

presiona el boton derecho sobre la carpeta donde tienes alojada tu b de datos y certifica que el atributo read only este deschekeado...hace lo mismo con tu propia b de datos.