Envio peticion y encriptacion

[Rave1996]

Buenos días/tardes/noches, quería preguntarles si podian enviarme algun ejemplo de encriptacion sencilla-avanzada en Visual Basic.net, que la encriptacion fuera mediante una contraseña, y tambien les queria pedir un manual y algunos ejemplos de envio de peticiones php utilizando el metodo post, y que los parametros se definieran entre varios textbox
Saludos y gracias

[Cristo_]

Que tal amigo, saludos, en cuanto a la encriptación te puedo ayudar con las siguientes funciones.
Las hice hace algún tiempo y encripta en AES (Advanced Encryption Standard), lo que hace una funcion es encriptar y la otra desencriptar, una cadena de texto con el método AES, requiere de 2 llaves 1 pública o vector que debe ser de 16 posiciones (puede ir hardcoded o embebida en tu código sin ningún problema) y la llave privada (que es la que deberan de ingresar) que debe ser forzosamente de 32 posiciones; para lo cual te adjunto el código para crear un hash MD5 que crea dicho texto a 32 posiciones a partir de un texto de cualquier número de caracteres, las funciones estan documentadas y explicadas pero si tienes alguna duda, puedes preguntarme

nota: el numero de posiciones por lo que entiendo, son por cuestiones del estandar

Código vb:

''' <summary>
    ''' Encripta una cadena de texto mediante el método AES (rijndael)
    ''' </summary>
    ''' <param name="Texto">Cadena de texto a encriptar de tipo String  </param>
    ''' <param name="Key">Llave Privada de tipo String, con la cual se encripatrá el texto; debe de tener sólo 32 Posiciones (Se recomienda usar Hashing MD5)</param>
    ''' <param name="Vector"> Llave Publica de tipo String , con la cual se encripatrá el texto; debe tener sólo 16 Posiciones </param>
    ''' <param name="Err">Variable Opcional Tipo String Por Referencia, que nos permite obtener los errores al encriptar si es que los hubiera  </param>
    Public Function Encriptar(ByVal Texto As String, ByVal Key As String, ByVal Vector As String, Optional ByRef Err As String = "") As String
        Try
            Dim BKey, BVector As Byte()
            BKey = Encoding.ASCII.GetBytes(CrearHashMD5(Key)) 'llave de 32 Posiciones convertido a byte
            BVector = Encoding.ASCII.GetBytes(Vector)         'Vector de 16 Posiciones convertido a byte
 
            Dim inputBytes As Byte() = Encoding.ASCII.GetBytes(Texto)
            Dim encripted As Byte()
            Dim cripto As New RijndaelManaged
 
            Using ms As New MemoryStream(inputBytes.Length)
                Using objCryptoStream As New CryptoStream(ms, cripto.CreateEncryptor(BKey, BVector), CryptoStreamMode.Write)
                    objCryptoStream.Write(inputBytes, 0, inputBytes.Length)
                    objCryptoStream.FlushFinalBlock()
                    objCryptoStream.Close()
                End Using
                encripted = ms.ToArray()
            End Using
 
            Return Convert.ToBase64String(encripted)
        Catch ex As Exception
            Err = "Error al encriptar: " & ex.Message
        End Try
        Return ""
 
    End Function
    ''' <summary>
    ''' Desencripta una cadena de texto mediante el método AES (rijndael)
    ''' </summary>
    ''' <param name="inputText">Cadena de texto a desencriptar de tipo String  </param>
    ''' <param name="Key">Llave Privada de tipo String, con la cual se desencripatrá el texto; debe de tener sólo 32 Posiciones (Se recomienda usar Hashing MD5)</param>
    ''' <param name="Vector"> Llave Publica de tipo String , con la cual se desencripatrá el texto; debe tener sólo 16 Posiciones </param>
    ''' <param name="Err">Variable Opcional Tipo String Por Referencia, que nos permite obtener los errores al encriptar si es que los hubiera  </param>
    Public Function Desencriptar(ByVal inputText As String, ByVal Key As String, ByVal Vector As String, Optional ByRef Err As String = "") As String
        Try
            Dim BKey, BVector As Byte()
            BKey = Encoding.ASCII.GetBytes(CrearHashMD5(Key))       'llave de 32 Posiciones convertido a byte
            BVector = Encoding.ASCII.GetBytes(Vector)               'Vector de 16 Posiciones convertido a byte
            Dim inputBytes As Byte() = Convert.FromBase64String(inputText)
            Dim resultBytes As Byte() = New Byte(inputBytes.Length - 1) {}
            Dim CadDesencriptada As String = [String].Empty
            Dim cripto As New RijndaelManaged()
            Using ms As New MemoryStream(inputBytes)
                Using objCryptoStream As New CryptoStream(ms, cripto.CreateDecryptor(BKey, BVector), CryptoStreamMode.Read)
                    Using sr As New StreamReader(objCryptoStream, True)
                        CadDesencriptada = sr.ReadToEnd()
                    End Using
                End Using
            End Using
            Return CadDesencriptada
        Catch ex As Exception
            Err = "Error al desencriptar: " & ex.Message
        End Try
        Return ""
    End Function
    ''' <summary>
    ''' Devuelve un valor tipo String del HASH MD5 de una cadena de entrada
    ''' </summary>
    ''' <param name="Texto">Cadena de texto de la cual se generará el Hash MD5</param>
    Public Function CrearHashMD5(ByVal Texto As String) As String
        'Crea un objeto codificado, para asegurar la codificación estandar del texto origen
        Dim ASCIIenc As New ASCIIEncoding
        Dim strReturn
        'Recupera un arreglo de bites basados en el texto origen
        Dim ByteSourceText() As Byte = ASCIIenc.GetBytes(Texto)
        'Instancia el objeto proveedor de MD5
        Dim Md5Hash As New MD5CryptoServiceProvider
        'Computa el valor hash de valor origen
        Dim ByteHash() As Byte = Md5Hash.ComputeHash(ByteSourceText)
        'Ciclo para convertir el ByteHash resultante a cadena
        For Each b As Byte In ByteHash
            'Convierte Bytes a cadena
            strReturn &= b.ToString("x2")
        Next
        'Regresa el hash MD5
        Return strReturn
    End Function
 

