Funcion eliminar registro que borra todo

[XYON126]

Hola!

Tengo un problemilla y no veo donde tengo el error, he realizado una funcion para borrar el primer registro de un archivo que siempre esta vacio(el registro), el problema es que en vez de borrarme el 1er registro, me genera los mismos registros que tenia menos uno, pero todos vacios como el primero, el que queria eliminar. Podia alguien echarme una manita y decirme donde he cometido el error.

Muchas gracias

Código vb:

' --------------------------------------------------------------------------
' \\ -- Subrutina para eliminar el 1er registro si esta en blanco.
' --------------------------------------------------------------------------
 
Private Sub EliminarRegistro()
 
' Verificamos que el archivo temporal no exista, si existe se elimina
If Dir("Temporal.dat") = "Temporal.dat" Then
Kill "Temporal.dat"
End If
 
FileTemp = FreeFile
'Abrimos y creamos un nuevo fichero temporal
Open "Temporal.dat" For Random As FileTemp Len = Len(HorasTemp)
 
RegActual = RegActual + 1
RegActualTemp = 1
 
'Se recorren los registros del archivo
 
For Pos = 1 To RegUltimo - 1
 
    Get #Numero, RegActual, Horas
    
MsgBox "RegActual =  " & RegActual
    
With HorasTemp
    
'Variables datos de las Horas.
                
        .inicio1 = inicio1_C
        .fin1 = fin1_C
        .inicio2 = inicio2_C
        .fin2 = fin2_C
        .inicio3 = inicio3_C
        .fin3 = fin3_C
        .tiempo = tiempo_C
        .dia = dia_C
        .fecha = fecha_C
        .semana = semana_C
        .mes = mes_C
        .año = año_C
        .npedido = npedido_C
        .Totalhoras = Totalhoras_C
                
End With
    
'Escribe en el archivo temporal los datos
MsgBox "RegActualTemp  =  " & RegActualTemp
    
    Put #FileTemp, RegActualTemp, HorasTemp
 
    RegActual = RegActual + 1
    RegActualTemp = RegActualTemp + 1
 
Next
 
Close Numero
Close FileTemp
 
'Elimina el archjivo con los datos
Kill "Horas.dat"
 
 
'Renombra el archivo temporal a Datos.dat
Name "Temporal.dat" As "Horas.dat"
 
End Sub
 

[pkj]

No estoy seguro de que hayas abierto el fichero de datos Numero para leerlo, ya que en la sub solo lo cierras "Close Numero".
De todas formas los valores que guardas de cada registro parecen siempre los mismos.
¿No deberia ser algo como esto?

Código vb:

Private Sub EliminarRegistro()
 
' Verificamos que el archivo temporal no exista, si existe se elimina
If Dir("Temporal.dat") = "Temporal.dat" Then
Kill "Temporal.dat"
End If
 
FileTemp = FreeFile
'Abrimos y creamos un nuevo fichero temporal
Open "Temporal.dat" For Random As FileTemp Len = Len(HorasTemp)
 
Numero = FreeFile
'Abrimos el fichero de datos
Open "Horas.dat" For Random As Numero Len = Len(HorasTemp)
 
RegActual = RegActual + 1
 
'Se recorren los registros del archivo
 
For Pos = 1 To RegUltimo - 1
 
    Get #Numero, RegActual, Horas
    
MsgBox "RegActual =  " & RegActual
    
'Escribe en el archivo temporal los datos
MsgBox "RegActual  =  " & RegActual
    
    Put #FileTemp, RegActualTemp, Horas
 
    RegActual = RegActual + 1
 
Next
 
Close Numero
Close FileTemp
 
'Elimina el archjivo con los datos
Kill "Horas.dat"
 
 
'Renombra el archivo temporal a Datos.dat
Name "Temporal.dat" As "Horas.dat"
 
End Sub
 

Saludos

[erbuson]

Hola:

Te respondo en este mensaje porque aqui es donde tienes la pregunta y a fin de no liar al foro:

Código vb:

Private Sub EliminarRegistro()
  Dim Entrada As Integer, Salida As Integer, Registro As Single
  Dim RegistroDatos As String * 256
  
  Entrada = FreeFile
  Open "Horas.dat" For Random As #Entrada Len = 256
  Salida = FreeFile
  Open "Horas.tmp" For Random As #Salida Len = 256
  ' Bucle desde el segundo hasta el final (el tamaño del archivo dividido por la longitud de registro)
  For Registro = 2 To LOF(Entrada) / 256
    ' Leemos el Registro
    Get #Entrada, Registro, RegistroDatos
    ' Grabamos el nuevo en el siguiente registro (el tamaño del archivo dividido por la longitud) + 1
    Put #Salida, LOF(Salida) / 256 + 1, RegistroDatos
  Next
  Close #Entrada
  Close #Salida
  
  Kill "Horas.dat"
  Name "Horas.tmp" As "Horas.dat"
  
End Sub
 

