reproductor flash cs3 no puedo hacer que jale la musica

[acosta9000]

hola tengo tengo un reproductor flash pero al parecer tiene errores no puedo hacerlo que jale la musica alguien sabe como si alguien sabe flas cs3 que me pueda ayudar..puedo darle algo de dinero ah cambio contactenme
dejame tu msn.... o correo gracias

puedo pagar por el trabajo

[esdebon]

Prueba esta clase, ve como funciona y no necesitas mas si necesitas mas puedes contactarme por medio d emi pagina http://fluocode.com

Código actionscript:

import flash.display.MovieClip;
    import flash.media.Sound;
    import flash.net.URLRequest;
    import flash.media.SoundChannel;
    import flash.events.MouseEvent;
    import flash.media.SoundTransform;
    import flash.events.Event;
    import flash.events.ProgressEvent;
 
    public class Principal extends MovieClip {
 
        // Constants:
        // Public Properties:
        // Private Properties:
 
        private var cancion:Sound=new Sound  ;// se encarga en sì del mp3
        private var canal:SoundChannel=new SoundChannel  ;// se encarga de los controles
        private var detenido:int=0;
        private var tocando:Boolean=true;
        private var st:SoundTransform=new SoundTransform  ;
 
        // la variable interna solo la leen las clases del mismo directorio, la variable publica todos, la variable privada solo la clase dentro de la que esta declarada
 
        // Initialization:
        public function Principal() {
            cancion.load(new URLRequest("Guns N' Roses - Sweet Child O' Mine.mp3"));
            reproducir.addEventListener(MouseEvent.CLICK,rep);
            detener.addEventListener(MouseEvent.CLICK,det);
            bajar.addEventListener(MouseEvent.CLICK,baj);
            elslider.addEventListener(Event.CHANGE,vol);
            paneo.addEventListener(Event.CHANGE,pan);
            cancion.addEventListener(Event.ID3, mostrarID3);// datos de la cancion, del mp3
            cancion.addEventListener(Event.COMPLETE, alCompletar);
            cancion.addEventListener(ProgressEvent.PROGRESS, progreso);
 
            // cancion.play(); // no tiene metodo stop!!!
            // cancion.close(); // quita de la memoria, y hay que volver a cargar el archivo;
        }
        private function progreso (e:ProgressEvent):void {
            var total:int = e.bytesTotal;
            var cargado:int = e.bytesLoaded;
            var porciento:int = cargado * 100 / total;
            trace(porciento);
        }
        private function alCompletar(e:Event):void {
            canal=cancion.play(detenido);
            this.addEventListener(Event.ENTER_FRAME, verPosicion);
        }
        private function verPosicion(e:Event) {
            var porciento:int=canal.position*100/cancion.length;
            barra.scaleX=porciento/100;
            picoD.scaleY=canal.rightPeak;// rightPeak es una propiedad
            picoI.scaleY=canal.leftPeak;
        }
        private function mostrarID3(e:Event):void {
            cancion_txt.text=cancion.id3.songName;// desde iTunes, click derecho en el mp3, convert ID3 Tags - debe ser la version 
            album.text=cancion.id3.album;
            artista.text=cancion.id3.artist;
        }
 
        // Public Methods:
        // Protected Methods:
        private function rep(e:MouseEvent):void {
            if (! tocando) {
                tocando=true;
                canal=cancion.play(detenido);
            }
        }
        private function det(e:MouseEvent):void {
            detenido=canal.position;
            canal.stop();
            tocando=false;
        }
        private function baj(e:MouseEvent):void {
            st.volume=.5;
            canal.soundTransform=st;
        }
        private function vol(e:Event):void {
            st.volume=elslider.value;
            canal.soundTransform=st;
        }
        private function pan(e:Event):void {
            st.pan=paneo.value;
            canal.soundTransform=st;
        }
    }
}