Problema para controlar AS3

[MiLLeN]

Os cuento, nose que hago exactamente mal o porque no funciona, pero tengo declarada una clase, dicha clase tienes dos metodos que me hacen dos funciones, uno funciona correctamente, pero el otro, que lo unico que tiene que hacer es modificar el "alpha" de un MovieClip que le paso no consigo controlarlo, deberia de empezar a modificar el "alpha" del MC cuando la variable estado este a "true", pero tengo algun problema de concepto con lo del codigo en el fotograma1 que no me deja hacerlo funcionar correctamente. ¿Como lo soluciono?

Aqui teneis el codigo del fotograma1 del fla y de la clase del .as

.fla

Código:

import Presentacion; 
var prt:Presentacion = new Presentacion();

var cjBasico:Basico = new Basico();
var miTexto:String = campoTexto.text;
campoTexto.text = "";

prt.escribir(miTexto, campoTexto, 30);
cjBasico.width = 100;
cjBasico.height = 100;
cjBasico.x = 80;
cjBasico.y = 140;
cjBasico.alpha = 0;
addChild(cjBasico);
prt.setEstado(true);
prt.mostrarCajas(cjBasico);
//prt.setEstado(false);

.as

Código:

package {

	import flash.text.TextField;
	import flash.utils.Timer;
	import flash.events.TimerEvent;
	import flash.display.MovieClip;

	public class Presentacion {

		var estado:Boolean = false;

		function Presentacion() {
		}
		
		public function setEstado(estado:Boolean):void{
			this.estado = estado;
		}

		public function escribir(texto:String, campo:TextField, intervalo:Number):void {

			function escribeLetra(Event:TimerEvent):void {
				if (campo.length<texto.length) {
					campo.appendText(texto.charAt(campo.length));
				}
			}

			var miTimer:Timer=new Timer(intervalo,texto.length);
			miTimer.addEventListener(TimerEvent.TIMER, escribeLetra);
			miTimer.start();
		}

		public function mostrarCajas(caja:MovieClip):void {
			function cambiarAlpha(Event:TimerEvent):void {
				if (caja.alpha<1 && estado) {
					caja.alpha+=0.10;
				}
			}

				var miTimer:Timer=new Timer(50,0);
				miTimer.addEventListener(TimerEvent.TIMER, cambiarAlpha);
				miTimer.start();
		}
	}

}

Gracias y un saludo!

[jahepi]

Hola MiLLeN !

Esas funciones internas que se encuentran dentro de los métodos deberías pasarlas a métodos privados de clase:

Código actionscript:

package 
{
 
    import flash.text.TextField;
    import flash.utils.Timer;
    import flash.events.TimerEvent;
    import flash.display.MovieClip;
 
    public class Presentacion 
    {
 
        private var estado:Boolean = false;
        private var caja:MovieClip;
        private var campo:TextField;
        private var texto:String;
 
        function Presentacion() 
        {
        }
        
        public function setEstado(estado:Boolean):void
        {
            this.estado = estado;
        }
 
        public function escribir(texto:String, campo:TextField, intervalo:Number):void 
        {
            this.campo = campo;
            this.texto = texto;
            var miTimer:Timer=new Timer(intervalo,texto.length);
            miTimer.addEventListener(TimerEvent.TIMER, escribeLetra);
            miTimer.start();
        }
 
        private function escribeLetra(Event:TimerEvent):void 
        {
            if (campo.length<texto.length) {
                campo.appendText(texto.charAt(campo.length));
            }
        }
 
        public function mostrarCajas(caja:MovieClip):void 
        {
            this.caja = caja;
            var miTimer:Timer=new Timer(50,0);
            miTimer.addEventListener(TimerEvent.TIMER, cambiarAlpha);
            miTimer.start();
        }
 
        private function cambiarAlpha(Event:TimerEvent):void 
        {
            if (caja.alpha<1 && estado) {
                caja.alpha+=0.10;
            }
        }
    }
}
 

Un saludote !