Como ves resulta mas simple de lo que parece, pero no me saltes de aqui para allá. Como te decía en el otro mensaje, revisa el código para aprender su función.

No he puesto la comprobación de existencia del anterior que la puedes simplificar en una sóla y yo te aconsejaría utilizarla así

If Dir("Horas.tmp") <> "" Then Kill "Horas.tmp"

porque si por ejemplo el archivo en disco se llama HORAS.TMP no te funcionará porque el nombre Horas.tmp es diferente de HORAS.TMP


Saludos

[XYON126]

Hola pkj!

Referente al codigo me comentas que no esta abierto en esa rutina el Archivo o canal Numero, este lo tengo abierto en el form_Load() al principio, por eso aqui es donde solo abro el temporal para guardar todo lo del archivo Horas.dat escepto el primer registro que es el que me interesa borrar.
He probado tu codigo y me da un error en la linea .:

29. " Put #FileTemp, RegActualTemp, Horas " ,

el error que me da es "Nümero de registro incorrecto". por otro lado veo que has eliminado todo lo contenido en el "Whit/End With", Pregunta de novato.: No es necesario leer y guardar en variables temporales registro a registro o se puede hacer directo?.

Un saludo

[XYON126]

Hola erbunson!

Gracias por adelantado, como bien dices he preferido dividir los temas para no liarla ya que en un lado toco un tema y aqui otro aunque del mismo programilla, pero temas totalmente diferentes. Veo que en la linea 14. Put #Salida, LOF(Salida) / 256 + 1, RegistroDatos, en vez de la variable RegActualTemp pones LOF(Salida) / 256 + 1 que en principio seria lo mismo, ¿Es asi, es mejor es por esto el error de numero de registro ? Tambien veo que como habia consultado a pkj no hay el Whit/End whit ¿Es esto lo que me provocaba que me guardase todos los regitros pero con ceros?

Un saludo

[erbuson]

Hola XYON, el tema es que si grabas con la opción que te doy de LOF(Fichero)/Longitud + 1 con esto SIEMPRE obligas al siguiente registro libre.

Por otra parte si es necesario LEER el Registro, cosa que conseguimos con el GET y la variable para después grabarlo con el PUT, aunque como puedes comprobar no necesariamente EN ESTE CASO tenemos la necesidad de leer en el UDT ya que lo único que hacemos es Leer la Variable desde uno para Grabarla en el otro.

Lo que es del todo innecesario es el Whit/End Whit que utilizas ya que puedes trabajar directamente sobre el UDT, por ejemplo cuando pasas un dato al MsFlexGrid lo puedes hacer como Horas.LoQueSea

Saludos

[pkj]

Imagino que el código de erbuson será mejor, ya que creo que tiene experiencia en trabajar con ese tipo de archivos.
Yo realmente solo he modificado un poco tu código.

Como has comentado, con el with lo que hacías era estropear los registros leidos, cuando para lo que tú querías hacer solo hay que leer el registro y guardarlo directamente al nuevo fichero.

El fallo que me comentabas que dá era porque no he revisado tu línea de Put y no he visto que usa una variable incorrecta. No es RegActualTemp sino RegActual, aunque imagino que realmente el mejor modo sería algo como lo que pone erbuson:

Put #Salida, (LOF(Salida) / Len(Horas)) + 1, Horas

Que se dé bien

[XYON126]

Hola pkj!

Muchas gracias, por lo que comentas del codigo de erbunson es cierto lo he probado y modificado en las partes que duplicaba las sentencias que yo tenia en otras lineas fuera de este codigo y me ha funcionado perfectamente.
Como me comentaba Erbunson, aparte de ver el codigo lo que hago es estudiarlo a fondo para aprender, pues copiar y pegar si no se lo que hace el codigo no me aporta nada.

Un saludo y muchas gracias

[XYON126]

hola erbunson!

Una consulta, en tu codigo de borrado de registro sobre entiendo que el valor de la variable "Dim RegistroDatos As String * 256", este 256 se lo has dado como ejemplo, que deberia ser el tamaño del LEN(archivo.dat) es decir que si mi archivo.dat tiene un tamaño por registro de 433 la variable "Dim RegistroDatos As String * 433" seria asi, con intencion de en una sola variable guardar todo el registro.

Estoy casi seguro pero si no fuese asi, dime el porque.

Muchas gracias

[erbuson]

Efectivamente era un ejemplo y lo que piensas es correcto el 256 es en mi caso la longitud de registro.

Saludos

[pkj]

Ese valor es la longitud de 1 registro.
Erbuson ha usado un registro que solo contiene un texto de 256 caracteres como ejemplo.
Tu vas a usar la variable Horas en lugar de RegistroDatos, y el valor a usar debe ser Len(Horas), que es la suma de las longitudes de todos los valores dentro de el registro.

len(horas.Inicio1)+len(horas.fin1)+len(horas.inici o2)+.....

Al poner Len(Horas) consigues la suma de todos de una sola vez.

Espero habertelo aclarado.

Saludos

[XYON126]

Muchas gracias!

Aclarado.

Un saludo