CDONTS configuracion

[engonga]

hola con el CDONTS se puede hacer que se valide en el servidor
con usuario y password?

como el aspemail de pesist?

[u_goldman]

Según recuerdo no...esa fué la principal razón por la cuál fué suplantado por CDO; aunque puedes crear reglas especiales en tu SMTP que solo permita envíar desde local por ejemplo; pero lo más recomendable es migrar a CDO.

Saludos

[engonga]

ok mi servidor soporta CDO

existe algun ejmplo con CDO para que se valide en el smtp?

[engonga]

he encontrado un ejemplo pero me da un error

el ejemplo

Código HTML:

<% 
DIM corpoMessaggio, numeroCampi, invioA, invioDa, nomeDominio, indirizzoIp, modulo, browserSistemaOperativo 
invioA = "[email protected]" 'Direccion de correo con que se esta accesando al SMTP (debe ser una direccion valida). 
invioDa = "[email protected]" 'Direccion de correo a enviar el mail. 
'------------final de las modificaciones necesarias------------------ 
'nomeDominio = Request.ServerVariables("HTTP_HOST") 
'indirizzoIp = Request.ServerVariables("REMOTE_ADDR") 
'modulo = Request.ServerVariables("HTTP_REFERER") 
'browserSistemaOperativo = Request.ServerVariables("HTTP_USER_AGENT") 
'* creo los objetos cdosys en el servidor y los gestiono 
DIM iMsg, Flds, iConf 
Set iMsg = CreateObject("CDO.Message") 
Set iConf = CreateObject("CDO.Configuration") 
Set Flds = iConf.Fields 
Flds(cdoSendUsingMethod) = cdoSendUsingPort 
Flds(cdoSMTPServer) = "smtp.sumer-consultora.com" 'Aqui se pone el nombre del dominio smtp del servidor de correo 
'Cabe mencionar que se debe tener un software de servidor de correo o se debe usar un smtp que tenga el software para enviar el correo 
'el windows 2000 server y xp profesional no traen un servidor de correo solo te permiten hacer la salida 
'a un servidor de correo como pudiere ser "smtp.prodigy.net.mx", a menos que en su mismo servidor de trabajo 
'tengan uno pueden poner su nombre. 
Flds(cdoSMTPServerPort) = 465
Flds(cdoSMTPAuthenticate) = cdoBasic 'En los siguientes campos se indica que la autenticación sera por ID y clave 
Flds(cdoSendUserName) = "user" 'Aqui se debe poner el ID de usuario con que se accesar al servidor de correo 
'previamente asignado en el campo del SMTP (recuerde debe ser una direccion valida para el servidor de correos). 
Flds(cdoSendPassword) = "pass" 'Aqui por supuesto va la clave de acceso del id de usuario 
'Es preferible que se use de esta manera a menos de que su servidor de correo no requiera 
'autenticación por medio de ID y contraseña, en este caso sí se usa un servidor por 
'ejemplo smtp.prodigy.net.mx (ISP de prodigy), se debe poner su dirección completa de correo 
'y su clave para accesar a su correo como comunmente lo haria al quere revisar su correo. 
Flds.Update 
With iMsg 
Set .Configuration = iConf 
.To = invioA 'Aqui va una dirección de correo valida por el servidor de correo, de preferencia se usa con la que se acceso. 
'en los campos anteriores UserName y Password. 
'.From = Request.Form("email") 'Aqui se pone la dirección de correo a donde se desea enviar el mail 
.From = "[email protected]"'
'.Sender = invioDa 'Este se usa para enviar el mail a esa direccion es posible que les de problemas a mi no me funciono y lo quite. 
.Subject = "prova de correo CDO user password"
.TextBody = "prova correu CDO user password"
.Send 'Por fin se envia el mensaje. 
End With 
%>

y el error es



ADODB.Fieldserror '800a0bb9'
Argumentos incorrectos, fuera del intervalo permitido o en conflicto con otros. /admin/proves_ibw/2cdosys.asp, línea 31

[u_goldman]

