Mirá aquí te pego el texto de la ayuda de Flash:
Sentencia class
[dynamic] class className [ extends superClass ] [ implements interfaceName[, interfaceName... ] ] {
// class definition here
}
Define una clase personalizada que permite crear instancias de objetos que comparten métodos y propiedades definidas por el usuario. Por ejemplo, si está desarrollando un sistema de seguimiento de facturas, podría crear una clase invoice (factura) que defina todos los métodos y propiedades que debería tener cada factura. Utilizaría entonces el nuevo comando new invoice() para crear objetos invoice.
El nombre de la clase debe coincidir con el nombre del archivo externo que contiene la clase. El nombre del archivo externo debe ser el nombre de la clase con la extensión de archivo .as. Por ejemplo, si se denomina a una clase Student, el archivo que defina la clase debe denominarse Student.as.
Si una clase está contenida en un paquete, la declaración de clase debe utilizar el nombre completo con el formato base.sub1.sub2.MyClass. Además, el archivo AS de la clase debe almacenarse en la ruta de una estructura de directorios que refleje la estructura del paquete, como base/sub1/sub2/MyClass.as. Si la definición de la clase tiene el formato "class MyClass", se encuentra en el paquete predeterminado y el archivo MyClass.as debería situarse en el nivel superior de algún directorio de la ruta.
Por este motivo, es aconsejable planificar una estructura de directorios antes de empezar a crear clases. De otro modo, si decide mover archivos de clases después de crearlos, deberá modificar las sentencias de declaración de clases para reflejar su nueva ubicación.
No es posible anidar definiciones de clase, es decir, no se pueden definir clases adicionales en una definición de clase.
Para indicar que los objetos pueden añadir propiedades dinámicas y acceder a ellas en tiempo de ejecución, incluya la palabra clave dynamic antes de la sentencia class. Para declarar que una clase implemente una interfaz, utilice la palabra clave implements. Para crear subclases de una clase, utilice la palabra clave extends. (Una clase sólo puede ampliar una clase pero puede implementar varias interfaces.) Puede utilizar las palabras clave implements y extends en una sola sentencia. En el siguiente ejemplo se muestran diversos usos habituales de las palabras claves implements y extends:
class C implements Interface_i, Interface_j // OK
class C extends Class_d implements Interface_i, Interface_j // OK
class C extends Class_d, Class_e // not OK
Disponibilidad: Flash Player 6; ActionScript 2.0
Parámetros
className:String - Nombre completo de la clase.
Ejemplo
En el siguiente ejemplo se crea una clase llamada Plant. El constructor Plant utiliza dos parámetros.
Código actionscript:
Ver original// Filename Plant.as
class Plant {
// Define property names and types
var leafType:String;
var bloomSeason:String;
// Following line is constructor
// because it has the same name as the class
function Plant(param_leafType:String, param_bloomSeason:String) {
// Assign passed values to properties when new Plant object is created
this.leafType = param_leafType;
this.bloomSeason = param_bloomSeason;
}
// Create methods to return property values, because best practice
// recommends against directly referencing a property of a class
function getLeafType():String {
return leafType;
}
function getBloomSeason():String {
return bloomSeason;
}
}
En un archivo de script externo o en el panel Acciones, utilice el operador new para crear un objeto Plant.
Código actionscript:
Ver originalvar pineTree:Plant = new Plant("Evergreen", "N/A");
// Confirm parameters were passed correctly
trace(pineTree.getLeafType());
trace(pineTree.getBloomSeason());
En el siguiente ejemplo se crea una clase llamada ImageLoader. El constructor ImageLoader utiliza tres parámetros.
Código actionscript:
Ver original// Filename ImageLoader.as
class ImageLoader extends MovieClip {
function ImageLoader(image:String, target_mc:MovieClip, init:Object) {
var listenerObject:Object = new Object();
listenerObject.onLoadInit = function(target) {
for (var i in init) {
target[i] = init[i];
}
};
var JPEG_mcl:MovieClipLoader = new MovieClipLoader();
JPEG_mcl.addListener(listenerObject);
JPEG_mcl.loadClip(image, target_mc);
}
}
En un archivo de script externo o en el panel Acciones, utilice el operador new para crear un objeto ImageLoader.
Código actionscript:
Ver originalvar jakob_mc:MovieClip = this.createEmptyMovieClip("jakob_mc", this.getNextHighestDepth());
var jakob:ImageLoader = new ImageLoader("http://www.helpexamples.com/flash/images/image1.jpg", jakob_mc, {_x:10, _y:10, _alpha:70, _rotation:-5});
