Problema con MsFlexgrid

[XYON126]

Hola!

Tengo un problema, tengo un boton que cuando lo ejecuto debe cargarme unos datos en un Msflexgrid el problema esta en que el archivo tiene varios registros pero en cambio solo me carga uno ¿Donde he cometido el error?

Un saludo y muchas gracias

Este es el codigo del boton.:

Código vb:

'Botón para posicionarse en el registro de la semana actual
'###########################################################
 
Private Sub cmd_actual_Click()
LimpiarGrid
FunSemanaActual
 
Get #Numero, RegTemp, Horas
Do
    CargarDatos
    VisualizarDatos
    RegTemp = RegTemp - 1
    
Loop While dia_C > "lunes"
 
End Sub
 

Y aqui esta el codigo de las funciones que aparecen en el boton .:

Código vb:

' ---------------------------------------------------------------------------
' \\ -- Función para asignar los Datos de un registro del archivo Horas.dat a
' -----  las variables internas.
' ---------------------------------------------------------------------------
Private Sub CargarDatos()
 
'Asignamos contenidos de las variables con datos de Horas.dat.
With Horas
 
inicio1_C = .inicio1
fin1_C = .fin1
inicio2_C = .inicio2
fin2_C = .fin2
inicio3_C = .inicio3
fin3_C = .fin3
tiempo_C = .tiempo
dia_C = Trim(.dia)
fecha_C = .fecha
semana_C = .semana
mes_C = .mes
año_C = .año
npedido_C = .npedido
Totalhoras_C = .Totalhoras
 
End With
 
End Sub
 
' ---------------------------------------------------------------------------
' \\ -- Subrutina que Visualiza los datos en el MSFlexGrid
' ---------------------------------------------------------------------------
Private Sub VisualizarDatos()
 
'Mostramos los datos en las celdas
Dim Columna As Single
Select Case dia_C
Case "lunes": Columna = 0
Case "martes": Columna = 1
Case "miercoles": Columna = 2
Case "jueves": Columna = 3
Case "viernes": Columna = 4
Case "sabado": Columna = 5
Case "domingo": Columna = 6
End Select
 
MSFlexGrid.TextMatrix(0, Columna) = fecha_C
MSFlexGrid.TextMatrix(1, Columna) = inicio1_C
MSFlexGrid.TextMatrix(2, Columna) = fin1_C
MSFlexGrid.TextMatrix(3, Columna) = inicio2_C
MSFlexGrid.TextMatrix(4, Columna) = fin2_C
MSFlexGrid.TextMatrix(5, Columna) = inicio3_C
MSFlexGrid.TextMatrix(6, Columna) = fin3_C
MSFlexGrid.TextMatrix(7, Columna) = tiempo_C
 
End Sub
 
' ---------------------------------------------------------------------------
' \\ -- Limpia el MSFlexGrid.
' ---------------------------------------------------------------------------
Private Sub LimpiarGrid()
 
Dim i As Integer, c As Integer
 
For i = 1 To 7
    For c = 0 To 6
    MSFlexGrid.TextMatrix(0, c) = ""
    MSFlexGrid.TextMatrix(1, c) = ""
    MSFlexGrid.TextMatrix(2, c) = ""
    MSFlexGrid.TextMatrix(3, c) = ""
    MSFlexGrid.TextMatrix(4, c) = ""
    MSFlexGrid.TextMatrix(5, c) = ""
    MSFlexGrid.TextMatrix(6, c) = ""
    MSFlexGrid.TextMatrix(7, c) = ""
    Next c
Next i
    
End Sub
 
' ---------------------------------------------------------------------------
' \\ -- Subrutina para para posicionarse en el registro de la semana actual.
' ---------------------------------------------------------------------------
Private Sub FunSemanaActual()
 
Dim i As Integer
 
SemanaActual = Format(Date, "WW")
 
D = LOF(Numero) / 94
 
For i = 0 To D
 
    Get #Numero, RegActual, Horas
    SemanaTemp = Horas.semana
       If SemanaTemp = SemanaActual Then Exit For
            If SemanaTemp < SemanaActual Then
            RegActual = RegActual + 1
            ElseIf SemanaTemp > SemanaActual Then
            RegActual = RegActual - 1
       End If
 
Next i
RegTemp = RegActual
End Sub
 

[erbuson]

Hola: Asi a primera vista y sin analizar del todo por si se trata de esto, veo que la función de Lectura la tienes fuera del Bucle:

Creo que en lugar de estar de esta manera

Get #Numero, RegTemp, Horas
Do
CargarDatos
VisualizarDatos
RegTemp = RegTemp - 1
Loop While dia_C > "lunes"


