POST en vb.net

[seinkraft]

Necesito crear una aplicacion que realice un POST a un formulario echo en php para subir un archivo, mas especificamente una imagen, pero no encuentro la forma de hacerlo.

Mire por todos lados en varios foros pero no eh podido hacer funcionar los ejemplos para ese tipo de funcion.

Alguien me puede dar una mano con ello o algun ejemplo que sirva?

[gnzsoloyo]

Hay mucho en la web, sólo tienes que buscar en Google y no tener miedo del inglés:
Working with HttpWebRequest and HttpWebResponse in ASP.NET
How to use HttpWebRequest to send POST request to another web server?
How to use HttpWebRequest and HttpWebResponse in .NET

En definitiva, tienes que estudiar el funcionamiento de la clase HttpWebRequest

[seinkraft]

Gracias por la respuesta.

Tambien econtre estos ejemplos y para mi son oro puro por eso quise compartir el link.

http://developer.yahoo.com/dotnet/howto-rest_vb.html

[seinkraft]

Bueno por el momento logre esto:

Código vb:

Private Sub btnUpload_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles btnUpload.Click
        Dim request As HttpWebRequest
        Dim response As HttpWebResponse = Nothing
        Dim reader As StreamReader
        Dim address As Uri
        Dim data As StringBuilder
        Dim byteData() As Byte
        Dim postStream As Stream = Nothing
 
        Dim username As String
        Dim password As String
        Dim file_location As String
        Dim tags As String
        Dim source As String
        Dim md5 As String
 
        address = New Uri("http://localhost/api/add_image")
 
        ' Create the web request  
        request = DirectCast(WebRequest.Create(address), HttpWebRequest)
 
        ' Set type to POST  
        request.Method = "POST"
        request.ContentType = "multipart/form-data"
 
        ' Create the data we want to send
        username = "user"
        password = "userpass"
        file_location = txtFile.Text
        tags = "coco nu_se"
        source = "http://www.seinkraft.info"
        md5 = "2ef87d61eb6c5d318760db51828d8d00"
 
        data = New StringBuilder()
        data.Append("login=" + username)
        data.Append("&password=" + password)
        data.Append("&file=" + file_location)
        data.Append("&md5=" + md5)
        data.Append("&tags=" + tags)
        data.Append("&source=" + source)
 
        TextBox1.Text = data.ToString
 
        ' Create a byte array of the data we want to send  
        byteData = UTF8Encoding.UTF8.GetBytes(data.ToString())
 
        ' Set the content length in the request headers  
        request.ContentLength = byteData.Length
 
        ' Write data  
        Try
            postStream = request.GetRequestStream()
            postStream.Write(byteData, 0, byteData.Length)
        Finally
            If Not postStream Is Nothing Then postStream.Close()
        End Try
 
        Try
            ' Get response  
            response = DirectCast(request.GetResponse(), HttpWebResponse)
 
            ' Get the response stream into a reader  
            reader = New StreamReader(response.GetResponseStream())
 
            ' Console application output  
            TextBox2.Text = reader.ReadToEnd()
        Finally
            If Not response Is Nothing Then response.Close()
        End Try
    End Sub
 

Y los parametros de la api son:
Parameters
* login: login
* password: password
* file: file as a multipart form
* source: source url
* tags: list of tags as a string, delimited by whitespace
* md5: MD5 hash of upload in hexadecimal format

Lo que no se es como hacer la parte del file (ahora esta echa asi nomas). No se como enviarlo como multipart

Alguien me puede ayudar con ello?

[jmo25]

Hola.

Recorriendo varios foros encontré este problema, voy a intentar ser lo más claro posible. El problema principal es que no hay muchos ejemplos y los que hay son poco claro.

Para abordar este tema hay que tener en cuenta las necesidades de cada aplicación y la configuración del servidor al que vamos a enviar el archivo

De la aplicación tener en cuenta

• Si se envía datos de cadena solamente
• Si se envía archivo/s
• Utiliza buffer de escritura

Del servidor tener en cuanta

• Que protocolo utiliza
  • Si es a través de HTTPS (SSL) requiere que revisemos el certificado del servidor
• Que tipo de autenticación utiliza
  • Anónima
  • Integrada
    • Debemos pasarle las credenciales de conexión o indicarle que utilice las por defecto
  • Básica
    • Indicarle en el head del post el usuario y la contraseña

Certificado del servidor
Cuando la conexión se realiza a través de HTTPS el objeto HttpWebRequest va a requerir una función que valide el certicado del servidor.
¿Como se hace?
1) Crear la función que analiza el certificado

Código vb:

Private Function ValidateCertificate(ByVal sender As Object, ByVal      certificate As X509Certificate, ByVal chain As X509Chain, ByVal sslPolicyErrors As SslPolicyErrors) As Boolean
        Dim resultado As Boolean
        resultado = True
        '
        ' Analizar el certificado y devolver true o false según sea el caso
        '
        Return resultado
    End Function
 

2) Asignar la misma al “ServicePointManager”

Código vb:

ServicePointManager.ServerCertificateValidationCallback = New RemoteCertificateValidationCallback(AddressOf ValidateCertificate)
 

Autenticación
Según el tipo de autenticación requerida por el servidor utilizaremos alguno de los siguiente códigos, hay otras formas de asignar las credenciales, les dejo las que me parecen las más simples

Autenticación Anónima
Podemos obviar el codigo o indicarle que utilizaremos las credenciales por defecto

Código vb:

HttpWRequest.Credentials = CredentialCache.DefaultCredentials
 

Autenticación integrada
Debemos darle las credenciales apropiadas

Código vb:

Dim creds As New Net.NetworkCredential(USERNAME, PSSWD, Domain)
HttpWRequest.Credentials = creds
 

Buffer de escritura
Otro tema a tener en cuenta es si la escritura se realiza directamente al flujo de salida o se retiene en buffer para luego ser enviado.
Para la mayoría de las aplicaciones es más cómodo utilizar el buffer ya que nos permite manejar de forma más simple los errores, la escritura directa se utiliza para envíos de stream, para enviar archivos de gran tamaño con control de progreso en el envío, etc.

Código vb:

HttpWRequest.AllowWriteStreamBuffering = True
 

Enviar datos
Ahora si, pasado el certificado y la autenticación ahora vamos a enviar los datos.
Primero tener en cuenta que si se van a enviar archivos se debe utilizar el contentType=”multipart/form-data” que es distinto de cuando se envía solamente cadenas (contentType=”application/x-www-form-urlencoded” )

Enviar solamente cadenas
Cuando se requiere enviar datos de cadena hay que generar una cadena igual a la del metodo “GET“, que en lugar de concatenarla a la URL se envía por “POST”.
Vi algunas implementaciones donde envían archivos como cadenas codificados en base64, si bien en principio esto funciona no lo recomiendo ya que para eso esta el otro enctype (multipart/form-data)

Código vb:

HttpWRequest.Method = "POST"
HttpWRequest.ContentType = "application/x-www-form-urlencoded"
'Generar cadena igual que para el metodo get
Dim data As StringBuilder = New StringBuilder()
data.Append("param01=" + HttpUtility.UrlEncode("valor01"))
data.Append("&param02=" + HttpUtility.UrlEncode("valor02"))
data.Append("&param03=" + HttpUtility.UrlEncode("valor03"))
 
'Crear array de bytes de la cadena  
Dim byteData() As Byte
byteData = UTF8Encoding.UTF8.GetBytes(data.ToString())
'Setear el largo del stream  
HttpWRequest.ContentLength = byteData.Length
'Escribir datos
Dim postStream As Stream = Nothing
postStream = wr.GetRequestStream()
postStream.Write(byteData, 0, byteData.Length)
 
'Enviar los datos (si buffer está activado) y recuperar la respuesta
Dim Response As HttpWebResponse
Response = wr.GetResponse()
 

Enviar archivos

Para enviar archivo se debe utilizar el contentType “multipart/form-data” del método “POST” esta codificación es una estructura de datos que permite incluir en la misma el contenido de los archivo. Es la que utilizan los exploradores para enviar archivos cuando se crean los forms con input de tipo file.

Código HTML:

<form name="formDocs" method="post" action="pagina.asp" enctype="multipart/form-data">
        <input type="hidden" name="param01" value="valor01"/>
        <input type="file" name=" archivo" />
        <input type="submit" /> 
</form>
 

Este el el código

Código vb:

Dim LocalFile As String = "c:\archivo_a_enviar.txt" 
HttpWRequest.Method = "POST"
'Hay que generar un limite y asegurarnos que sea único
'Por ejemplo
Dim limite As String = "----------" & DateTime.Now.Ticks.ToString("x")
HttpWRequest.ContentType = "multipart/form-data; boundary=" & limite
 
Dim sb As StringBuilder = New StringBuilder()
'Por cada parametro hay que generar una estructura que varía
'si es de archivo o no
 
