uso del evento KEYPRESS de textbox en VB winform .NET....

[nizaro]

oigan, en VB6.0 yo tenia una forma muy eficiente de asegurarme que el usuario no introdujera valores alfanumericos en un textbox que unicamente debia aceptar numeros.... y es el siguiente:

--------------------------------------------
Private Sub txtCotizacion_KeyPress(KeyAscii As Integer)
KeyAscii = filtroEntero(KeyAscii)
End Sub
--------------------------------------------
Public Function filtroEntero(KeyAscii As Integer) As Integer
If KeyAscii <> 8 Then
If KeyAscii < 48 Or KeyAscii > 57 Then
filtroEntero = 0
Else
filtroEntero = KeyAscii
End If
Else
filtroEntero = 8
End If
End Function
--------------------------------------------

pero ahora estoy aprendiendo VB.NET y la verdad no tengo ni la menor idea de como emular esta funcionalidad con la ayuda del evento keypress del textbox.....
por favor si alguien tiene una idea.... que la diga....

de antemano muchisimas gracias...

atte: el nizaro :(

[RootK]

Sería mas o menos así:

Private Sub TextBox1_KeyPress(ByVal sender As Object, ByVal e As System.Windows.Forms.KeyPressEventArgs) Handles TextBox1.KeyPress
Dim KeyAscii As Integer
KeyAscii = filtroEntero(Asc(e.KeyChar))
End Sub
Public Function filtroEntero(ByVal KeyAscii As Integer)
If KeyAscii <> 8 Then
If KeyAscii < 48 Or KeyAscii > 57 Then
Return 0
Else
Return KeyAscii
End If
Else
Return 8
End If
End Function

Ya sería cosa de adaptarlo a lo que necesitas pero esa es la idea general.

Espero que te sirva.

Salu2

[nizaro]

pues la verdad ya lo he intentado asi mas o menos como lo planteas, pero no veo la forma de como "interceptar" el key antes de que se lo asigne el form al textbox, es como si no pudieras eviarlo.... ademas, no es posible modificar el key del textbox desde este evento [a diferencia de VB6.0] porque el arg se lo manda byval, y n obyref :(
esto es un gran problema.... :(
creo que ya encontre una fuerte desventaja del .NET comparado con VB6.0... :(

espero haya otra solucion viable, si se les ocurre otra idea, porfa hagamenla saber....

atte: el nizaro

[xknown]

Puedes hacerlo de una manera simple con:

Código:

Private Sub txtCotizacion_KeyPress(ByVal sender As Object, ByVal e As System.Windows.Forms.KeyPressEventArgs) Handles txtCustomLog.KeyPress
        If Not (Char.IsDigit(e.KeyChar) Or Char.IsControl(e.KeyChar)) Then
            e.Handled = True
        End If
    End Sub

Saludos

[nizaro]

en verdad esa fué una MAGNIFICA respuesta, llevo semanas tratando de resolver ese problema pero mi falta de experiencia en .NET y mi error al tratar de resolver los problemas al estilo 6.0 ... pues hacen que no vea la respuesta aunque este frente a mis narices.... !!!!

muchas gracias Xknown, en verdad que me has salvado el día...

y tambien gracias a RootK, que aunque no entendí a cabalidad su respuesta, pues tambien hay que reconocer su ayuda......

gracias a los dos

atte: el nizaro

[laureano59]

Hola xKnown

Si eso fue una excelente respuesta, pero como funciona con ASP.NET ya que esa es para Visual Basic.NET y no me funciona en ASP.NET


Gracias

[xknown]

Efectivamente no funciona y no tiene porque funcionar con asp.net ya que los TextBox's de asp.net ni siquiera tienen el evento OnKeyPress. Si quieres tener la misma funcionalidad tienes que utilizar código del lado del cliente, definitamente el más adecuado es javascript, ya que es soportado por varios navegadores.
Aquí te envío un pequeño ejemplito:

Código:

<%@ Page Language="VB" %>
<script runat="server">
    Sub Page_Load( sender as Object,e as EventArgs)
        Dim script as String = "<script type=""text/javascript"">"
        script += "function validar(e) {"
        script += "tecla = (document.all)?e.keyCode:e.which;"
        script += "if (tecla==8) return true;"
        script += "patron = /\d/;"
        script += "te = String.fromCharCode(tecla);"
        script += "return patron.test(te);"
        script += "}"
        script += "</" + "script>"
        RegisterClientScriptBlock("kbd",script)
        txtDemo.Attributes.Add("onkeypress","return validar(event)")
    End Sub
</script>
<html>
<head>
</head>
<body>
    <form runat="server">
        <asp:TextBox id="txtDemo" runat="server"></asp:TextBox>
        <!-- Insert content here -->
    </form>
</body>
</html>

Saludos

[laureano59]

Hola de nuevo.

Bueno, lograr lo anterior en un java script no es complicado, Lo que verdaderamente requiero es que al escribir un código en un TEXTBOX y luego dar ENTER (todo esto es en ASP.NET) automaticamente me haga el siguiente evento : consultarme unos datos en una base de datos y mostrar el resultado en un textbox.

El problema no es conectarme a la base de datos lo unico que no se es como hacerlo al precionar ENTER y no se Si con JAVA SCRIPT se pueda.

Si tienes alguna solución o un ejemplillo se lo agradesería.


Gracias de nuevo