y estos son ejemplos de su uso

Código vb:

Encriptar("Hola", 12345678901234561234567890123456, 1234567890123456, Me.LblErrores.Text) 
 
Desencriptar("(cadena encriptada)", 12345678901234561234567890123456, 1234567890123456, Me.LblErrores.Text)
 

Recuerda ambas devuelven un valor string

[Aquaventus]

y tambien les queria pedir un manual y algunos ejemplos de envio de peticiones php utilizando el metodo post

Querrás decir a un servicio PHP. Porque si quieres enviar desde PHP estás en el Foro incorrecto.

[MaLkAvIaN_NeT]

Los métodos de descripción más seguros son los unilaterales, es decir, que sólo sirven para encriptar. Para utilizarlos debes encriptar la clave ingresada por el usuario y comparar con el texto encriptado en la base de datos.

.NET tiene funciones de encriptación basadas en md5, sha1, triple_des, bluefish.

Un ejemplo de uso:

Código:

    Public Enum AlgoritmoDeEncriptacion
        MD5 = 0
        SHA = 1
        TRIPLE_DESC
    End Enum

    Public Function encriptar(ByVal valAlgoritmo As AlgoritmoDeEncriptacion, ByVal strCadena As String, Optional ByVal valIV As Byte = 0, Optional ByVal valKey As Byte = 0) As String

        Dim Codificacion As New UTF8Encoding

        Select Case valAlgoritmo

            Case AlgoritmoDeEncriptacion.MD5
                Dim md5Hasher As MD5 = MD5.Create()
                Dim data As Byte() = md5Hasher.ComputeHash(Encoding.Default.GetBytes(strCadena))
                Dim sBuilder As New StringBuilder
                Dim i As Integer
                For i = 0 To data.Length - 1
                    sBuilder.Append(data(i).ToString("x2"))
                Next i
                Return sBuilder.ToString()

            Case AlgoritmoDeEncriptacion.SHA
                Dim data() As Byte = Codificacion.GetBytes(strCadena)
                Dim resultado() As Byte
                Dim sha As New SHA1CryptoServiceProvider
                resultado = sha.ComputeHash(data)
                Dim sb As New StringBuilder
                For i As Integer = 0 To resultado.Length - 1
                    If resultado(i) < 16 Then
                        sb.Append("0")
                    End If
                    sb.Append(resultado(i).ToString("x"))
                Next
                Return sb.ToString() '<-

            Case AlgoritmoDeEncriptacion.TRIPLE_DESC

                Dim message As Byte() = Codificacion.GetBytes(strCadena)
                Dim criptoProvider As New TripleDESCryptoServiceProvider
                Dim criptoTransform As ICryptoTransform = criptoProvider.CreateEncryptor(criptoProvider.Key, criptoProvider.IV)
                Dim memorystream As New MemoryStream
                Dim cryptoStream As New CryptoStream(memorystream, criptoTransform, CryptoStreamMode.Write)
                cryptoStream.FlushFinalBlock()
                Dim encriptado As Byte() = memorystream.ToArray
                Dim cadenaEncriptada As Object = Codificacion.GetString(encriptado)
                Return cadenaEncriptada

            Case Else
                Return ""
        End Select

    End Function