Guardar archivos en Visual Basic

[FedericoC]

Hola, mi nombre es Federico y necesito su ayuda...
Estoy haciendo una aplicación, donde necesito guardar las configuraciones de los usuarios, pero nose en que tipo de archivos guardarla. ¿que me recomiendan?, si es posible, y me pueden decir como o decirme donde puedo conseguir un tutorial...

Muchisimas gracias

[OYEME]

puedes guardarlo en el regedit con savesettings y lo recuperas con getsettings

ejemplo:

SaveSetting "nombreapli1","subapli1", "campo1", 50
donde 50 es loq ue guardas

SaveSetting "nombreapli1","subapli1", "campo2", 100

eso es pa guardar ahora para recuperar ese valor seria:
Xcampo1 =GetSetting("nombreapli1","subapli1", "campo1", 0 )
donde 0 es el valor por defecto peor en este caso recuperaras 50 por que ese valor se guardo en campo1

esto se guarda en el editor de regsitro
HKEY_CURRENT_USER\Software\VB y VBA Program

Espero te sirva

EL PeRu es SUPER

[lic_dahool]

Con este código puedes utilizar archivos INI

Código:

Option Explicit

'declares for ini controlling
Private Declare Function GetPrivateProfileSection Lib "kernel32" Alias "GetPrivateProfileSectionA" (ByVal lpAppName As String, ByVal lpReturnedString As String, ByVal nSize As Long, ByVal lpFileName As String) As Long
Private Declare Function GetPrivateProfileString Lib "kernel32" Alias "GetPrivateProfileStringA" (ByVal lpApplicationName As String, ByVal lpKeyName As Any, ByVal lpDefault As String, ByVal lpReturnedString As String, ByVal nSize As Long, ByVal lpFileName As String) As Long
Private Declare Function WritePrivateProfileSection Lib "kernel32" Alias "WritePrivateProfileSectionA" (ByVal lpAppName As String, ByVal lpString As String, ByVal lpFileName As String) As Long
Private Declare Function WritePrivateProfileString Lib "kernel32" Alias "WritePrivateProfileStringA" (ByVal lpApplicationName As String, ByVal lpKeyName As Any, ByVal lpString As Any, ByVal lpFileName As String) As Long

'// INI CONTROLLING PROCEDURES

'reads ini string
Public Function ReadIni(Filename As String, Section As String, Key As String) As String
Dim RetVal As String * 255, v As Long
v = GetPrivateProfileString(Section, Key, "", RetVal, 255, Filename)
If v > 0 Then ReadIni = Left(RetVal, v)
End Function

'reads ini section
Public Function ReadIniSection(Filename As String, Section As String) As String
Dim RetVal As String * 255, v As Long
v = GetPrivateProfileSection(Section, RetVal, 255, Filename)
If v > 1 Then ReadIniSection = Left(RetVal, v - 1)
End Function

'writes ini
Public Sub WriteIni(Filename As String, Section As String, Key As String, Value As String)
WritePrivateProfileString Section, Key, Value, Filename
End Sub

'writes ini section
Public Sub WriteIniSection(Filename As String, Section As String, Value As String)
WritePrivateProfileSection Section, Value, Filename
End Sub

Saludos.

[FedericoC]

y en dll´s?, se puede crear en VB6?