Get URL dinamica, una dudita!

[eybel]

Bueno estoy necesitando cargar una URL dinamica...

Algo asi...

on (release) {getURL ("http://www.web.com/"+imagen, _self)
}

Cuando apreto el MC, en este caso lo uso como boton, abre una ventana nueva pero va a estar URL:

http://www.web.com/undefined

+imagen es una variable que es de donde flash toma la imagen, sacando el nombre desde un XML, para mostrar...

Entonces asi puedo abrir la foto sola...Como hago para q funcione???

Intente poniendo _root.imagen pero me aparecio .com/undefinedundefined

Gracias...

Asi intente yo...

imagenbig = _root.imagen


on (release) {getURL ("http://www.web.com/"+imagenbig, _self)
}

Es un MC, lo tengo q poner dentro de onClipEvent () ?

[Mahalo]

El primer parámetro de getURL es de tipo cadena de texto. Prueba a declarar la variable 'imagen' como tal:

Código:

var imagen:String = "xxxxx.jpg";

O monta todo el enlace por separado:

Código:

var enlace:String = "http://www.web.com/"+imagen;
boton.onRelease = function() {
   getURL(enlace);
}

[eybel]

Hola gracias por el codigo, bueno probe esto pero no funciono:

on (release) {

var enlace:String = "http://www.web.com/"+imagen;
expand.onRelease = function() {getURL(enlace);}

}

Probe tal cual vos me lo pasaste y me pedia que lo meta adentro del controlador onClipEvent...

Bueno no me salio y lo cambie a boton...

Me sigue apareciendo udefined...

Te digo que la variable imagen esta en el frame 1 del scene 1.No se si se podia hacer referencia de cualquier lugar de ese modo, lo habia leido pero me olvide...

Capaz es por eso que me aparece undefined...

[Mahalo]

Cuando deseas emplear la variable imagen en un botón, debes respetar las rutas. Por eso te pasé el segundo código, que le da acciones al botón desde la línea principal (obviamente, en aquel caso, boton debería ser el nombre de instancia del botón).
El código que has colgado en último lugar es incorrecto casi del todo, así que olvídalo.
Imagino que en la línea principal cargas el xml, ¿no? Algo así:

Código:

var enlace:String = "http://www.web.com/";
var xml:XML = new XML();
xml.ignoreWhite = true;
xml.onLoad = function () {
   var imagen:String = this.firstChild......;
   enlace += imagen;
}
xml.load("archivo.xml");

// Hasta aquí supongo que lo haces así, ¿no?
// Ahora, suponiendo que el nombre de instancia del botón es 'boton':

boton.onRelease = function () {
   getURL(enlace);
}

Todo el código va en las acciones de fotograma y debería funcionarte, y si no, verifica que a la variable imagen se le asigna un valor correcto.

Saludos!

[eybel]

Te respondo rapido para que veas el codigo que yo tengo, es este:

Yo ahora leo bien y pruebo lo que pusiste vos...

//Permite caracteres tradicionales como letras con tilde la ñ, etc.
System.useCodepage = true;

//Se declara la variable indice de tipo número (utilizada para referencia la noticia a mostrar)
var indice:Number;

//Se declara la variable noticias_xml de tipo XML (utilizada para almacenar el documento xml)
var noticias_xml:XML;

/*
Funcion cargarDatos (utilizada para cargar y cambiar las noticias en el documento)
Esta función recibe un parámetro "_indice" que corresponde al elemento noticia a mostrar
*/
function cargarDatos(_indice:Number){
//Se inicializan variables utilizadas para almacenar los datos de una noticia
var fecha:String;
var titulo:String;
var mensaje:String;
var imagen:String;
//Abel: Este codigo agrega la variable para el codigo de identificacion en el sistema de adopciones...
//var codigo_identificacion:String;

//Recuperando datos del objeto xml
//Se accede al primer elemento [noticia] y se recupera la fecha desde el atributo [fecha]
fecha = noticias_xml.firstChild.childNodes[_indice].attributes.fecha;

//Se accede al primer hijo de elemento [noticia] y se recupera al valor del primer elemento de [titulo]
titulo = noticias_xml.firstChild.childNodes[_indice].firstChild.firstChild.nodeValue;

//Se accede al segundo hijo de elemento [noticia] y se recupera el valor del primer elemento de [mensaje]
mensaje = noticias_xml.firstChild.childNodes[_indice].firstChild.nextSibling.firstChild.nodeValue

//Se accede al último hijo de elemento [noticia] y se recupera el valor del primer elemento de [imagen]
imagen = noticias_xml.firstChild.childNodes[_indice].lastChild.firstChild.nodeValue

//codigo_identificacion = noticias_xml.firstChild.childNodes[_indice].lastChild.firstChild.nodeValue

//Mostrando los datos recuperados en el cuado de texto mensaje_txt y cargando la imagen en pantalla_mc
_root.mensaje_txt.htmlText = "";
_root.mensaje_txt.htmlText += "<p align='center'><font color='#006633' size='18'><b>" + titulo + "</b></font></p>";
_root.mensaje_txt.htmlText += "<p><font size='14'><b>" + mensaje + "</b></font>";
_root.mensaje_txt.htmlText += "<font color='#666666' size='10'>Date: " + fecha + "</font></p>";



this.createEmptyMovieClip("contenedor",this.getNex tHighestDepth());
var foto_mc:MovieClip = contenedor.createEmptyMovieClip("contenedorfoto", this.getNextHighestDepth());
foto_mc.loadMovie("http://www.forosdelweb.com/images/" + imagen);
this.onEnterFrame = function() {
if (foto_mc.getBytesLoaded() != 0 && foto_mc.getBytesLoaded() == foto_mc.getBytesTotal()) {
foto_mc._x = 9;
foto_mc._y = 22;
foto_mc._height = 150;
foto_mc._width = 230;
delete this.onEnterFrame;
trace("fin");
}
};

}


