crear rectas entre 2 puntos

[Jose_marin]

como puedo hacer para que se dibuje automaticamente un recta entre 2 puntos que son drag&drop, es decir yo puedo mover estos puntos a cualquier lado de mi animacion y automaticamente se dibuja la linea recta que los une.
muchas gracias !!!!!!!!!!

[TMeister]

A ver si esto te sirve,.....
Copia/Pega y prueba..
Lo que dibuja la linea es el Prototype dibuja..

Código:

MovieClip.prototype.crea = function(nombre, x, y, ancho, largo, color, prof) {
	tmp_mc = createEmptyMovieClip(nombre, prof);
	tmp_mc._y = y;
	tmp_mc._x = x;
	tmp_mc.lineStyle(1);
	tmp_mc.beginFill(color);
	tmp_mc.moveTo(0, 0);
	tmp_mc.lineTo(0, 0);
	tmp_mc.lineTo(0+ancho, 0);
	tmp_mc.lineTo(0+ancho, 0+largo);
	tmp_mc.lineTo(0, 0+largo);
	tmp_mc.lineTo(0, 0);
};
MovieClip.prototype.dibuja = function(destino) {
	this.startDrag();
	this.onEnterFrame = function() {
		line_mc = createEmptyMovieClip("l", 10);
		line_mc.lineStyle(1, 0x999999);
		line_mc.moveTo(this._x, this._y);
		line_mc.lineTo(this._x, this._y);
		line_mc.lineTo(destino._x, destino._y);
	};
};
MovieClip.prototype.detiene = function() {
	stopDrag();
	delete this.onEnterFrame;
};
/***********************************************
	    Creamos los Objetos a arrastar
***********************************************/
crea("a_mc", 20, 20, 10, 10, 0xFF0000, 1);
crea("b_mc", 120, 120, 10, 10, 0xFF0000, 2);
/***********************************************
	        Asignamos los Eventos
***********************************************/
a_mc.onPress = function() {
	this.dibuja(b_mc);
};
a_mc.onRelease = function() {
	this.detiene();
};
//----------------------------
b_mc.onPress = function() {
	this.dibuja(a_mc);
};
b_mc.onRelease = function() {
	this.detiene();
};

Saludos!!