Este es un objeto el cual uso para mis desarrollos, fijate si te sirve:

Código:

<%
Class SimpleMailSender
    Private s_titulo
    Private s_de
    Private s_para
    Private s_cc
    Private s_bcc
    Private s_body
    Private s_reply
    Private isHtml
        
    
    Public Property Get Titulo()
        Titulo=s_titulo
    End Property
    Public Property Let Titulo(p_data)
        s_titulo=p_data
    End Property
    
    Public Property Get De()
        De=s_de
    End Property
    Public Property Let De(p_data)
        s_de=p_data
    End Property
    
    Public Property Get Para()
        Para=s_para
    End Property
    Public Property Let Para(p_data)
        s_para=p_data
    End Property
    
    Public Property Get Cc()
        Cc=s_cc
    End Property
    Public Property Let Cc(p_data)
        s_cc=p_data
    End Property
    
    Public Property Get Bcc()
        Bcc=s_bcc
    End Property
    Public Property Let Bcc(p_data)
        s_bcc=p_data
    End Property
    
    Public Property Get Body()
        Body=s_body
    End Property
    Public Property Let Body(p_data)
        s_body=p_data
    End Property
    
    Public Property Get Html()
        Html=isHtml
    End Property
    Public Property Let Html(p_data)
        isHtml=p_data
    End Property
    
        Public Property Get gReply()
        gReply=s_reply
    End Property
    Public Property Let gReply(p_data)
        s_reply=p_data
    End Property
    
    
    
    
    
    Public Function Enviar()
        Dim sch
        Dim objEmail
        Dim EdoError
        Set objEmail = CreateObject("CDO.Message")
        
        sch = "http://schemas.microsoft.com/cdo/configuration/" 
        
        With objEmail.Configuration.Fields

            .Item(sch & "sendusing")  = 2
            .Item(sch & "smtpserver") = "tuSMTP"
            .Item(sch & "sendusername") = "unusuariopermitido"
            .Item(sch & "sendpassword") = "password"
            .Item(sch & "smtpauthenticate") = 1
            .Item(sch & "smtpserverport") = "25"
            .Update
        End With

        Set objMail = Server.CreateObject("CDO.Message") 

        With objEmail
            .Subject = s_titulo
            .From = s_de
            .To = s_para
            .Cc = s_cc
            .Bcc = s_bcc            
            .ReplyTo= s_reply
             
            select case isHtml
                    case True 
                        .HTMLBody  = s_body                     
                    case False 
                        .TextBody  = s_body
                    case else   
                        .TextBody  = s_body
            end select
            
            on error resume next
                .Send
            if err<>0 then
                EdoError=True
                Response.Write err.description
            else
                EdoError=False
            end if
        End With
        
        Set objEmail = Nothing
        Enviar=EdoError
        'Enviar=err.Description
    End Function
    
End Class
%>

Código:

'implementacion.asp
<!--#include file = "simplemailsender.asp"-->
strDetails = "Hola Mundo"

Set mail=New SimpleMailSender
mail.De="[email protected]"
mail.Para="[email protected]"
'mail.Cc= "opcional"
'mail.Bcc="opcional"
mail.Titulo="Titulo"
mail.Html=false 'true si enviaremos HTML
mail.Body=strDetails

if not mail.Enviar then
  'aqui se envia exitosamente, si ya se...pero nunca me dio la gana arreglar la logica :borracho:
else
  'aqui hubo un error
end if

Saludos

[Shiryu_Libra]

Master excelente codigo, esa estructura definitivamente es rara de obtener

Feliz Año Nuevo 2008

[u_goldman]

Iniciado por Shiryu_Libra

Master excelente codigo, esa estructura definitivamente es rara de obtener

Feliz Año Nuevo 2008

Bueno, en realidad lo único que hace es centralizar el envío de emails, en ASP no se puede realmente "ahorrar" en términos de código mediante esta clase, pero en lenguajes OOP, quizás puedes crear este método como virtual dentro de una clase abstracta de esta manera no necesitas crear el objeto.

Salud y feliz año nuevo!