//Función que permite avanzar a la [noticia] siguiente almacenada en el objeto xml
siguiente_btn.onPress = function(){
//comprobando si existe el siguiente elemento [noticia]
if(noticias_xml.firstChild.childNodes[indice+1] != null){//retringue a avanzar solo si hay una [noticia] siguiente
indice++; //incrementado en uno el indice
cargarDatos(indice); //recuprando y mostrando los datos y la imagen en la pantalla
}
}

//Función que permite retroceder a la noticia anterior almacenada en el objeto xml
anterior_btn.onPress = function(){
//comprobando si existe una elemento [noticia] anterior
if(noticias_xml.firstChild.childNodes[indice-1] != null){//retringue a avanzar solo si hay una [noticia] anterior
indice--; //reducciendo en uno el indice
cargarDatos(indice); //recuprando y mostrando los datos y la imagen en la pantalla
}
}

//Inicializaciones
indice=0; //inicializando indice en 0 para mostrar la primera noticia

//creando el objeto noticias_xml de typo XML
noticias_xml = new XML();

//Permite que el objeto XML ignore los espacios en blanco entre marca y marca del documento XML
noticias_xml.ignoreWhite = true;


//El método load() permite cargar el documento xml "noticias.xml"
noticias_xml.load("lastworks.xml");

//El evento onLoad se activa cuado se haya cargado el documento noticias.xml
noticias_xml.onLoad = function(){
//Se llama a la funcion cragarDatos para mostar la primera noticia (esto por la variable indice en 0)
cargarDatos(indice);
}

Entonces pense, como estas fotos se ven chiquitas a un costado.La opcion de hacer tipo POPUP...

Puse un boton que cada vez que se apreta, abra la foto.jpg que este tomada del XML en ese momento con la variable imagen...Eso es lo q quiero lograr.

[Mahalo]

Me remito a mi último mensaje. Si las variables se están cargando bien (compruébalo), monta las acciones del botón desde la línea principal.

[eybel]

Hola Mahalo, si revise probe.Te comento por que las variables cargan bien, por que en el codigo, justamente con esa variable varga las imagenes...

Tiene unas flechitas el sistema y usa la variable imagen para cargar y mostrarla en el Empty MC...Por eso se que andan...

Yo aca estoy errando en la sintaxis del armado del nuevo codigo...

No puedo lograr que tome imagen como variable valida y su correspondiente valor...Ya que todavia me sigue tirando undefined...

Puse el codigo en la linea principal, pero no se por que no toma el valor...

El script es el ultimo que te mande...

• La variable enlace lo puse en la linea 9, abajo de la de noticias
• La funcion de suma dinamica enlace+= imagen, la puse abajo de donde toma el valor del xml.
• Y la funcion on release del boton al final...

Que estoy haciendo mal?

[Mahalo]

Declara las variables fecha, titulo, mensaje e imagen fuera de la función cargarDatos, es decir, junto con indice y noticias_xml, de ese modo serán globales y accesibles desde cualquier parte del código de la línea principal.

[eybel]

Un capo!!!

funciono, yo sabes q estube leyendo el tema de _global ahora q me acuerdo creo que era la forma de que pueda llamarse de cualquier lado, justamente esa era la duda que tenia por eso habia intentado poner _root

Me matas la duda??? por que sacandola afuera de cargar datos funciona como global???

Y para que sea global tiene una sintaxis expecial cuando uno crea la variable???

Saludos!!!! muchas gracias Mahalo...