'Parámnetro de cadena
sb.Append("--")
sb.Append(limite)
sb.Append(vbNewLine)
sb.Append("Content-Disposition: form-data; name=""")
sb.Append("param01")
sb.Append("""")
sb.Append(vbNewLine)
sb.Append(vbNewLine)
sb.Append("param_valor01")
sb.Append(vbNewLine)
 
'Parámnetro de archivo
sb.Append("--")
sb.Append(limite)
sb.Append(vbNewLine)
sb.Append("Content-Disposition: form-data; name=""")
sb.Append("sampfile")
sb.Append("""; filename=""")
sb.Append(Path.GetFileName(LocalFile))
sb.Append("""")
sb.Append(vbNewLine)
sb.Append("Content-Type: ")
sb.Append("application/octet-stream")
sb.Append(vbNewLine)
sb.Append(vbNewLine)
 
'pasamos la cadena a matriz de bytes
Dim postHeader As String = sb.ToString()
Dim postHeaderBytes As Byte() = Encoding.UTF8.GetBytes(postHeader)
 
'Crear la string de límite final como matriz de bytes
Dim limiteBytes As Byte() = Encoding.UTF8.GetBytes(vbNewLine & "--" + limite + vbNewLine)
 
 
'Crear un stream con el archivo
Dim fileStream As FileStream = New FileStream(LocalFile, FileMode.Open, FileAccess.Read)
 
'Calcular el largo del contenido
Dim length As Long = postHeaderBytes.Length + fileStream.Length + limiteBytes.Length
HttpWRequest.ContentLength = length
 
Dim stream As Stream = wr.GetRequestStream()
'Escribir cabecera
stream.Write(postHeaderBytes, 0, postHeaderBytes.Length)
'Escribir contenido del archivo
Dim buffer As Byte() = {}
ReDim buffer(fileStream.Length - 1)
 
Dim bytesRead As Integer = 0
bytesRead = fileStream.Read(buffer, 0, buffer.Length)
While bytesRead <> 0
  stream.Write(buffer, 0, bytesRead)
  bytesRead = fileStream.Read(buffer, 0, buffer.Length)
End While
 
'Escribir el límite final
stream.Write(limiteBytes, 0, limiteBytes.Length)
 
'Enviar los datos (si buffer está activado) y recuperar la respuesta
Dim Response As HttpWebResponse
Response = wr.GetResponse()
 

[jmo25]

Les adjunto el codigo de un modulo que me funciona OK.
Recibe una estructura de parametros indicando si son archivos o cadenas, los envia al servidor y retorna el objeto response.

Saludos, espero les sea de utilidad

Código vb:

Imports System.IO
Imports System.Net
Imports System.Net.Security
Imports System
Imports System.Web
Imports System.Security.Cryptography.X509Certificates
Imports System.Text
 
Module utiles
    Public Enum typeParam
        param_string = 0
        param_file = 1
    End Enum
    Public Structure tParam
        Dim name As String
        Dim value As String
        Dim type As typeParam
    End Structure
 
 
 
    Public Function requestHTTP(ByVal strURL As String, ByVal params() As tParam, Optional ByVal USERNAME As String = "", _
                                 Optional ByVal PSSWD As String = "", _
                                 Optional ByVal Domain As String = "") As HttpWebResponse
 
        '****************************************************************
        'Genarar datos del POST en el stream tmpStream
        '****************************************************************
 
        'Generar limite 
        Dim limite As String = "----------" & DateTime.Now.Ticks.ToString("x")
 
        'Generar contenido del post
        Dim sb As StringBuilder = New StringBuilder()
        Dim paramHeader As String
        Dim paramHeaderBytes As Byte()
        Dim tmpStream As Stream = New MemoryStream()
        Dim buffer As Byte() = {}
        Dim bytesRead As Integer = 0
        Dim i As Integer
        'Recorre cada parametro generando el arreglo de bytes y esribiendolos en el buffer de salida
        For i = 0 To UBound(params)
            sb = New StringBuilder()
            If params(i).type = typeParam.param_string Then
                'Si es una cadena
                sb.Append("--")
                sb.Append(limite)
                sb.Append(vbNewLine)
                sb.Append("Content-Disposition: form-data; name=""")
                sb.Append(params(i).name) 'Nombre del parametro
                sb.Append("""")
                sb.Append(vbNewLine)
                sb.Append(vbNewLine)
                sb.Append(params(i).value) 'Valor del parametro
                sb.Append(vbNewLine)
                'Escribir la cabecera del parametro en el tmpStream
                paramHeader = sb.ToString()
                paramHeaderBytes = Encoding.UTF8.GetBytes(paramHeader)
                tmpStream.Write(paramHeaderBytes, 0, paramHeaderBytes.Length)
            Else
                'Si es un archivo
                sb.Append("--")
                sb.Append(limite)
                sb.Append(vbNewLine)
                sb.Append("Content-Disposition: form-data; name=""")
                sb.Append(params(i).name) 'Nombre del parametro
                sb.Append("""; filename=""")
                sb.Append(Path.GetFileName(params(i).value)) 'Nombre del archivo
                sb.Append("""")
                sb.Append(vbNewLine)
                sb.Append("Content-Type: ")
                sb.Append("application/octet-stream")
                sb.Append(vbNewLine)
                sb.Append(vbNewLine)
 
                'Escribir la cabecera del parametro en el tmpStream
                paramHeader = sb.ToString()
                paramHeaderBytes = Encoding.UTF8.GetBytes(paramHeader)
                tmpStream.Write(paramHeaderBytes, 0, paramHeaderBytes.Length)
 
                Dim fileStream As FileStream = New FileStream(params(i).value, FileMode.Open, FileAccess.Read)
 
                'Escribir el contenido del archivo
                ReDim buffer(fileStream.Length - 1)
                bytesRead = fileStream.Read(buffer, 0, buffer.Length)
                While bytesRead <> 0
                    tmpStream.Write(buffer, 0, bytesRead)
                    bytesRead = fileStream.Read(buffer, 0, buffer.Length)
                End While
 
            End If
        Next
 
        'Crear el string de límite final como matriz de bytes
        Dim limiteBytes As Byte() = Encoding.UTF8.GetBytes(vbNewLine & "--" + limite + vbNewLine)
 
        'Escriba el límite final
        tmpStream.Write(limiteBytes, 0, limiteBytes.Length)
 
 
        '********************************************************************
        'Enviar el request
        '********************************************************************
 
        'Cuando utiliza protocolo HTTPS necesita una función de validación de certificado
        'Para este caso la función devuelve siempre true
        'Si no es HTTPS no utiliza esta funcion
        ServicePointManager.ServerCertificateValidationCallback = New RemoteCertificateValidationCallback(AddressOf ValidateCertificate)
 
        'Crear el objeto HttpWebRequest con la url de la pagina destino
        Dim HttpWRequest As HttpWebRequest = HttpWebRequest.Create(strURL)
        'Si se le pasaron credenciales las asigna, sino utilizar las credenciales actuales
        If (USERNAME <> "") Then
            Dim creds As New Net.NetworkCredential(USERNAME, PSSWD, Domain)
            HttpWRequest.Credentials = creds
        Else
            HttpWRequest.Credentials = CredentialCache.DefaultCredentials
        End If
 
        'Habilitar el buffer, no se envían los datos hasta la sentencia GetResponse()
        HttpWRequest.AllowWriteStreamBuffering = True
 
        HttpWRequest.Method = "POST"
 
        'Asignar el contentType con el limite
        HttpWRequest.ContentType = "multipart/form-data; boundary=" & limite
 
 
        tmpStream.Seek(0, SeekOrigin.Begin)
        'asignar el largo del stream
        HttpWRequest.ContentLength = tmpStream.Length
        Dim stream As Stream = HttpWRequest.GetRequestStream()
 
        ReDim buffer(tmpStream.Length - 1)
        bytesRead = tmpStream.Read(buffer, 0, buffer.Length)
        While bytesRead <> 0
            stream.Write(buffer, 0, bytesRead)
            bytesRead = tmpStream.Read(buffer, 0, buffer.Length)
        End While
 
        Dim Response As HttpWebResponse = Nothing
        Try
            Response = HttpWRequest.GetResponse()
        Catch ex As Exception
            Debug.Print(ex.Message)
        End Try
        Return Response
    End Function
 
   
 
 
    Private Function ValidateCertificate(ByVal sender As Object, ByVal certificate As X509Certificate, ByVal chain As X509Chain, ByVal sslPolicyErrors As SslPolicyErrors) As Boolean
        Dim validationResult As Boolean
        validationResult = True
        '
        ' policy code here ...
        '
        Return validationResult
    End Function
 
    Function readFileHTTP(ByVal strURL As String) As Byte()
        Dim res() As Byte = {}
        Try
            Dim fr As System.Net.HttpWebRequest
            Dim targetURI As New Uri(strURL)
            fr = DirectCast(System.Net.HttpWebRequest.Create(targetURI), System.Net.HttpWebRequest)
            If (fr.GetResponse().ContentLength > 0) Then
                Dim str As New System.IO.StreamReader(fr.GetResponse().GetResponseStream())
                res = System.Text.ASCIIEncoding.ASCII.GetBytes(str.ReadToEnd())
                str.Close()
            End If
        Catch ex As System.Net.WebException
        End Try
 
        Return res
    End Function
 
 
End Module
 

[gnzsoloyo]

Pero... Esto sería mucho más útil para todos si en lugar de ponerlo en un post viejo lo pusieras en una FAQ...
Los post hay que buscarlos, y mucho, en cambio las FAQ están siempre a mano.