Debería estar de esta otra no ?

Do
Get #Numero, RegTemp, Horas
CargarDatos
VisualizarDatos
RegTemp = RegTemp - 1
Loop While dia_C > "lunes"

De lo contrario, ¿ que sentido tiene el Bucle ? ya que siempre está procesando el mismo contenido de Horas

[XYON126]

Hola erbunson!

De momento ahora me visualiza mas registros me mirare el codigo no sea tenga un error en otro sitio, por lo menos ahora me funciona al 70% ya comentare el donde si consigo encontrar el resto del problema.Ya que me hace el tonto en otras cosas.

Un saludo

[erbuson]

Hola Xyon:

La comparación del Do/Loop me parece que no tiene ningun sentido, ya que se trata de una comparación que no puede funcionar:

lunes
martes
miercoles
jueves
viernes
sabado
domingo

el orden alfabético que tu comparas sería realmente

domingo
jueves
lunes
martes
miercoles
sabado
viernes

¿ podría estar por ahí el problema ?

[XYON126]

Iniciado por erbuson

Hola Xyon:

el orden alfabético que tu comparas sería realmente

domingo
jueves
lunes
martes
miercoles
sabado
viernes

¿ podría estar por ahí el problema ?

Hola Erbuson!

No comprendo lo que comentas que mi orden de comparación es este .:

domingo
jueves
lunes
martes
miercoles
sabado
viernes

ya que aunque yo leo de mayor a menos que seria asi .:

domingo
sabado
viernes
jueves
miercoles
martes
lunes

en el peor de los casos que solo es que haya un dia y sea lunes o en su defecto tres dias, seria .:

domingo
martes
lunes

pero jamas los puedo tener revueltos o por lo menos asi creo ya que se graba en el archivo y que es secuencial o ¿ estoy equivocado?.

Un saludo

[erbuson]

Hola Xyon:

Suponiendo los días de la semana
1 - Lunes
2 - Martes
3 - Miercoles
4 - Jueves
5 - Viernes
6 - Sabado
7 - Domingo
En una comparacion SIEMPRE 2 es menor que 4

Pero la comparación en VB se realiza según caracteres y el caracter J SIEMPRE es antes que M

Esta es mas o menos la idea que intento explicarte

Si quieres verlo facilmente, inserta un ListBox en tu proyecto y pon su propiedad Sorted a TRUE, entonces pegas este código

List1.AddItem "lunes"
List1.AddItem "martes"
List1.AddItem "miercoles"
List1.AddItem "jueves"
List1.AddItem "viernes"
List1.AddItem "sabado"
List1.AddItem "domingo"

y verás lo que te enseña el ListBox ya que la comparación es por valor ASCII del caracter o sea que 5 es menor que 6 pero JUEVES es menor que MARTES porque la J viene antes que la M

Saludos

[erbuson]

Ha sido un pequeño reto, aquí te dejo una posible solución:

Public Function DiaNum(DiaEnLetras As String) As Integer
' Recibe el dia semana en letras y devuelve su número Lunes 1, Martes 2, ...
DiaNum = InStr("lmmjvsd", LCase$(Left$(DiaEnLetras, 1)))
If DiaNum = 2 And LCase$(Left$(DiaEnLetras, 2)) = "mi" Then DiaNum = 3
End Function

de este modo la comparación si que debería funcionar

Loop While DiaNum(dia_C) > DiaNum("lunes")

aunque como siempre comparas con Lunes, podrías hacer lo siguiente:

Loop While DiaNum(dia_C) > 1

Saludos

[XYON126]

Hola erbuson!

Me has aclarado un tema que me estaba volviendo loco, muchas gracias Pero ahora llega la pregunta del siglo pues hay otro loop que me esta dejando peor que el anterior, resulta que en el Msflexgrid siempre me visualizaba un dia y en el archivo habian dos dias 19 uno en la semana 17 y otro en la 20 pero el resto de dias no me salia, despues de muchas pruebas y analisis decidi modificar el archivo procurando que no hubiese un dia del mes que se duplicase en el archivo es decir 19 de abril y 19 de Mayo eliminando uno de ellos, e aqui la sorpresa que el primer registro que me inserta no era el de la ultima semana el 19 de Mayo sino el de la semana 17 que es el dia 17 abril, si yo le digo que me visualice el ultimo registro ¿porque me sale el de la semana 17 y no el de la semana 20? o es que la lectura es al reves. si quieres te remito nuevamente el proyecto con el archivo para que veas lo que ocurre.

Un saludo